[oe-commits] Denis 'GNUtoo' Carikli : gnash : add 0.8.8 version

[git version control]

Module: openembedded.git
Branch: org.openembedded.dev
Commit: 36fa802068c749e833c92cfdfb6a0f6334d3a6f0
URL:    http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=36fa802068c749e833c92cfdfb6a0f6334d3a6f0

Author: Denis 'GNUtoo' Carikli <GNUtoo at no-log.org>
Date:   Sun Nov 21 22:26:00 2010 +0100

gnash : add 0.8.8 version

The 0.8.8 version fixes youtube.

Note that I had to add one more include:
  -I${STAGING_INCDIR}/cairo
Because gnash didn't find cairo:
  | ../sysroots/armv7a-oe-linux-gnueabi/usr/include/gtk-2.0/gdk/gdkscreen.h:31:19: fatal error: cairo.h: No such file or directory
Note that gnashes disables pkg-config during cross-compilation:
  Nov 19 18:09:46 <strk>  IIRC we _never_ use pkgconfig when crossbuilding
>From #gnash in Freenode on irc.

I also had to add that:
  --with-npapi-plugindir=${libdir}/mozilla/plugins \
else the plugin would have been installed in:
  image/usr/lib64/mozilla/plugins/libgnashplugin.so
which is a path made using the host libdir(I've a 64bit buildhost)

Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo at no-log.org>

---

 recipes/gnash/gnash_0.8.8.bb |   54 ++++++++++++++++++++++++++++++++++++++++++
 1 files changed, 54 insertions(+), 0 deletions(-)

diff --git a/recipes/gnash/gnash_0.8.8.bb b/recipes/gnash/gnash_0.8.8.bb
new file mode 100644
index 0000000..a244e11
--- /dev/null
+++ b/recipes/gnash/gnash_0.8.8.bb
@@ -0,0 +1,54 @@
+DESCRIPTION = "Gnash is a GNU Flash movie player that supports many SWF v8 features"
+HOMEPAGE = "http://www.gnu.org/software/gnash"
+LICENSE = "GPLv3"
+DEPENDS = "giflib cairo libtool gtk+ agg libsdl-mixer zlib boost jpeg pango curl freetype \
+           ${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'ffmpeg', d)} speex"
+DEPENDS += "gst-plugins-base"
+
+PR = "r0"
+
+SRC_URI = "ftp://ftp.gnu.org/gnu/${PN}/${PV}/${P}.tar.bz2"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--enable-gui=gtk \
+                --enable-renderer=agg \
+                ${@base_conditional('ENTERPRISE_DISTRO', '1', '', '--enable-media=ffmpeg', d)} \
+                --with-plugins-install=system \
+		--enable-plugins \
+                --disable-dependency-tracking \
+                --disable-testsuite \
+                --enable-media=ffmpeg \
+                --with-speex-incl=${STAGING_INCDIR}/speex/ \
+                --with-jpeg-incl=${STAGING_INCDIR} \
+                --with-jpeg-lib=${STAGING_LIBDIR} \
+                --with-top-level=${STAGING_DIR_HOST}/usr \
+		--disable-avm2 \
+		--with-npapi-plugindir=${libdir}/mozilla/plugins \
+		"
+
+PACKAGES =+ " gnash-browser-plugin libgnashamf libgnashbackend libgnashbase libgnashgeo libgnashgui libgnashplayer libgnashserver "
+
+FILES_gnash-browser-plugin= "${libdir}/mozilla/plugins/*"
+FILES_libgnashamf = "${libdir}/gnash/libgnashamf-${PV}.so"
+FILES_libgnashbackend = "${libdir}/gnash/libgnashbackend-${PV}.so"
+FILES_libgnashbase = "${libdir}/gnash/libgnashbase-${PV}.so"
+FILES_libgnashgeo = "${libdir}/gnash/libgnashgeo-${PV}.so"
+FILES_libgnashgui = "${libdir}/gnash/libgnashgui-${PV}.so"
+FILES_libgnashplayer = "${libdir}/gnash/libgnashplayer-${PV}.so"
+FILES_libgnashserver = "${libdir}/gnash/libgnashserver-${PV}.so"
+
+RDEPENDS_${PN}-browser-plugin += "${PN}"
+
+acpaths = " -Imacros"
+
+# Boost lacks defines for lots of archs
+TARGET_CC_ARCH_append = " -I${STAGING_INCDIR}/cairo -I${STAGING_INCDIR}/libxml2 -DHAVE_POLL_H ${@[' -D_BIG_ENDIAN', ' -D_LITTLE_ENDIAN'][bb.data.getVar('SITEINFO_ENDIANNESS', d, 1) == 'le']}"
+
+
+do_install_append() {
+	oe_runmake DESTDIR=${D} install-plugin
+}
+
+SRC_URI[md5sum] = "ce57f66e222f7eb1adf7f7b4a1274612"
+SRC_URI[sha256sum] = "dcac4b81f81ecd6cc7c5422d7c731fc5c2a7be7fb18b5570a7e6f8fb5fc6e220"