[oe-commits] Frans Meulenbroeks : mythtv: created recipe for 0.22rc1 ( based upon svn version)

[git version control]

Module: openembedded.git
Branch: org.openembedded.dev
Commit: c5704e55e6b03cbe9933950873bd7e59dc42c920
URL:    http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=c5704e55e6b03cbe9933950873bd7e59dc42c920

Author: Frans Meulenbroeks <fransmeulenbroeks at gmail.com>
Date:   Wed Oct 28 16:39:24 2009 +0100

mythtv: created recipe for 0.22rc1 (based upon svn version)
DEFAULT_PREFERENCE=-1, still need to look at the patches from 0.21
builds for beagleboard, not for sheevaplug (armv5te)

---

 conf/checksums.ini               |    4 ++
 recipes/mythtv/mythtv_0.22rc1.bb |   86 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+), 0 deletions(-)

diff --git a/conf/checksums.ini b/conf/checksums.ini
index 1fbfb61..bbaf3cd 100644
--- a/conf/checksums.ini
+++ b/conf/checksums.ini
@@ -18674,6 +18674,10 @@ sha256=777ff60afa89426f0e52e49b0e7a7661ddb45b59d2ebbfdcbe07fd179e526ff3
 md5=49fc135e1cde90cd935c1229467fa37e
 sha256=33a878a8fc3efdd74519b09b4ec3d16fa9d3a0436b321c13344e5f3ab723c5e4
 
+[ftp://ftp.osuosl.org/pub/mythtv/mythtv-0.22rc1.tar.bz2]
+md5=049e93d78d5370351539c9a23b47e1af
+sha256=8e6823f4b92d88c837735322ca71199919406a2826bddae257c6e0f52d089cd7
+
 [http://kldp.net/frs/download.php/3742/nabi-0.17.tar.gz]
 md5=8746890ea666ac1b7ae6db77993c6592
 sha256=1a239a7bb0644441ca781459fbf5a1c5fb95e823351bf308aa680eb60cc45b94
diff --git a/recipes/mythtv/mythtv_0.22rc1.bb b/recipes/mythtv/mythtv_0.22rc1.bb
new file mode 100644
index 0000000..d8b6868
--- /dev/null
+++ b/recipes/mythtv/mythtv_0.22rc1.bb
@@ -0,0 +1,86 @@
+require mythtv.inc
+
+inherit qmake2 qt4x11
+
+DEFAULT_PREFERENCE = "-1"
+
+PR = "r0"
+
+SRC_URI = "ftp://ftp.osuosl.org/pub/mythtv/mythtv-${PV}.tar.bz2"
+
+#S = "${WORKDIR}/mythtv"
+
+QMAKE_PROFILES = "mythtv.pro"
+
+mythlibs = "mythdb mythavutil mythavcodec mythavformat mythswscale mythhdhomerun myth mythtv mythui mythfreemheg mythupnp mythlivemedia"
+PACKAGES =+ "mythtv-backend mythtv-frontend mythtv-bin mythtv-filters mythtv-data"
+
+FILES_${PN}-dbg += "${libdir}/mythtv/filters/.debug"
+FILES_mythtv-backend = "${bindir}/mythbackend ${bindir}/mythcommflag ${bindir}/mythfilldatabase ${bindir}/mythtranscode"
+FILES_mythtv-frontend = "${bindir}/mythfrontend ${datadir}/mythtv/i18n/mythfrontend_* ${datadir}/mythtv/*.ttf"
+FILES_mythtv-bin = "${bindir}/*"
+FILES_mythtv-filters = "${libdir}/mythtv/filters/*"
+FILES_mythtv-data = "${datadir}"
+RDEPENDS_${PN} = "mythtv-backend mythtv-frontend mythtv-bin mythtv-filters mythtv-data"
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGES_DYNAMIC = "mythtv-theme-*"
+
+python __anonymous () {
+    import bb
+
+    mythlibs = bb.data.getVar('mythlibs', d).split()
+    pv = bb.data.expand(bb.data.getVar("REALPV", d), d)
+
+    for m in mythlibs:
+        bb.data.setVar("FILES_lib%s%s" % (m, pv), "${libdir}/lib%s-%s.so.*" % (m, pv), d)
+        bb.data.setVar("FILES_lib%s%s-dev" % (m, pv), "${libdir}/lib%s-%s.*" % (m, pv), d)
+
+    packages = " ".join(map(lambda x: "lib%s%s lib%s%s-dev" % (x, pv, x, pv), mythlibs) + bb.data.getVar("PACKAGES", d).split())
+
+    bb.data.setVar("PACKAGES", packages, d)
+}
+
+EXTRA_MYTHTVCONF_armv7a  = "--cpu=cortex-a8"
+EXTRA_MYTHTVCONF ?= ""
+
+EXTRA_OECONF = " \
+        --cross-prefix=${TARGET_PREFIX} \
+        --sysroot=${STAGING_DIR_HOST} \
+        --prefix=${prefix} \
+        \
+        --arch=${TARGET_ARCH} \
+        --extra-cflags="${TARGET_CFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
+        --extra-cxxflags="${TARGET_CXXFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
+        --extra-ldflags="${TARGET_LDFLAGS}" \
+        ${EXTRA_MYTHTVCONF} \
+"
+
+do_configure_prepend() {
+# it's not autotools anyway, so we call ./configure directly
+	find . -name "Makefile"|xargs rm -f
+
+	./configure     --qmake=qmake2          \
+			--disable-altivec	\
+		 	--disable-opengl	\
+			--disable-stripping	\
+			--disable-xvmc		\
+			--enable-v4l		\
+			--enable-audio-oss	\
+			--enable-dvb		\
+			--enable-libmp3lame \
+            --dvb-path=${STAGING_INCDIR} \
+			--without-bindings=perl,python \
+			${EXTRA_OECONF}
+}
+
+python populate_packages_prepend () {
+	new_packages = []
+
+	def the_hook(file, pkg, pattern, format, basename):
+		new_packages.append(pkg)
+
+	do_split_packages(d, root=bb.data.expand('${datadir}/mythtv/themes', d), file_regex='(.*)', output_pattern='mythtv-theme-%s', description='MythTV theme %s', allow_dirs=True, hook=the_hook, prepend=True)
+
+	bb.data.setVar("RDEPENDS_${PN}", "%s %s" % (bb.data.getVar("RDEPENDS_${PN}", d), " ".join(new_packages)), d)
+}