[oe-commits] Roman I Khimov : cluster-resource-agents: add new recipe
git version control
git at git.openembedded.org
Mon Mar 29 19:08:23 UTC 2010
Module: openembedded.git
Branch: shr/unstable
Commit: c5497549b9caf94be40a938b6dfcfb664ce5f186
URL: http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=c5497549b9caf94be40a938b6dfcfb664ce5f186
Author: Roman I Khimov <khimov at altell.ru>
Date: Mon Mar 22 18:48:23 2010 +0300
cluster-resource-agents: add new recipe
A resource agent is a standardized interface for a cluster resource.
In translates a standard set of operations into steps specific to the
resource or application, and interprets their results as success or
failure.
Signed-off-by: Roman I Khimov <khimov at altell.ru>
---
recipes/linux-ha/cluster-resource-agents_1.0.2.bb | 70 +++++++++++++++++++++
1 files changed, 70 insertions(+), 0 deletions(-)
diff --git a/recipes/linux-ha/cluster-resource-agents_1.0.2.bb b/recipes/linux-ha/cluster-resource-agents_1.0.2.bb
new file mode 100644
index 0000000..cdc8165
--- /dev/null
+++ b/recipes/linux-ha/cluster-resource-agents_1.0.2.bb
@@ -0,0 +1,70 @@
+DESCRIPTION = "OCF resource agents for use by compatible cluster managers"
+LICENSE = "GPL"
+DEPENDS = "cluster-glue"
+
+SRC_URI = "http://hg.linux-ha.org/agents/archive/agents-${PV}.tar.bz2;name=tar"
+SRC_URI[tar.md5sum] = "b536dea1b1f642bdc3607cb85ea0b89d"
+SRC_URI[tar.sha256sum] = "c5a1ea9a83c578672cd475ab4af5c2e40736669bae0eb70bb9bb6124074e5e5e"
+
+inherit autotools_stage
+
+S = "${WORKDIR}/Cluster-Resource-Agents-agents-${PV}"
+
+# ARM build fails on send_arp.linux.c with
+#
+# cc1: warnings being treated as errors
+# send_arp.linux.c: In function 'send_pack':
+# send_arp.linux.c:106: error: cast increases required alignment of target type
+# send_arp.linux.c: In function 'recv_pack':
+# send_arp.linux.c:207: error: cast increases required alignment of target type
+#
+# The code itself doesn't look that bad, so just disable -Werror
+EXTRA_OECONF_arm += "--disable-fatal-warnings"
+
+PACKAGES =+ "ldirectord ldirectord-doc"
+
+FILES_ldirectord = " \
+ ${sbindir}/ldirectord \
+ ${sysconfdir}/ha.d/resource.d/ldirectord \
+ ${sysconfdir}/init.d/ldirectord \
+ ${sysconfdir}/logrotate.d/ldirectord \
+ ${libdir}/ocf/resource.d/heartbeat/ldirectord \
+ "
+FILES_ldirectord-doc = "${mandir}/man8/ldirectord.8*"
+
+# Missing:
+# Authen::Radius
+# Net::LDAP
+# Net::IMAP::Simple::SSL
+# Net::IMAP::Simple
+RDEPENDS_ldirectord += " \
+ libdbi-perl \
+ libmailtools-perl \
+ libnet-dns-perl \
+ libsocket6-perl \
+ libwww-perl \
+ perl \
+ perl-module-getopt-long \
+ perl-module-net-ftp \
+ perl-module-net-smtp \
+ perl-module-pod-usage \
+ perl-module-posix \
+ perl-module-socket \
+ perl-module-strict \
+ perl-module-sys-hostname \
+ perl-module-sys-syslog \
+ perl-module-vars \
+ "
+
+FILES_${PN} += " \
+ /usr/lib/heartbeat/findif \
+ /usr/lib/heartbeat/ocf-returncodes \
+ /usr/lib/heartbeat/ocf-shellfuncs \
+ /usr/lib/heartbeat/send_arp \
+ /usr/lib/heartbeat/sfex_daemon \
+ /usr/lib/heartbeat/tickle_tcp \
+ /usr/lib/ocf/resource.d/heartbeat/ \
+ /usr/share/resource-agents/ra-api-1.dtd \
+ "
+
+FILES_${PN}-dbg += "/usr/lib/heartbeat/.debug/"
More information about the Openembedded-commits
mailing list