[oe-commits] Khem Raj : eglibc_2.11: Add recipes for new eglibc 2.11 release

Sat Nov 14 06:25:13 UTC 2009

Module: openembedded.git
Branch: shr/merge
Commit: 849cddddec8f53105cf54d8e9eb56416f93c4c71
URL:    http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=849cddddec8f53105cf54d8e9eb56416f93c4c71

Author: Khem Raj <raj.khem at gmail.com>
Date:   Fri Nov 13 14:24:16 2009 -0800

eglibc_2.11: Add recipes for new eglibc 2.11 release

* Use EGLIBC_BRANCH in missing places where it could be used.
* Update svn recipe to latest.
* Update svn recipe version to 2.11+ now that 2.12 is tracking trunk.
* Make DEFAULT_PREFERENCE = -1 for eglibc 2.11 default stays 2.10.

Signed-off-by: Khem Raj <raj.khem at gmail.com>

---

 recipes/eglibc/eglibc-initial_2.11.bb |    6 ++
 recipes/eglibc/eglibc_2.10.bb         |    2 +-
 recipes/eglibc/eglibc_2.11.bb         |  100 +++++++++++++++++++++++++++++++++
 recipes/eglibc/eglibc_2.9.bb          |    2 +-
 recipes/eglibc/eglibc_svn.bb          |    9 +--
 5 files changed, 112 insertions(+), 7 deletions(-)

diff --git a/recipes/eglibc/eglibc-initial_2.11.bb b/recipes/eglibc/eglibc-initial_2.11.bb
new file mode 100644
index 0000000..787c762
--- /dev/null
+++ b/recipes/eglibc/eglibc-initial_2.11.bb
@@ -0,0 +1,6 @@
+require eglibc_${PV}.bb
+require eglibc-initial.inc
+
+do_configure_prepend () {
+        unset CFLAGS
+}
diff --git a/recipes/eglibc/eglibc_2.10.bb b/recipes/eglibc/eglibc_2.10.bb
index 2a62fe3..38faaf8 100644
--- a/recipes/eglibc/eglibc_2.10.bb
+++ b/recipes/eglibc/eglibc_2.10.bb
@@ -6,7 +6,7 @@ PV = "2.10"
 PR = "${INC_PR}.5"
 SVN_REV="9124"
 EGLIBC_BRANCH="eglibc-2_10"
-SRC_URI = "svn://svn.eglibc.org/branches;module=eglibc-2_10;rev=${SVN_REV};proto=svn \
+SRC_URI = "svn://svn.eglibc.org/branches;module=${EGLIBC_BRANCH};rev=${SVN_REV};proto=svn \
            file://eglibc-svn-arm-lowlevellock-include-tls.patch;patch=1 \
            file://armv4t-interworking.patch;patch=1 \
            file://IO-acquire-lock-fix.patch;patch=1 \
diff --git a/recipes/eglibc/eglibc_2.11.bb b/recipes/eglibc/eglibc_2.11.bb
new file mode 100644
index 0000000..8c7901c
--- /dev/null
+++ b/recipes/eglibc/eglibc_2.11.bb
@@ -0,0 +1,100 @@
+require eglibc.inc
+
+DEFAULT_PREFERENCE = "-1"
+DEPENDS += "gperf-native"
+FILESPATHPKG =. "eglibc-svn:"
+PV = "2.11"
+PR = "${INC_PR}.0"
+SVN_REV="9235"
+EGLIBC_BRANCH="eglibc-2_11"
+SRC_URI = "svn://svn.eglibc.org/branches;module=${EGLIBC_BRANCH};rev=${SVN_REV};proto=svn \
+           file://eglibc-svn-arm-lowlevellock-include-tls.patch;patch=1 \
+           file://IO-acquire-lock-fix.patch;patch=1 \
+           file://etc/ld.so.conf \
+           file://generate-supported.mk"
+S = "${WORKDIR}/${EGLIBC_BRANCH}/libc"
+B = "${WORKDIR}/build-${TARGET_SYS}"
+
+PACKAGES_DYNAMIC = "libc6*"
+RPROVIDES_${PN}-dev = "libc6-dev virtual-libc-dev"
+PROVIDES_${PN}-dbg = "glibc-dbg"
+
+# the -isystem in bitbake.conf screws up glibc do_stage
+BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}"
+TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${layout_includedir}"
+
+GLIBC_ADDONS ?= "ports,nptl,libidn"
+
+GLIBC_BROKEN_LOCALES = " _ER _ET so_ET yn_ER sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN"
+
+#
+# For now, we will skip building of a gcc package if it is a uclibc one
+# and our build is not a uclibc one, and we skip a glibc one if our build
+# is a uclibc build.
+#
+# See the note in gcc/gcc_3.4.0.oe
+#
+
+python __anonymous () {
+    import bb, re
+    uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
+    if uc_os:
+        raise bb.parse.SkipPackage("incompatible with target %s" %
+                                   bb.data.getVar('TARGET_OS', d, 1))
+}
+
+EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
+                --without-cvs --disable-profile --disable-debug --without-gd \
+                --enable-clocale=gnu \
+                --enable-add-ons=${GLIBC_ADDONS},ports \
+                --with-headers=${STAGING_INCDIR} \
+                --without-selinux \
+                ${GLIBC_EXTRA_OECONF}"
+
+EXTRA_OECONF += "${@get_eglibc_fpu_setting(bb, d)}"
+
+do_unpack_append() {
+	bb.build.exec_func('do_move_ports', d)
+}
+
+do_move_ports() {
+        if test -d ${WORKDIR}/${EGLIBC_BRANCH}/ports ; then
+	    rm -rf ${S}/ports
+	    mv ${WORKDIR}/${EGLIBC_BRANCH}/ports ${S}/
+	fi
+}
+
+do_configure () {
+# override this function to avoid the autoconf/automake/aclocal/autoheader
+# calls for now
+# don't pass CPPFLAGS into configure, since it upsets the kernel-headers
+# version check and doesn't really help with anything
+        if [ -z "`which rpcgen`" ]; then
+                echo "rpcgen not found.  Install glibc-devel."
+                exit 1
+        fi
+        (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
+        find ${S} -name "configure" | xargs touch
+        CPPFLAGS="" oe_runconf
+}
+
+rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
+	  yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
+	  rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
+
+do_compile () {
+	# -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
+	unset LDFLAGS
+	base_do_compile
+	(
+		cd ${S}/sunrpc/rpcsvc
+		for r in ${rpcsvc}; do
+			h=`echo $r|sed -e's,\.x$,.h,'`
+			rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
+		done
+	)
+}
+
+require eglibc-stage.inc
+
+require eglibc-package.bbclass
diff --git a/recipes/eglibc/eglibc_2.9.bb b/recipes/eglibc/eglibc_2.9.bb
index 7a82627..792ca83 100644
--- a/recipes/eglibc/eglibc_2.9.bb
+++ b/recipes/eglibc/eglibc_2.9.bb
@@ -6,7 +6,7 @@ PV = "2.9"
 PR = "${INC_PR}.6"
 SVN_REV="8690"
 EGLIBC_BRANCH="eglibc-2_9"
-SRC_URI = "svn://svn.eglibc.org/branches;module=eglibc-2_9;rev=${SVN_REV};proto=svn \
+SRC_URI = "svn://svn.eglibc.org/branches;module=${EGLIBC_BRANCH};rev=${SVN_REV};proto=svn \
            file://eglibc-svn-arm-lowlevellock-include-tls.patch;patch=1 \
 	   file://armv4t-interworking.patch;patch=1 \
 	   file://IO-acquire-lock-fix.patch;patch=1 \
diff --git a/recipes/eglibc/eglibc_svn.bb b/recipes/eglibc/eglibc_svn.bb
index 08f280a..460af5a 100644
--- a/recipes/eglibc/eglibc_svn.bb
+++ b/recipes/eglibc/eglibc_svn.bb
@@ -1,15 +1,14 @@
 require eglibc.inc
 
 DEPENDS += "gperf-native"
-SRCREV = "9191"
+SRCREV = "9241"
 DEFAULT_PREFERENCE = "-1"
 FILESPATHPKG =. "eglibc-svn:"
-PV = "2.10+svnr${SRCREV}"
-PR = "${INC_PR}.2"
+PV = "2.11+svnr${SRCREV}"
+PR = "${INC_PR}.3"
 EGLIBC_BRANCH="trunk"
-SRC_URI = "svn://svn.eglibc.org;module=trunk \
+SRC_URI = "svn://svn.eglibc.org;module=${EGLIBC_BRANCH} \
            file://eglibc-svn-arm-lowlevellock-include-tls.patch;patch=1 \
-	   file://armv4t-interworking.patch;patch=1 \
 	   file://IO-acquire-lock-fix.patch;patch=1 \
            file://etc/ld.so.conf \
            file://generate-supported.mk"



