[oe-commits] Frans Meulenbroeks : lmbench: added 3.0-a9 version

[git version control]

Module: openembedded.git
Branch: org.openembedded.dev
Commit: 3c886c48160b9f204b24b6e680b9a1cc7a3ddcba
URL:    http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=3c886c48160b9f204b24b6e680b9a1cc7a3ddcba

Author: Frans Meulenbroeks <fransmeulenbroeks at gmail.com>
Date:   Wed Aug 25 10:19:19 2010 +0200

lmbench: added 3.0-a9 version

kept 2.5 so people who want to compare results still can build
that version if desired

Signed-off-by: Frans Meulenbroeks <fransmeulenbroeks at gmail.com>

---

 recipes/lmbench/lmbench_3.0-a9.bb |   56 +++++++++++++++++++++++++++++++++++++
 1 files changed, 56 insertions(+), 0 deletions(-)

diff --git a/recipes/lmbench/lmbench_3.0-a9.bb b/recipes/lmbench/lmbench_3.0-a9.bb
new file mode 100644
index 0000000..d058849
--- /dev/null
+++ b/recipes/lmbench/lmbench_3.0-a9.bb
@@ -0,0 +1,56 @@
+SECTION = "console/utils"
+DESCRIPTION = "Tools for performance analysis."
+LICENSE = "GPL"
+RDEPENDS_${PN} = "debianutils"
+
+PR = "r0"
+
+inherit autotools
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/lmbench/lmbench-${PV}.tgz \
+	   file://lmbench-run"
+SRC_URI[md5sum] = "b3351a3294db66a72e2864a199d37cbf"
+SRC_URI[sha256sum] = "cbd5777d15f44eab7666dcac418054c3c09df99826961a397d9acf43d8a2a551"
+
+S = "${WORKDIR}/lmbench-${PV}"
+
+EXTRA_OEMAKE = 'CC="${CC}" AR="${AR}" CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" LD="${LD}" OS="${TARGET_SYS}" \
+		TARGET="${TARGET_OS}" BASE="${prefix}"'
+
+
+python do_unpack () {
+	bb.build.exec_func('base_do_unpack', d)
+	bb.build.exec_func('byebk_do_unpack', d)
+}
+
+byebk_do_unpack () {
+	find ${S}/.. -name BitKeeper -o -name SCCS | xargs rm -rf
+}
+
+do_configure() {
+	:
+}
+
+do_compile () {
+	. ${CONFIG_SITE}
+	if [ X"$ac_cv_uint" == X"yes" ]; then
+		CFLAGS="${CFLAGS} -DHAVE_uint"
+	fi
+	install -d ${S}/bin/${TARGET_SYS}
+	oe_runmake -C src
+	sed -i -e 's,^SHAREDIR=.*$,SHAREDIR=${datadir}/${PN},;' \
+	       -e 's,^BINDIR=.*$,BINDIR=${libdir}/${PN},;' ${WORKDIR}/lmbench-run
+}
+
+do_install () {
+        mkdir -p ${D}${libdir}/lmbench
+	oe_runmake 'BASE=${D}${prefix}' \
+		    -C src install
+	install -d ${D}${localstatedir}/lib/lmbench/config \
+		   ${D}${localstatedir}/run/lmbench \
+		   ${D}${bindir}
+	install -m 0755 ${WORKDIR}/lmbench-run ${D}${bindir}/
+	mkdir -p ${D}${mandir}
+	mv ${D}${prefix}/man/* ${D}${mandir}/
+}