[oe-commits] org.oe.dev fontconfig_2.4.1.bb : add the latest stable fontconfig.

[xora commit]

fontconfig_2.4.1.bb : add the latest stable fontconfig.

Also took opportunity to improve its cross compiling by removing
${HOST_ARCH} stuff from native bits of the build.

Author: xora at openembedded.org
Branch: org.openembedded.dev
Revision: cdf35bf5da7dda3c2ee00ddc7c71372a64d83a95
ViewMTN: http://monotone.openembedded.org/revision.psp?id=cdf35bf5da7dda3c2ee00ddc7c71372a64d83a95
Files:
1
packages/fontconfig/fontconfig_2.4.1.bb
Diffs:

#
# mt diff -r2a4863b068e03adf240aff4aea0c3ebc9662fe3c -rcdf35bf5da7dda3c2ee00ddc7c71372a64d83a95
#
# 
# 
# add_file "packages/fontconfig/fontconfig_2.4.1.bb"
#  content [0bb511dccbc9ae256b30075f05f08e26525ee48e]
# 
============================================================
--- packages/fontconfig/fontconfig_2.4.1.bb	0bb511dccbc9ae256b30075f05f08e26525ee48e
+++ packages/fontconfig/fontconfig_2.4.1.bb	0bb511dccbc9ae256b30075f05f08e26525ee48e
@@ -0,0 +1,57 @@
+SECTION = "libs"
+LICENSE = "BSD"
+DESCRIPTION = "A library for configuring and customizing font access."
+DEPENDS = "expat freetype freetype-native zlib"
+
+SRC_URI = "http://fontconfig.org/release/fontconfig-${PV}.tar.gz"
+
+PR = "r0"
+
+PACKAGES =+ "fontconfig-utils-dbg fontconfig-utils "
+FILES_fontconfig-utils-dbg = "${bindir}/*.dbg"
+FILES_fontconfig-utils = "${bindir}/*"
+
+# Work around past breakage in debian.bbclass
+RPROVIDES_fontconfig-utils = "libfontconfig-utils"
+RREPLACES_fontconfig-utils = "libfontconfig-utils"
+RCONFLICTS_fontconfig-utils = "libfontconfig-utils"
+DEBIAN_NOAUTONAME_fontconfig-utils = "1"
+
+S = "${WORKDIR}/fontconfig-${PV}"
+
+inherit autotools pkgconfig
+
+export HASDOCBOOK="no"
+
+EXTRA_OECONF = " --disable-docs --with-arch=${HOST_ARCH}"
+EXTRA_OEMAKE = "FC_LANG=fc-lang FC_GLYPHNAME=fc-glyphname"
+
+# The tarball has some of the patched files as read only, which
+# patch doesn't like at all
+
+fontconfig_do_unpack() {
+       chmod -R u+rw ${S}
+}
+
+python do_unpack () {
+       bb.build.exec_func('base_do_unpack', d)
+       bb.build.exec_func('fontconfig_do_unpack', d)
+}
+
+do_stage () {
+	oe_libinstall -so -a -C src libfontconfig ${STAGING_LIBDIR}
+	install -d ${STAGING_INCDIR}/fontconfig
+	for i in ${S}/fontconfig/*.h; do install -m 0644 $i ${STAGING_INCDIR}/fontconfig/; done
+}
+
+do_configure_append () {
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-case/Makefile
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-glyphname/Makefile
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-lang/Makefile
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-arch/Makefile
+}
+
+do_install () {
+	autotools_do_install
+}
+