[oe-commits] org.oe.dev net-snmp: Add 5.4.1

[eha commit]

net-snmp: Add 5.4.1
(From #2765, minor edits to follow in next commit)

The current net-snmp version in OE (5.1.2) is an old release from an
unsupported release train (5.1.x).

Further more, there it is using socket option SO_BSDCOMPAT which is no longer
supported in Linux (at least in current 2.6 kernels).

I have attached a patch for upgrading. I am not sure about my changes to
DEPENDS and RDEPENDS, so please verify.

Author: eha at doredevelopment.dk
Branch: org.openembedded.dev
Revision: 1c677cd93897689aa52a23eb04ceefc28c394100
ViewMTN: http://monotone.openembedded.org/revision.psp?id=1c677cd93897689aa52a23eb04ceefc28c394100
Files:
1
packages/net-snmp/net-snmp-5.4.1
packages/net-snmp/net-snmp_5.4.1.bb
Diffs:

#
# mt diff -r26e6a3557f6ba9ad4ffb5bfed72f48b1cdaff3a5 -r1c677cd93897689aa52a23eb04ceefc28c394100
#
# 
# 
# add_dir "packages/net-snmp/net-snmp-5.4.1"
# 
# add_file "packages/net-snmp/net-snmp_5.4.1.bb"
#  content [7c3359913e775d9c6ef9ef5e39432c1debc828db]
# 
============================================================
--- packages/net-snmp/net-snmp_5.4.1.bb	7c3359913e775d9c6ef9ef5e39432c1debc828db
+++ packages/net-snmp/net-snmp_5.4.1.bb	7c3359913e775d9c6ef9ef5e39432c1debc828db
@@ -0,0 +1,62 @@
+DESCRIPTION = "Various tools relating to the Simple Network Management Protocol"
+HOMEPAGE = "http://www.net-snmp.org/"
+LICENSE = "BSD"
+DEPENDS = "openssl perl"
+RDEPENDS = "perl-lib"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/net-snmp/net-snmp-${PV}.tar.gz \
+	file://configure-tail.patch;patch=1 \
+	file://init \
+	file://snmpd.conf \
+	file://snmptrapd.conf"
+
+inherit autotools
+
+PARALLEL_MAKE = ""
+EXTRA_OECONF = "--enable-shared --disable-manuals --with-defaults"
+EXTRA_OEMAKE = "INSTALL_PREFIX=${D}"
+
+do_configure() {
+	# Additional flag based on target endiness (see siteinfo.bbclass)
+	ENDIANESS="${@base_conditional('SITEINFO_ENDIANESS', 'le', '--with-endianness=little', '--with-endianness=big', d)}"
+	oenote Determined endianess as: $ENDIANESS
+	oe_runconf $ENDIANESS
+}
+
+do_install_append() {
+	install -d ${D}${sysconfdir}/snmp
+	install -d ${D}${sysconfdir}/init.d
+	install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/snmpd
+	install -m 644 ${WORKDIR}/snmpd.conf ${D}${sysconfdir}/snmp/
+	install -m 644 ${WORKDIR}/snmptrapd.conf ${D}${sysconfdir}/snmp/
+}
+
+PACKAGES = "net-snmp-dbg net-snmp-doc net-snmp-dev net-snmp-libs net-snmp-mibs net-snmp-server net-snmp-client"
+FILES_net-snmp-libs = "${libdir}/*"
+FILES_net-snmp-mibs = "${datadir}/snmp/mibs"
+FILES_net-snmp-server = "${sbindir}/* ${sysconfdir}"
+FILES_net-snmp-client = "${bindir}/* ${datadir}/snmp/"
+FILES_net-snmp-dbg += "${libdir}/.debug/ ${sbindir}/.debug/ ${bindir}/.debug/"
+RDEPENDS_net-snmp-server += "net-snmp-mibs"
+RDEPENDS_net-snmp-client += "net-snmp-mibs"
+
+pkg_postinst_net-snmp-server() {
+if test "x$D" != "x"; then
+	D="-r $D"
+else
+	D="-s"
+fi
+update-rc.d $D snmpd defaults
+}
+
+pkg_postrm_net-snmp-server() {
+if test "x$D" != "x"; then
+	D="-r $D"
+else
+	/etc/init.d/snmpd stop
+fi
+update-rc.d $D snmpd remove
+}
+
+CONFFILES_${PN}_nylon = "${sysconfdir}/snmp/snmpd.conf ${sysconfdir}/snmp/snmptrapd.conf"