[oe-commits] org.oe.dev dbus-java: Added recipe.

[thebohemian commit]

dbus-java: Added recipe.
libmatthew: Added recipe (dependency for dbus-java).

Author: thebohemian at openembedded.org
Branch: org.openembedded.dev
Revision: 8e7f10e1b07e1925f6b58430087d8881060e3bac
ViewMTN: http://monotone.openembedded.org/revision/info/8e7f10e1b07e1925f6b58430087d8881060e3bac
Files:
1
packages/dbus-java
packages/libmatthew
packages/dbus-java/dbus-java_2.3.bb
packages/libmatthew/libmatthew_0.5.bb
Diffs:

#
# mt diff -r69912ac05c10249dadb65f5f98c58f8401c9d0ec -r8e7f10e1b07e1925f6b58430087d8881060e3bac
#
# 
# 
# add_dir "packages/dbus-java"
# 
# add_dir "packages/libmatthew"
# 
# add_file "packages/dbus-java/dbus-java_2.3.bb"
#  content [0f364694e12942f190ab3353a87700e5ae39ac26]
# 
# add_file "packages/libmatthew/libmatthew_0.5.bb"
#  content [23e5bf387eae5233d4fd7f2f2ec8be582756bac2]
# 
============================================================
--- packages/dbus-java/dbus-java_2.3.bb	0f364694e12942f190ab3353a87700e5ae39ac26
+++ packages/dbus-java/dbus-java_2.3.bb	0f364694e12942f190ab3353a87700e5ae39ac26
@@ -0,0 +1,98 @@
+DESCRIPTION = "A pure Java D-Bus Implementation"
+DESCRIPTION_dbus-java-viewer = "${DESCRIPTION} (DBusViewer Binary)"
+DESCRIPTION_dbus-java-bin = "${DESCRIPTION} (Binaries)"
+
+LICENSE = "GPLv2 AFL"
+SECTION = "libs"
+MAINTAINER = "Fabian Koester, tarent GmbH Bonn <f.koester at tarent.de>"
+HOMEPAGE = "http://jalimo.org"
+AUTHOR = "Matthew Johnson <dbus at matthew.ath.cx>"
+
+PR = "r2"
+
+inherit java-library
+
+SRC_URI = "http://dbus.freedesktop.org/releases/dbus-java/dbus-java-${PV}.tar.gz"
+
+S = "${WORKDIR}/dbus-java-${PV}"
+
+DEPENDS = "libmatthew docbook-utils-native docbook-sgml-dtd-4.1-native"
+RSUGGESTS_libdbus-java = "libmatthew-java dbus"
+RDEPENDS_dbus-java-viewer = "java2-runtime libmatthew-java ${JPN}"
+RDEPENDS_dbus-java-bin = "java2-runtime libmatthew-java ${JPN}"
+
+do_compile () {
+  # run target .binclasses first to fix a brokenness in the Makefile
+	oe_runmake \
+    JCFLAGS="-source 1.5" \
+    JAVAC="javac" \
+    JARPREFIX="${STAGING_DATADIR}/java" \
+    JAVAUNIXJARDIR="${STAGING_DATADIR}/java" \
+    CLASSPATH="${S}/classes" \
+    JAR="fastjar" \
+    .binclasses
+
+	oe_runmake \
+    JCFLAGS="-source 1.5" \
+    JAVAC="javac" \
+    JARPREFIX="${STAGING_DATADIR}/java" \
+    JAVAUNIXJARDIR="${STAGING_DATADIR}/java" \
+    CLASSPATH="${S}/classes" \
+    JAR="fastjar" \
+    all
+
+  # Generated shell scripts will have staging paths inside them.
+  rm bin/*
+
+  # Generate them again with target paths.
+  oe_runmake \
+    JAVAC="oefatal \"No Java compilation expected here.\"" \
+    JAR="oefatal \"No jar invocation expected here.\"" \
+    JARPREFIX=${datadir}/java \
+    JAVAUNIXPATH=${datadir}/java \
+    all
+
+  # Trigger generation of all documentation files to prevent this
+  # being happen at the target 'install-man' in do_install.
+  oe_runmake \
+    JAVAC="oefatal \"No Java compilation expected here.\"" \
+    JAR="oefatal \"No jar invocation expected here.\"" \
+    JARPREFIX=${datadir}/java \
+    JAVAUNIXPATH=${datadir}/java \
+    CreateInterface.1 ListDBus.1 DBusDaemon.1 DBusViewer.1 changelog AUTHORS COPYING README INSTALL DBusCall.1
+}
+
+do_staging () {
+  oe_jarinstall -s ${JPN}-${PV}.jar ${JPN}.jar
+}
+
+do_install () {
+  oe_jarinstall ${JPN}-${PV}.jar ${JPN}.jar
+  oe_jarinstall dbus-java-viewer-${PV}.jar dbus-java-viewer.jar
+  oe_jarinstall dbus-java-bin-${PV}.jar dbus-java-bin.jar
+
+  install -d ${D}${bindir}
+  install bin/DBusViewer ${D}${bindir}
+  install bin/DBusCall ${D}${bindir}
+  install bin/CreateInterface ${D}${bindir}
+  install bin/ListDBus ${D}${bindir}
+  install bin/DBusDaemon ${D}${bindir}
+
+  oe_runmake \
+    JAVAC="oefatal \"No Java compilation expected here.\"" \
+    JAR="oefatal \"No jar invocation expected here.\"" \
+    MANPREFIX=${D}${mandir} \
+    DOCPREFIX=${D}${docdir}/${JPN} \
+    install-man
+}
+
+# ${JPN} must be last otherwise it would pick up dbus-viewer*.jar
+# and dbus-bin*.jar
+PACKAGES = "dbus-java-viewer dbus-java-viewer-doc dbus-java-bin dbus-java-bin-doc ${JPN}"
+
+PACKAGE_ARCH = "all"
+
+FILES_dbus-java-viewer = "${datadir}/java/dbus-java-viewer*.jar ${bindir}/DBusViewer"
+FILES_dbus-java-viewer-doc = "${mandir}/DBusViewer*"
+FILES_dbus-java-bin = "${datadir}/java/dbus-java-bin*.jar ${bindir}"
+FILES_dbus-java-bin-doc = "${mandir} ${docdir}/${JPN}"
============================================================
--- packages/libmatthew/libmatthew_0.5.bb	23e5bf387eae5233d4fd7f2f2ec8be582756bac2
+++ packages/libmatthew/libmatthew_0.5.bb	23e5bf387eae5233d4fd7f2f2ec8be582756bac2
@@ -0,0 +1,54 @@
+DESCRIPTION = "Unix socket, debug and hexdump libraries"
+LICENSE = "LGPL"
+SECTION = "libs"
+MAINTAINER = "Fabian Koester, tarent GmbH Bonn <f.koester at tarent.de>"
+HOMEPAGE = "http://jalimo.org"
+AUTHOR = "Matthew Johnson <web at matthew.ath.cx>"
+
+inherit java-library
+
+DEPENDS = "classpath-native classpath"
+
+SRC_URI = "http://www.matthew.ath.cx/projects/java/libmatthew-java-${PV}.tar.gz"
+
+S = "${WORKDIR}/libmatthew-java-${PV}"
+
+do_compile() {
+  oe_runmake \
+    JCFLAGS="-source 1.5" \
+    JAVAC="javac" \
+    JAR="fastjar" \
+    JAVAH="gjavah" \
+  	INCLUDES="-I${STAGING_INCDIR}/classpath" \
+    LDFLAGS="-fpic -shared -lc ${LDFLAGS}" \
+    LD="${CC}"
+}
+
+do_stage() { 
+  oe_jarinstall -s cgi-0.5.jar cgi.jar
+	oe_jarinstall -s debug-disable-1.1.jar debug-disable.jar
+	oe_jarinstall -s debug-enable-1.1.jar debug-enable.jar
+	oe_jarinstall -s hexdump-0.1.jar hexdump.jar
+	oe_jarinstall -s io-0.1.jar io.jar
+	oe_jarinstall -s unix-0.2.jar unix.jar
+}
+
+do_install() {
+  oe_jarinstall cgi-0.5.jar cgi.jar
+	oe_jarinstall debug-disable-1.1.jar debug-disable.jar
+	oe_jarinstall debug-enable-1.1.jar debug-enable.jar
+	oe_jarinstall hexdump-0.1.jar hexdump.jar
+	oe_jarinstall io-0.1.jar io.jar
+	oe_jarinstall unix-0.2.jar unix.jar
+
+  oe_libinstall -so libcgi-java ${D}${libdir}/jni
+  oe_libinstall -so libunix-java ${D}${libdir}/jni
+}
+
+PACKAGES += "${PN}-jni ${PN}-jni-dbg"
+
+RDEPENDS_${JPN} = "${PN}-jni"
+
+FILES_${PN}-jni = "${libdir}/jni/lib*.so"
+FILES_${PN}-jni-dbg = "${libdir}/jni/.debug/lib*.so"
+