[oe-commits] : gdbserver: add recipe that only builds gdbserver, usefull for target without native gdb support (e.g. avr32)

[OE GIT Trial]

Module: OE.dev
Branch: master
Commit: 82e150879a226757f1d651f7aa9e6cc2e5dda663
URL:    http://gitweb.openembedded.net//OE.dev.git/?a=commit;h=82e150879a226757f1d651f7aa9e6cc2e5dda663

Author:  <koen at openembedded.org>
Date:   Sat Sep  6 11:18:32 2008 +0000

gdbserver: add recipe that only builds gdbserver, usefull for target without native gdb support (e.g. avr32)

---

 packages/gdb/gdbserver.inc      |   66 +++++++++++++++++++++++++++++++++++++++
 packages/gdb/gdbserver_6.7.1.bb |    6 +++
 2 files changed, 72 insertions(+), 0 deletions(-)

diff --git a/packages/gdb/gdbserver.inc b/packages/gdb/gdbserver.inc
new file mode 100644
index 0000000..a1610da
--- /dev/null
+++ b/packages/gdb/gdbserver.inc
@@ -0,0 +1,66 @@
+require gdb-common.inc
+
+DEFAULT_PREFERENCE_avr32 = "-99"
+
+DEPENDS = "ncurses readline"
+
+FILES_gdbserver = "${bindir}/gdbserver"
+
+RRECOMMENDS_gdb_append_linux = " glibc-thread-db "
+RRECOMMENDS_gdb_append_linux-gnueabi = " glibc-thread-db "
+
+inherit gettext
+
+SRC_URI += "file://kill_arm_map_symbols.patch;patch=1 \
+            file://gdbserver-cflags-last.diff;patch=1;pnum=0"
+#FIXME	   file://uclibc.patch;patch=1 \
+
+EXTRA_OEMAKE = "'SUBDIRS=intl mmalloc libiberty opcodes bfd sim gdb etc utils'"
+
+EXTRA_OECONF = "--disable-gdbtk --disable-tui --disable-x \
+                --with-curses --disable-multilib --with-readline --disable-sim \
+                --program-prefix=''"
+
+LDFLAGS_append = " -s"
+export CFLAGS_append=" -L${STAGING_LIBDIR}"
+
+do_configure () {
+    # override this function to avoid the autoconf/automake/aclocal/autoheader
+    # calls for now
+    (cd ${S}/gdb/gdbserver && gnu-configize) || die "failure in running gnu-configize"
+        CPPFLAGS="" oe_rungdbserverconf
+}
+
+do_install () {
+    install -d ${D}${bindir}
+    install -m 0755 ${B}/gdbserver ${D}${bindir}
+}
+
+oe_rungdbserverconf() {
+    if [ -x ${S}/gdb/gdbserver/configure ] ; then
+        cfgcmd="${S}/gdb/gdbserver/configure \
+            --build=${BUILD_SYS} \
+            --host=${HOST_SYS} \
+            --target=${TARGET_SYS} \
+            --prefix=${prefix} \
+            --exec_prefix=${exec_prefix} \
+            --bindir=${bindir} \
+            --sbindir=${sbindir} \
+            --libexecdir=${libexecdir} \
+            --datadir=${datadir} \
+            --sysconfdir=${sysconfdir} \
+            --sharedstatedir=${sharedstatedir} \
+            --localstatedir=${localstatedir} \
+            --libdir=${libdir} \
+            --includedir=${includedir} \
+            --oldincludedir=${oldincludedir} \
+            --infodir=${infodir} \
+            --mandir=${mandir} \
+            ${EXTRA_OECONF} \
+            $@"
+        oenote "Running $cfgcmd..."
+        $cfgcmd || oefatal "oe_runconf failed"
+    else
+        oefatal "no configure script found"
+    fi
+}
diff --git a/packages/gdb/gdbserver_6.7.1.bb b/packages/gdb/gdbserver_6.7.1.bb
new file mode 100644
index 0000000..fb92ebc
--- /dev/null
+++ b/packages/gdb/gdbserver_6.7.1.bb
@@ -0,0 +1,6 @@
+require gdbserver.inc
+
+DEFAULT_PREFERENCE_avr32 = "99"
+SRC_URI_avr32 = " http://avr32linux.org/twiki/pub/Main/GDBPatches/gdb-6.7.1.atmel.1.0.3.tar.bz2"
+S_avr32 = "${WORKDIR}/gdb-6.7.1.atmel.1.0.3"
+