[oe-commits] Michael 'Mickey' Lauer : libcanberra: add metadata, fix packaging

[git version control]

Module: openembedded.git
Branch: fso/milestone5.5
Commit: ebf671f6360209ee289941916d9df89be8f3ae5c
URL:    http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=ebf671f6360209ee289941916d9df89be8f3ae5c

Author: Michael 'Mickey' Lauer <mickey at vanille-media.de>
Date:   Thu May 21 02:11:23 2009 +0200

libcanberra: add metadata, fix packaging

---

 recipes/pulseaudio/libcanberra_0.12.bb |   61 ++++++++++++++++++++++++++++++++
 1 files changed, 61 insertions(+), 0 deletions(-)

diff --git a/recipes/pulseaudio/libcanberra_0.12.bb b/recipes/pulseaudio/libcanberra_0.12.bb
new file mode 100644
index 0000000..44f82d1
--- /dev/null
+++ b/recipes/pulseaudio/libcanberra_0.12.bb
@@ -0,0 +1,61 @@
+DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name \
+Specifications, for generating event sounds on free desktops."
+LICENSE = "LGPL"
+DEPENDS = "alsa-lib gstreamer gtk+ libvorbis pulseaudio"
+SECTION = "libs/multimedia"
+AUTHOR = "Lennart Poettering"
+HOMEPAGE = "http://0pointer.de/lennart/projects/libcanberra"
+PR = "r1"
+
+inherit autotools autotools_stage
+
+SRC_URI = "http://0pointer.de/lennart/projects/libcanberra/libcanberra-${PV}.tar.gz"
+
+EXTRA_OECONF = "\
+  --enable-alsa \
+  --enable-gstreamer \
+  --enable-gtk \
+  --enable-multi \
+  --enable-null \
+  --disable-oss \
+# enable pulse again when pulseaudio >= 0.9.11 is the default in OE
+  --disable-pulse \
+  --disable-tdb \
+"
+
+# This needs autoconf 2.62, which isn't used by any distro in OE atm
+do_configure() {
+	gnu-configize --force
+	oe_runconf
+}
+
+# TODO: Test more fine granular version
+#OE_LT_RPATH_ALLOW=":${libdir}/${P}:"
+OE_LT_RPATH_ALLOW = "any"
+OE_LT_RPATH_ALLOW[export] = "1"
+
+PACKAGES_DYNAMIC = "libcanberra-*"
+
+python populate_packages_prepend() {
+	plugindir = bb.data.expand('${libdir}/${P}/', d)
+	do_split_packages(d, plugindir, '^lib(.*)\.so$', 'lib%s', '%s support library', extra_depends='' )
+}
+
+PACKAGES =+ "${PN}-gtk"
+
+FILES_${PN}-gtk = "\
+  ${sysconfdir}/gconf \
+  ${bindir} \
+  ${libdir}/libcanberra-gtk.so.* \
+  ${libdir}/gtk-2.0/modules/ \
+  ${datadir}/gnome \
+"
+FILES_${PN}-dev += "\
+  ${libdir}/${P}/*.la \
+"
+FILES_${PN}-dbg += "\
+  ${libdir}/gtk-2.0/modules/.debug \
+  ${libdir}/${P}/.debug \
+"
+
+AUTOTOOLS_STAGE_PKGCONFIG = "1"