[oe-commits] org.oe.dev task-opie-16mb, opie-image-16mb: Add task and image recipes for small OPIE image.

[pfalcon commit]

task-opie-16mb, opie-image-16mb: Add task and image recipes for small OPIE image.

Author: pfalcon at openembedded.org
Branch: org.openembedded.dev
Revision: f0f36228e0efce9c251ba830603b54e72d39d404
ViewMTN: http://monotone.openembedded.org/revision.psp?id=f0f36228e0efce9c251ba830603b54e72d39d404
Files:
1
packages/images/opie-image-16mb.bb
packages/tasks/task-opie-16mb.bb
Diffs:

#
# mt diff -r4eb10ba006f2d10539be2d9fe0a8ffcedd4bb880 -rf0f36228e0efce9c251ba830603b54e72d39d404
#
# 
# 
# add_file "packages/images/opie-image-16mb.bb"
#  content [2e6f0db6374c4e3b3ab6fc27b52380ef7e65b882]
# 
# add_file "packages/tasks/task-opie-16mb.bb"
#  content [c0a18727fc19ff18cf71d626b50d65ff16793273]
# 
============================================================
--- packages/images/opie-image-16mb.bb	2e6f0db6374c4e3b3ab6fc27b52380ef7e65b882
+++ packages/images/opie-image-16mb.bb	2e6f0db6374c4e3b3ab6fc27b52380ef7e65b882
@@ -0,0 +1,67 @@
+export IMAGE_BASENAME = "opie-image-16mb"
+export IMAGE_LINGUAS = ""
+
+LICENSE = "MIT"
+PR = "r0"
+
+DEPENDS = "${MACHINE_TASK_PROVIDER} task-opie-16mb"
+RDEPENDS = "${INSTALL_PACKAGES}"
+
+INSTALL_PACKAGES = "${MACHINE_TASK_PROVIDER} \
+                    task-opie-16mb-base \
+                    task-opie-16mb-applets \
+                    task-opie-16mb-inputmethods \
+                    task-opie-16mb-settings \
+                    task-opie-16mb-apps \
+                    task-opie-16mb-pim \
+		    task-opie-irda"
+
+export PACKAGE_INSTALL = "${INSTALL_PACKAGES}"
+
+# merge feed-sources into ipkg.conf for opie-aqpkg as it can't handle feed-sources outside of ipkg.conf.
+merge_feeds() {
+
+        if ! test -z "${FEED_URIS}"
+        then
+                # Die gracefully if ipkg-collateral failed
+                if ! test -e "${IMAGE_ROOTFS}/etc/ipkg.conf"
+                then
+                        echo "[${IMAGE_ROOTFS}/etc/ipkg.conf] is missing!"
+                        exit 1
+                fi
+
+                # comment out existing feed-sources inserted by ipkg-collateral
+                cat ${IMAGE_ROOTFS}/etc/ipkg.conf | sed "s/^src\ /#src\ /" > ${IMAGE_ROOTFS}/etc/ipkg.conf_
+                rm ${IMAGE_ROOTFS}/etc/ipkg.conf && mv ${IMAGE_ROOTFS}/etc/ipkg.conf_ ${IMAGE_ROOTFS}/etc/ipkg.conf
+
+                # extract, then delete destinations
+                cat ${IMAGE_ROOTFS}/etc/ipkg.conf | egrep "^dest\ " > ${IMAGE_ROOTFS}/etc/ipkg.conf.dest
+                cat ${IMAGE_ROOTFS}/etc/ipkg.conf | egrep -v "^dest\ " > ${IMAGE_ROOTFS}/etc/ipkg.conf_
+                rm ${IMAGE_ROOTFS}/etc/ipkg.conf && mv ${IMAGE_ROOTFS}/etc/ipkg.conf_ ${IMAGE_ROOTFS}/etc/ipkg.conf
+
+
+                for line in ${FEED_URIS}
+                do
+                        # strip leading and trailing spaces/tabs, then split into name and uri
+                        line_clean="`echo "$line"|sed 's/^[ \t]*//;s/[ \t]*$//'`"
+                        feed_name="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\1/p'`"
+                        feed_uri="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\2/p'`"
+
+                        # insert new feed-sources
+                        echo "src/gz $feed_name $feed_uri" >> ${IMAGE_ROOTFS}/etc/ipkg.conf
+                done
+
+                # remove temporary files and rebuild ipkg.conf
+                echo "" >> ${IMAGE_ROOTFS}/etc/ipkg.conf
+                cat ${IMAGE_ROOTFS}/etc/ipkg.conf.dest >> ${IMAGE_ROOTFS}/etc/ipkg.conf
+                rm ${IMAGE_ROOTFS}/etc/ipkg.conf.dest
+
+                # remove -feed.conf files which are no longer needed
+                cd ${IMAGE_ROOTFS}/etc/ipkg/ && rm -- *-feed.conf
+        fi
+}
+
+# merge feed-sources into ipkg.conf and create /etc/timestamp from build date
+IMAGE_PREPROCESS_COMMAND = "merge_feeds; create_etc_timestamp"
+
+inherit image
============================================================
--- packages/tasks/task-opie-16mb.bb	c0a18727fc19ff18cf71d626b50d65ff16793273
+++ packages/tasks/task-opie-16mb.bb	c0a18727fc19ff18cf71d626b50d65ff16793273
@@ -0,0 +1,54 @@
+DESCRIPTION = "Tasks for small OPIE image"
+SECTION = "opie/base"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+ALLOW_EMPTY = "1"
+LICENSE = "MIT"
+
+PR = "r0"
+
+PACKAGES = "task-opie-16mb-base \
+            task-opie-16mb-applets \
+            task-opie-16mb-inputmethods \
+            task-opie-16mb-settings \
+            task-opie-16mb-apps \
+            task-opie-16mb-pim \
+           "
+
+#
+# Dependencies to get the launcher up and running
+#
+RDEPENDS_task-opie-16mb-base = "opie-init opie-alarm opie-qcop opie-qss opie-quicklauncher \
+                           opie-taskbar opie-pics opie-sounds opie-freetype \
+                           ttf-dejavu-sans ttf-dejavu-sans-mono"
+
+#
+# things for reasonable bootstrap image
+#
+RDEPENDS_task-opie-16mb-applets = "opie-aboutapplet opie-clockapplet opie-suspendapplet \
+                                   opie-homeapplet opie-rotateapplet \
+		                   opie-brightnessapplet opie-volumeapplet \
+                                   opie-screenshotapplet \
+    ${@base_contains("COMBINED_FEATURES", "irda", "opie-irdaapplet", "",d)} \
+    ${@base_contains("COMBINED_FEATURES", "apm", "opie-batteryapplet", "",d)} \
+    ${@base_contains("COMBINED_FEATURES", "pcmcia", "opie-pcmciaapplet", "",d)} \
+    ${@base_contains("MACHINE_FEATURES", "keyboard", "opie-vtapplet opie-logoutapplet", "",d)}"
+
+#
+# clamshell models can benefit from the autorotate applet
+#
+RDEPENDS_task-opie-16mb-applets_append_c7x0   = " opie-autorotateapplet"
+RDEPENDS_task-opie-16mb-applets_append_spitz  = " opie-autorotateapplet"
+RDEPENDS_task-opie-16mb-applets_append_akita  = " opie-autorotateapplet"
+
+RDEPENDS_task-opie-16mb-inputmethods = "opie-multikey"
+
+RDEPENDS_task-opie-16mb-settings = "opie-packagemanager opie-light-and-power opie-appearance \
+                           opie-systemtime opie-networksettings opie-button-settings \
+                           opie-icon-reload opie-launcher-settings opie-security \
+                           opie-securityplugin-pin"
+
+RDEPENDS_task-opie-16mb-apps = "opie-console opie-clock opie-backup opie-sysinfo \
+                       opie-advancedfm"
+
+RDEPENDS_task-opie-16mb-pim = "opie-addressbook opie-datebook opie-drawpad \
+                      opie-search opie-textedit opie-today opie-todo"