[oe-commits] Brijesh Singh : ti-c6accel_1.00.00.04: add new recipe
git version control
git at git.openembedded.org
Thu Sep 30 11:21:27 UTC 2010
Module: openembedded.git
Branch: org.openembedded.dev
Commit: a26253b6567991a569b45ac762a5766ecb8763e4
URL: http://gitweb.openembedded.net/?p=openembedded.git&a=commit;h=a26253b6567991a569b45ac762a5766ecb8763e4
Author: Brijesh Singh <bksingh at ti.com>
Date: Thu Sep 2 13:32:24 2010 -0500
ti-c6accel_1.00.00.04: add new recipe
C6Accel codec package wraps key DSP software kernels which can be invoked from
the ARM side using simple API calls. This codec can be used in a plug and play
like any other codec used for encoding and decoding audio and video streams.
Signed-off-by: Brijesh Singh <bksingh at ti.com>
Signed-off-by: Denys Dmytriyenko <denis at denix.org>
Signed-off-by: Roger Monk <r-monk at ti.com>
Signed-off-by: Koen Kooi <k-kooi at ti.com>
---
recipes/ti/ti-c6accel.inc | 82 +++++++++++++++++++++++++++++++++++
recipes/ti/ti-c6accel_1.00.00.04.bb | 7 +++
recipes/ti/ti-paths.inc | 2 +
3 files changed, 91 insertions(+), 0 deletions(-)
diff --git a/recipes/ti/ti-c6accel.inc b/recipes/ti/ti-c6accel.inc
new file mode 100644
index 0000000..c7f2243
--- /dev/null
+++ b/recipes/ti/ti-c6accel.inc
@@ -0,0 +1,82 @@
+DESCRIPTION = "TI C6Accel - DSP Software Libraries on ARM"
+HOMEPAGE = "https://gforge01.dal.design.ti.com/gf/project/dsplib4arm/"
+
+SECTION = "devel"
+LICENSE = "TI TSPA"
+
+require ti-paths.inc
+require ti-staging.inc
+require ti-eula-unpack.inc
+
+PLATFORM_omapl138 = "omapl138"
+PLATFORM_omap3 = "omap3530"
+PLATFORM ?= "<UNDEFINED_PLATFORM>"
+
+COMPATIBLE_MACHINE = "(da850-omapl138-evm|omap3evm|dm37x-evm)"
+
+PROVIDES += "ti-c6accel-apps"
+
+PR = "r8"
+
+S = "${WORKDIR}/c6accel_${PV}/c6accel_${PV}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/c6000/web/c6accel/latest/exports//c6accel_${PV}_Linux-x86_Setup.bin;name=c6accelbin "
+
+BINFILE="c6accel_${PV}_Linux-x86_Setup.bin"
+TI_BIN_UNPK_CMDS="Y:workdir"
+
+DEPENDS = "ti-codec-engine ti-xdais ti-dsplink ti-dspbios"
+DEPENDS += "ti-edma3lld ti-cgt6x ti-xdctools ti-framework-components"
+DEPENDS += "ti-biosutils"
+
+do_compile() {
+ # Build C6Accel package
+ cd ${S}
+ PLATFORM="${PLATFORM}" make \
+ PLATFORM="${PLATFORM}" \
+ CE_INSTALL_DIR="${CE_INSTALL_DIR}" \
+ XDAIS_INSTALL_DIR="${XDAIS_INSTALL_DIR}" \
+ LINK_INSTALL_DIR="${LINK_INSTALL_DIR}" \
+ CMEM_INSTALL_DIR="${CMEM_INSTALL_DIR}" \
+ EDMA3_LLD_INSTALL_DIR="${EDMA3_LLD_INSTALL_DIR}" \
+ CODEGEN_INSTALL_DIR="${CODEGEN_INSTALL_DIR}" \
+ XDC_INSTALL_DIR="${XDC_INSTALL_DIR}" \
+ FC_INSTALL_DIR="${FC_INSTALL_DIR}" \
+ BIOS_INSTALL_DIR="${BIOS_INSTALL_DIR}" \
+ BIOSUTILS_INSTALL_DIR="${BIOSUTILS_INSTALL_DIR}" \
+ LPM_INSTALL_DIR="${LPM_INSTALL_DIR}" \
+ SERVER_INSTALL_DIR="${CODEC_INSTALL_DIR}" \
+ C6ACCEL_INSTALL_DIR="${S}/soc" \
+ CSTOOL_DIR="${TOOLCHAIN_PATH}" \
+ CSTOOLS_PREFIX="${TOOLCHAIN_PATH}/bin/${TARGET_PREFIX}" \
+ all
+
+}
+
+do_install() {
+ install -d ${D}${C6ACCEL_INSTALL_DIR_RECIPE}
+ cp -pPrf ${S}/* ${D}${C6ACCEL_INSTALL_DIR_RECIPE}
+
+ cd ${S}
+ make \
+ PLATFORM="${PLATFORM}" \
+ CMEM_INSTALL_DIR="${CMEM_INSTALL_DIR}" \
+ LINK_INSTALL_DIR="${LINK_INSTALL_DIR}" \
+ LPM_INSTALL_DIR="${LPM_INSTALL_DIR}" \
+ C6ACCEL_INSTALL_DIR="${S}/soc" \
+ EXEC_DIR_C6ACCEL="${D}/${installdir}/c6accel-apps" \
+ install
+
+ # replace insmod with modprobe
+ sed -i 's/insmod/modprobe/g' ${D}/${installdir}/c6accel-apps/loadmodules_${PLATFORM}_c6accel.sh
+ sed -i 's/.ko//g' ${D}/${installdir}/c6accel-apps/loadmodules_${PLATFORM}_c6accel.sh
+ # remove prebuilt *.ko files
+ rm -rf ${D}/${installdir}/c6accel-apps/*.ko
+
+}
+
+PACKAGES += "ti-c6accel-apps"
+FILES_ti-c6accel-apps = "${installdir}/c6accel-apps/*"
+INSANE_SKIP_ti-c6accel-apps = True
+RDEPENDS_ti-c6accel-apps += "ti-cmem-module ti-dsplink-module"
+
diff --git a/recipes/ti/ti-c6accel_1.00.00.04.bb b/recipes/ti/ti-c6accel_1.00.00.04.bb
new file mode 100644
index 0000000..e358a5e
--- /dev/null
+++ b/recipes/ti/ti-c6accel_1.00.00.04.bb
@@ -0,0 +1,7 @@
+require ti-c6accel.inc
+
+PV = "1_00_00_04"
+
+SRC_URI[c6accelbin.md5sum] = "a1146d7b23252b4ac2ff927d79dcdc4b"
+SRC_URI[c6accelbin.sha256sum] = "c558ad170315b8706a9639a056a38b12c42b8ae9bb909e6529591a69c82cc789"
+
diff --git a/recipes/ti/ti-paths.inc b/recipes/ti/ti-paths.inc
index 27400a1..024419f 100644
--- a/recipes/ti/ti-paths.inc
+++ b/recipes/ti/ti-paths.inc
@@ -20,6 +20,7 @@ export DSPLIB_INSTALL_DIR_RECIPE = "${installdir}/ti-dsplib-tree"
export DVSDK_DEMOS_INSTALL_DIR_RECIPE = "${installdir}/ti-dvsdk-demos-tree"
export BIOSPSP_INSTALL_DIR_RECIPE = "${installdir}/ti-biospsp-tree"
export AUDIO_SOC_INSTALL_DIR_RECIPE = "${installdir}/ti-audio-soc-example-tree"
+export C6ACCEL_INSTALL_DIR_RECIPE = "${installdir}/ti-c6accel-tree"
# This is where the tools will end up in staging provided PACKAGE_ARCH = ${MACHINE_ARCH} is set
export CODEGEN_INSTALL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}${CODEGEN_INSTALL_DIR_RECIPE}"
@@ -39,6 +40,7 @@ export DMAI_INSTALL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}${DMAI_IN
export CODEC_INSTALL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}${CODEC_INSTALL_DIR_RECIPE}"
export DSPLIB_INSTALL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}${DSPLIB_INSTALL_DIR_RECIPE}"
export BIOSPSP_INSTALL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}${BIOSPSP_INSTALL_DIR_RECIPE}"
+export C6ACCEL_INSTALL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}${C6ACCEL_INSTALL_DIR_RECIPE}"
DSPSUFFIX_omapl137 = "x674"
DSPSUFFIX_omapl138 = "x674"
More information about the Openembedded-commits
mailing list