[oe-commits] Michael 'Mickey' Lauer : libcanberra: add 0.14
git version control
git at git.openembedded.org
Fri Aug 7 00:53:39 UTC 2009
Module: openembedded.git
Branch: org.openembedded.dev
Commit: c579f58d519f6e2e58a3b5acc52fc3d9cd953c3d
URL: http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=c579f58d519f6e2e58a3b5acc52fc3d9cd953c3d
Author: Michael 'Mickey' Lauer <mickey at vanille-media.de>
Date: Thu Aug 6 23:48:04 2009 +0200
libcanberra: add 0.14
---
recipes/pulseaudio/libcanberra_0.14.bb | 60 ++++++++++++++++++++++++++++++++
1 files changed, 60 insertions(+), 0 deletions(-)
diff --git a/recipes/pulseaudio/libcanberra_0.14.bb b/recipes/pulseaudio/libcanberra_0.14.bb
new file mode 100644
index 0000000..f9388e1
--- /dev/null
+++ b/recipes/pulseaudio/libcanberra_0.14.bb
@@ -0,0 +1,60 @@
+DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name \
+Specifications, for generating event sounds on free desktops."
+LICENSE = "LGPL"
+DEPENDS = "alsa-lib gstreamer gtk+ libvorbis pulseaudio"
+SECTION = "libs/multimedia"
+AUTHOR = "Lennart Poettering"
+HOMEPAGE = "http://0pointer.de/lennart/projects/libcanberra"
+PR = "r1"
+
+inherit autotools_stage
+AUTOTOOLS_STAGE_PKGCONFIG = "1"
+
+SRC_URI = "http://0pointer.de/lennart/projects/libcanberra/libcanberra-${PV}.tar.gz"
+
+EXTRA_OECONF = "\
+ --enable-alsa \
+ --enable-gstreamer \
+ --enable-gtk \
+ --enable-multi \
+ --enable-null \
+ --disable-oss \
+# enable pulse again when pulseaudio >= 0.9.11 is the default in OE
+ --disable-pulse \
+ --disable-tdb \
+"
+
+# This needs autoconf 2.62, which isn't used by any distro in OE atm
+do_configure() {
+ gnu-configize --force
+ oe_runconf
+}
+
+# TODO: Test more fine granular version
+#OE_LT_RPATH_ALLOW=":${libdir}/${P}:"
+OE_LT_RPATH_ALLOW = "any"
+OE_LT_RPATH_ALLOW[export] = "1"
+
+python populate_packages_prepend() {
+ plugindir = bb.data.expand('${libdir}/${P}/', d)
+ do_split_packages(d, plugindir, '^libcanberra-(.*)\.so$', 'libcanberra-%s', '%s support library', extra_depends='' )
+}
+
+PACKAGES =+ "${PN}-gtk"
+
+PACKAGES_DYNAMIC = "libcanberra-*"
+
+FILES_${PN}-gtk = "\
+ ${sysconfdir}/gconf \
+ ${bindir}/* \
+ ${libdir}/libcanberra-gtk.so.* \
+ ${libdir}/gtk-2.0/modules/* \
+ ${datadir}/gnome \
+"
+FILES_${PN}-dev += "\
+ ${libdir}/${P}/*.la \
+"
+FILES_${PN}-dbg += "\
+ ${libdir}/gtk-2.0/modules/.debug \
+ ${libdir}/${P}/.debug \
+"
More information about the Openembedded-commits
mailing list