[oe-commits] org.oe.dev fontconfig: added 2.6.0 from Poky - should close #2951

[hrw commit]

fontconfig: added 2.6.0 from Poky - should close #2951

Author: hrw at openembedded.org
Branch: org.openembedded.dev
Revision: e823514ff8e0cdded7f451b2e7602dea0a0a9fc7
ViewMTN: http://monotone.openembedded.org/revision/info/e823514ff8e0cdded7f451b2e7602dea0a0a9fc7
Files:
1
packages/fontconfig/fontconfig-2.6.0
packages/fontconfig/fontconfig-2.6.0/fix-pkgconfig.patch
packages/fontconfig/fontconfig-native_2.6.0.bb
packages/fontconfig/fontconfig_2.6.0.bb
Diffs:

#
# mt diff -rb68ae87d8ee0969bc8a91ea0ac326fb34c5eb9a4 -re823514ff8e0cdded7f451b2e7602dea0a0a9fc7
#
#
#
# add_dir "packages/fontconfig/fontconfig-2.6.0"
# 
# add_file "packages/fontconfig/fontconfig-2.6.0/fix-pkgconfig.patch"
#  content [5151c1f229c32c3ecb233fa9bd718d0b50d6ff1c]
# 
# add_file "packages/fontconfig/fontconfig-native_2.6.0.bb"
#  content [24c03de8b197db8f1a84eb259d920c904b79f74b]
# 
# add_file "packages/fontconfig/fontconfig_2.6.0.bb"
#  content [5554f91bd476e11e0bb44b471239d177ef4b0faa]
#
============================================================
--- packages/fontconfig/fontconfig-2.6.0/fix-pkgconfig.patch	5151c1f229c32c3ecb233fa9bd718d0b50d6ff1c
+++ packages/fontconfig/fontconfig-2.6.0/fix-pkgconfig.patch	5151c1f229c32c3ecb233fa9bd718d0b50d6ff1c
@@ -0,0 +1,15 @@
+---
+ fontconfig.pc.in |    2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+--- fontconfig-2.6.0.orig/fontconfig.pc.in
++++ fontconfig-2.6.0/fontconfig.pc.in
+@@ -5,7 +5,7 @@ includedir=@includedir@
+ 
+ Name: Fontconfig
+ Description: Font configuration and customization library
+ Version: @VERSION@
+ Libs: -L${libdir} -lfontconfig
+-Libs.private: @EXPAT_LIBS@ @FREETYPE_LIBS@
++Libs.private: @EXPAT_LIBS@ -L${libdir} -lfreetype
+ Cflags: -I${includedir}
============================================================
--- packages/fontconfig/fontconfig-native_2.6.0.bb	24c03de8b197db8f1a84eb259d920c904b79f74b
+++ packages/fontconfig/fontconfig-native_2.6.0.bb	24c03de8b197db8f1a84eb259d920c904b79f74b
@@ -0,0 +1,15 @@
+SECTION = "base"
+LICENSE = "BSD"
+require fontconfig_${PV}.bb
+inherit native
+DEPENDS = "freetype-native expat-native zlib-native"
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/fontconfig-${PV}"
+
+EXTRA_OEMAKE = ""
+EXTRA_OECONF = "${@[' --disable-docs',' --disable-docs --with-freetype-config=%s/freetype-config' % bb.data.getVar('STAGING_BINDIR', d, 1)][os.path.isfile('%s/freetype-config' % bb.data.getVar('STAGING_BINDIR', d, 1))]}"
+
+do_stage () {
+	oe_runmake install
+	install fc-lang/fc-lang ${STAGING_BINDIR}
+	install fc-glyphname/fc-glyphname ${STAGING_BINDIR}
+}
============================================================
--- packages/fontconfig/fontconfig_2.6.0.bb	5554f91bd476e11e0bb44b471239d177ef4b0faa
+++ packages/fontconfig/fontconfig_2.6.0.bb	5554f91bd476e11e0bb44b471239d177ef4b0faa
@@ -0,0 +1,76 @@
+SECTION = "libs"
+LICENSE = "BSD"
+DESCRIPTION = "A library for configuring and customizing font access."
+DEPENDS = "expat freetype zlib"
+
+SRC_URI = "http://fontconfig.org/release/fontconfig-${PV}.tar.gz \
+           file://fix-pkgconfig.patch;patch=1"
+
+PACKAGES =+ "fontconfig-utils-dbg fontconfig-utils "
+FILES_fontconfig-utils-dbg = "${bindir}/*.dbg"
+FILES_fontconfig-utils = "${bindir}/*"
+
+# Work around past breakage in debian.bbclass
+RPROVIDES_fontconfig-utils = "libfontconfig-utils"
+RREPLACES_fontconfig-utils = "libfontconfig-utils"
+RCONFLICTS_fontconfig-utils = "libfontconfig-utils"
+DEBIAN_NOAUTONAME_fontconfig-utils = "1"
+
+S = "${WORKDIR}/fontconfig-${PV}"
+
+PARALLEL_MAKE = ""
+
+inherit autotools pkgconfig
+
+export HASDOCBOOK="no"
+
+EXTRA_OECONF = " --disable-docs --with-arch=${HOST_ARCH}"
+EXTRA_OEMAKE = "FC_LANG=fc-lang FC_GLYPHNAME=fc-glyphname"
+
+# The tarball has some of the patched files as read only, which
+# patch doesn't like at all
+
+fontconfig_do_unpack() {
+       chmod -R u+rw ${S}
+}
+
+python do_unpack () {
+       bb.build.exec_func('base_do_unpack', d)
+       bb.build.exec_func('fontconfig_do_unpack', d)
+}
+
+do_stage () {
+	oe_libinstall -so -a -C src libfontconfig ${STAGING_LIBDIR}
+	install -d ${STAGING_INCDIR}/fontconfig
+	for i in ${S}/fontconfig/*.h; do install -m 0644 $i ${STAGING_INCDIR}/fontconfig/; done
+}
+
+BUILD_CFLAGS += " -I${STAGING_INCDIR}/freetype2"
+
+do_configure_append () {
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-case/Makefile
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-glyphname/Makefile
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-lang/Makefile
+	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-arch/Makefile
+
+	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-case/Makefile
+	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-glyphname/Makefile
+	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-lang/Makefile
+	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-arch/Makefile
+
+	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-case/Makefile
+	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-glyphname/Makefile
+	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-lang/Makefile
+	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-arch/Makefile
+
+	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-case/Makefile
+	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-glyphname/Makefile
+	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-lang/Makefile
+	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-arch/Makefile
+
+}
+
+do_install () {
+	autotools_do_install
+}
+