[oe-commits] Holger Hans Peter Freyther : qt4-tools-sdk: Add a Qt 4.7.0 version, create a .inc file for reuse.

[git version control]

Module: openembedded.git
Branch: master
Commit: dee46c3eb9f6b09ba129a75f40d7769d6f573e84
URL:    http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=dee46c3eb9f6b09ba129a75f40d7769d6f573e84

Author: Holger Hans Peter Freyther <zecke at selfish.org>
Date:   Tue Sep 28 21:27:48 2010 +0800

qt4-tools-sdk: Add a Qt 4.7.0 version, create a .inc file for reuse.

---

 recipes/qt4/qt4-tools-sdk.inc      |   86 ++++++++++++++++++++++++++++++++++++
 recipes/qt4/qt4-tools-sdk_4.7.0.bb |    6 +++
 2 files changed, 92 insertions(+), 0 deletions(-)

diff --git a/recipes/qt4/qt4-tools-sdk.inc b/recipes/qt4/qt4-tools-sdk.inc
new file mode 100644
index 0000000..9093afb
--- /dev/null
+++ b/recipes/qt4/qt4-tools-sdk.inc
@@ -0,0 +1,86 @@
+DESCRIPTION = "SDK tools for Qt/[X11|Mac|Embedded] version 4.x"
+DEPENDS = "zlib-native dbus-native"
+SECTION = "libs"
+HOMEPAGE = "http://www.trolltech.com"
+PRIORITY = "optional"
+LICENSE = "LGPLv2.1 GPLv3"
+
+PR = "r1"
+
+FILESPATHPKG =. "qt-${PV}:"
+inherit sdk
+
+SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-everywhere-opensource-src-${PV}.tar.gz \
+           file://configure-lflags.patch \
+           file://qt-config.patch \
+           file://g++.conf \
+           file://linux.conf"
+
+S = "${WORKDIR}/qt-everywhere-opensource-src-${PV}"
+
+
+# FIXME: make it work with "${STAGING_BINDIR_NATIVE}/pkg-config --cflags dbus-1"
+EXTRA_OECONF = "-prefix ${prefix} \
+                -qt-libjpeg -qt-gif -system-zlib \
+                -no-libjpeg -no-libpng \
+                -no-accessibility \
+                -no-cups \
+                -no-exceptions  \
+                -no-nas-sound \
+                -no-nis \
+                -verbose -release -fast -static \
+                -qt3support \
+                -I${STAGING_DIR_NATIVE}/usr/include \
+                -I${STAGING_DIR_NATIVE}/usr/include/dbus-1.0 \
+                -I${STAGING_DIR_NATIVE}/usr/lib/dbus-1.0/include"
+
+# yank default -e, otherwise we get the following error:
+# moc_qbuffer.cpp: No such file or directory
+EXTRA_OEMAKE = " "
+
+do_configure() {
+   (echo o; echo yes) | ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
+}
+
+TOBUILD = "\
+  src/tools/bootstrap \
+  src/tools/moc \
+  src/corelib \
+  src/sql \
+  src/dbus \
+  src/qt3support \
+  src/xml \
+  src/tools/uic \
+  src/tools/rcc \
+  src/network \
+  src/gui \
+  src/tools/uic3 \
+  tools/linguist/lrelease \
+  tools/linguist/lupdate \
+  tools/qdbus \
+"
+
+do_compile() {
+    for i in ${TOBUILD}; do
+        cd ${S}/$i && oe_runmake CC="${CC}" CXX="${CXX}"
+    done
+}
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 0755 bin/qmake ${D}${bindir}/qmake2
+    for i in moc uic uic3 rcc lrelease lupdate qdbuscpp2xml qdbusxml2cpp; do
+        install -m 0755 bin/${i} ${D}${bindir}/${i}4
+    done
+
+	(cd ${D}${bindir}; \
+	ln -s qmake2 qmake; \
+	for i in moc uic uic3 rcc lrelease lupdate qdbuscpp2xml qdbusxml2cpp; do \
+		ln -s ${i}4 ${i}; \
+	done)
+
+	# make a symbolic link to mkspecs for compatibility with Nokia's SDK
+	# and QTCreator
+	(cd ${D}${bindir}/..; ln -s ${TARGET_SYS}/usr/share/qtopia/mkspecs mkspecs;)
+}
+
diff --git a/recipes/qt4/qt4-tools-sdk_4.7.0.bb b/recipes/qt4/qt4-tools-sdk_4.7.0.bb
new file mode 100644
index 0000000..7b90a21
--- /dev/null
+++ b/recipes/qt4/qt4-tools-sdk_4.7.0.bb
@@ -0,0 +1,6 @@
+require qt4-tools-sdk.inc
+
+DEFAULT_PREFERENCE = "-1"
+
+SRC_URI[md5sum] = "3a2f25b9b115037277f4fb759194a7a5"
+SRC_URI[sha256sum] = "e05256d560ca7d674cd4310bb791748900ad14ad662cbfe22b6d72ada43e7955"