[oe-commits] org.oe.dev openmoko-icon-theme-standard2-qvga: icon theme for qvga devices

[pH5 commit]

openmoko-icon-theme-standard2-qvga: icon theme for qvga devices
* this recipe is a hack that rescales (from svgs or pngs) the stock
  icons in openmoko-icon-theme-standard2 to 22x22 and removes the
  bigger stock icons as well as the 128x128 icons.
* needs convert and rsvg, their native recipes are still missing

Author: pH5 at openembedded.org
Branch: org.openembedded.dev
Revision: 0d48495a9a1a7e2fc5709c220b7bff768e1550e8
ViewMTN: http://monotone.openembedded.org/revision/info/0d48495a9a1a7e2fc5709c220b7bff768e1550e8
Files:
1
packages/openmoko2/openmoko-icon-theme-standard2-qvga_svn.bb
conf/distro/include/sane-srcrevs.inc
Diffs:

#
# mt diff -r87cab650b7efedd959abe13ef2a7d918626703ff -r0d48495a9a1a7e2fc5709c220b7bff768e1550e8
#
# 
# 
# add_file "packages/openmoko2/openmoko-icon-theme-standard2-qvga_svn.bb"
#  content [b49376120f1dc1282d69613b3b21a271fe730912]
# 
# patch "conf/distro/include/sane-srcrevs.inc"
#  from [5cde08c669011db2659996a92a1d15a66d4f0bbb]
#    to [00f822dcbd3647b59467351dfc48ee1b86f31855]
# 
============================================================
--- packages/openmoko2/openmoko-icon-theme-standard2-qvga_svn.bb	b49376120f1dc1282d69613b3b21a271fe730912
+++ packages/openmoko2/openmoko-icon-theme-standard2-qvga_svn.bb	b49376120f1dc1282d69613b3b21a271fe730912
@@ -0,0 +1,54 @@
+DESCRIPTION = "Standard Gtk+ icon theme for the OpenMoko distribution, QVGA edition"
+SECTION = "openmoko/base"
+PV = "0.1.0+svn${SVNREV}"
+PR = "r0"
+
+inherit openmoko2
+
+SRC_URI = "svn://svn.openmoko.org/trunk/src/target/OM-2007.2/artwork/;module=icons;proto=http"
+S = "${WORKDIR}/icons"
+
+pkg_postinst_${PN} () {
+    if [ "x$D" != "x" ]; then
+        exit 1
+    fi
+    gtk-update-icon-cache -q /usr/share/icons/openmoko-standard
+}
+
+do_configure_prepend () {
+	cd ${S}
+	#
+	# don't include 36x36 and 128x128 icons, 32x32 and 48x48 stock icons
+	#
+	sed -i -e "/\(36\|128\)/d" -e "/\(32\|48\)\/stock/d" configure.ac
+	cd openmoko-standard
+	sed -i -e "s/\(36x36\|128x128\) //g" Makefile.am
+	sed -i "/^SUBDIRS=/s/ stock//" {32x32,48x48}/Makefile.am 
+	#
+	# rescale stock icons to 22x22
+	#
+	for png in $(ls */stock/*.png | sed "s,.*/,," | sort | uniq); do
+		svg=scalable/stock/$(basename $png .png).svg
+		out=22x22/stock/$png
+		if [ -f $svg ]; then
+			#
+			# if there are vector graphics, rerender
+			#
+			rsvg -w 22 -h 22 $svg $out
+		else
+			#
+			# otherwise rescale biggest existing bitmap
+			#
+			png=$(echo */stock/$png | sed "s/.* //")
+			convert -scale 22x22 $png $out
+		fi
+	done
+	#
+	# register the rescaled icons with automake
+	#
+	cd 22x22/stock
+	sed -i "/^icons_DATA/s/=.*/= $(echo *.png)/" Makefile.am
+	cd ${S}
+}
+
+PACKAGE_ARCH = "all"
============================================================
--- conf/distro/include/sane-srcrevs.inc	5cde08c669011db2659996a92a1d15a66d4f0bbb
+++ conf/distro/include/sane-srcrevs.inc	00f822dcbd3647b59467351dfc48ee1b86f31855
@@ -52,6 +52,7 @@ SRCREV_pn-openmoko-icon-theme-standard2 
 SRCREV_pn-openmoko-footer ?= "2354"
 SRCREV_pn-openmoko-icon-theme-standard ?= "2232"
 SRCREV_pn-openmoko-icon-theme-standard2 ?= "2967"
+SRCREV_pn-openmoko-icon-theme-standard2-qvga ?= "2967"
 SRCREV_pn-openmoko-keyboard ?= "1631"
 SRCREV_pn-openmoko-libs ?= "2367"
 SRCREV_pn-openmoko-mediaplayer2 ?= "2952"