[oe-commits] org.oe.dev alsa-*: update to 1.0.17

[koen commit]

alsa-*: update to 1.0.17

Author: koen at openembedded.org
Branch: org.openembedded.dev
Revision: b6468f30ba8615ab1fedc9f775cac1ede70d00fc
ViewMTN: http://monotone.openembedded.org/revision/info/b6468f30ba8615ab1fedc9f775cac1ede70d00fc
Files:
1
packages/alsa/alsa-lib_1.0.17.bb
packages/alsa/alsa-oss_1.0.17.bb
packages/alsa/alsa-plugins_1.0.17.bb
packages/alsa/alsa-utils_1.0.17.bb
Diffs:

#
# mt diff -r0db87b06924f108cfd5a9c17a370b06bf2e0bb20 -rb6468f30ba8615ab1fedc9f775cac1ede70d00fc
#
#
#
# add_file "packages/alsa/alsa-lib_1.0.17.bb"
#  content [9e11f02fb101b03a358b6a471d7420f82daac4bd]
# 
# add_file "packages/alsa/alsa-oss_1.0.17.bb"
#  content [4fa7f36a2c197c321f519368d1288b60ad07d66d]
# 
# add_file "packages/alsa/alsa-plugins_1.0.17.bb"
#  content [8f085bb2de8e8094c4500114a767eee8ce9b5612]
# 
# add_file "packages/alsa/alsa-utils_1.0.17.bb"
#  content [54364f933c80321c56eb6cac650adafa7ef0db63]
#
============================================================
--- packages/alsa/alsa-lib_1.0.17.bb	9e11f02fb101b03a358b6a471d7420f82daac4bd
+++ packages/alsa/alsa-lib_1.0.17.bb	9e11f02fb101b03a358b6a471d7420f82daac4bd
@@ -0,0 +1,48 @@
+DESCRIPTION = "Alsa sound library"
+HOMEPAGE = "http://www.alsa-project.org"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+
+# configure.in sets -D__arm__ on the command line for any arm system
+# (not just those with the ARM instruction set), this should be removed,
+# (or replaced by a permitted #define).
+#FIXME: remove the following
+ARM_INSTRUCTION_SET = "arm"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/lib/alsa-lib-${PV}.tar.bz2 \
+           file://fix-tstamp-declaration.patch;patch=1 \
+	   file://fix_libmath.patch;patch=1 \
+	  "
+
+inherit autotools pkgconfig
+
+
+EXTRA_OECONF = "--with-cards=pdaudiocf --with-oss=yes --disable-python"
+
+
+require alsa-fpu.inc
+EXTRA_OECONF += "${@get_alsa_fpu_setting(bb, d)} "
+
+
+require alsa-versym.inc
+EXTRA_OECONF += "${@get_alsa_versym_setting(bb, d)} "
+
+
+do_stage () {
+	autotools_stage_all
+}
+
+PACKAGES =+ "alsa-server libasound alsa-conf-base alsa-conf alsa-doc alsa-dev"
+FILES_${PN}-dbg += "${libdir}/alsa-lib/*/.debu*"
+FILES_libasound = "${libdir}/libasound.so.*"
+FILES_alsa-server = "${bindir}/*"
+FILES_alsa-conf = "${datadir}/alsa/"
+FILES_alsa-dev += "${libdir}/pkgconfig/ /usr/include/ ${datadir}/aclocal/*"
+FILES_alsa-conf-base = "\
+${datadir}/alsa/alsa.conf \
+${datadir}/alsa/cards/aliases.conf \
+${datadir}/alsa/pcm/default.conf \
+${datadir}/alsa/pcm/dmix.conf \
+${datadir}/alsa/pcm/dsnoop.conf"
+
+RDEPENDS_libasound = "alsa-conf-base"
============================================================
--- packages/alsa/alsa-oss_1.0.17.bb	4fa7f36a2c197c321f519368d1288b60ad07d66d
+++ packages/alsa/alsa-oss_1.0.17.bb	4fa7f36a2c197c321f519368d1288b60ad07d66d
@@ -0,0 +1,20 @@
+DESCRIPTION = "Alsa OSS Compatibility Package"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/oss-lib/alsa-oss-${PV}.tar.bz2 \
+	   file://libio.patch;patch=1 \
+	  "
+
+inherit autotools 
+
+LEAD_SONAME = "libaoss.so.0"
+
+do_configure_prepend () {
+	touch NEWS README AUTHORS ChangeLog
+}
+
+do_stage () {
+	autotools_stage_all
+}
============================================================
--- packages/alsa/alsa-plugins_1.0.17.bb	8f085bb2de8e8094c4500114a767eee8ce9b5612
+++ packages/alsa/alsa-plugins_1.0.17.bb	8f085bb2de8e8094c4500114a767eee8ce9b5612
@@ -0,0 +1,20 @@
+DESCRIPTION = "ALSA Plugins"
+HOMEPAGE = "http://www.alsa-project.org"
+SECTION = "multimedia/alsa/plugins"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib pulseaudio"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/plugins/alsa-plugins-${PV}.tar.bz2"
+
+inherit autotools
+
+PACKAGES_DYNAMIC = "libasound-module*"
+
+python populate_packages_prepend() {
+        plugindir = bb.data.expand('${libdir}/alsa-lib/', d)
+        do_split_packages(d, plugindir, '^libasound_module_(.*)\.so$', 'libasound-module-%s', 'Alsa plugin for %s', extra_depends='' )
+}
+
+FILES_${PN}-dev += "${libdir}/alsa-lib/libasound*.a ${libdir}/alsa-lib/libasound*.la"
+FILES_${PN}-dbg += "${libdir}/alsa-lib/.debug"
============================================================
--- packages/alsa/alsa-utils_1.0.17.bb	54364f933c80321c56eb6cac650adafa7ef0db63
+++ packages/alsa/alsa-utils_1.0.17.bb	54364f933c80321c56eb6cac650adafa7ef0db63
@@ -0,0 +1,63 @@
+DESCRIPTION = "ALSA Utilities"
+HOMEPAGE = "http://www.alsa-project.org"
+SECTION = "console/utils"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib ncurses"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/utils/alsa-utils-${PV}.tar.bz2 \
+           file://alsa-utils-automake.patch;patch=1 \
+	  "
+
+inherit autotools
+
+# This are all packages that we need to make. Also, the now empty alsa-utils
+# ipk depend on them.
+
+
+do_configure_append() {
+	for i in $(find ${S} -name Makefile) ; do
+		sed -i -e s:/usr/include/ncurses:${STAGING_INCDIR}/ncurses:g $i
+	done
+}
+
+PACKAGES += "\
+             alsa-utils-alsamixer \
+             alsa-utils-midi \
+             alsa-utils-aplay \
+             alsa-utils-amixer \
+             alsa-utils-aconnect \
+             alsa-utils-iecset \
+             alsa-utils-speakertest \
+             alsa-utils-aseqnet \
+             alsa-utils-aseqdump \
+             alsa-utils-alsaconf \
+             alsa-utils-alsactl "
+
+# We omit alsaconf, because
+# a) this is a bash script
+# b) it creates config files not suitable for OE-based distros
+
+FILES_${PN} = ""
+FILES_alsa-utils-aplay       = "${bindir}/aplay ${bindir}/arecord"
+FILES_alsa-utils-amixer      = "${bindir}/amixer"
+FILES_alsa-utils-alsamixer   = "${bindir}/alsamixer"
+FILES_alsa-utils-speakertest = "${bindir}/speaker-test ${datadir}/sounds/alsa/ ${datadir}/alsa/"
+FILES_alsa-utils-midi        = "${bindir}/aplaymidi ${bindir}/arecordmidi ${bindir}/amidi"
+FILES_alsa-utils-aconnect    = "${bindir}/aconnect"
+FILES_alsa-utils-aseqnet     = "${bindir}/aseqnet"
+FILES_alsa-utils-iecset      = "${bindir}/iecset"
+FILES_alsa-utils-alsactl     = "${sbindir}/alsactl"
+FILES_alsa-utils-aseqdump    = "${bindir}/aseqdump"
+FILES_alsa-utils-alsaconf    = "${sbindir}/alsaconf"
+
+DESCRIPTION_alsa-utils-aplay        = "play (and record) sound files via ALSA"
+DESCRIPTION_alsa-utils-amixer       = "command-line based control for ALSA mixer and settings"
+DESCRIPTION_alsa-utils-alsamixer    = "ncurses based control for ALSA mixer and settings"
+DESCRIPTION_alsa-utils-speakertest  = "ALSA surround speaker test utility"
+DESCRIPTION_alsa-utils-midi         = "miscalleanous MIDI utilities for ALSA"
+DESCRIPTION_alsa-utils-aconnect     = "ALSA sequencer connection manager"
+DESCRIPTION_alsa-utils-aseqnet      = "network client/server on ALSA sequencer"
+DESCRIPTION_alsa-utils-alsactl      = "saves/restores ALSA-settings in /etc/asound.state"
+DESCRIPTION_alsa-utils-alsaconf     = "a bash script that creates ALSA configuration files"
+
+ALLOW_EMPTY_alsa-utils = "1"