[oe-commits] Koen Kooi : nodejs: add 0.6.1
git at git.openembedded.org
git at git.openembedded.org
Tue Nov 15 12:21:21 UTC 2011
Module: meta-openembedded.git
Branch: master
Commit: 6032d213fa6599678a4c737bc757785a7c35e382
URL: http://git.openembedded.org/?p=meta-openembedded.git&a=commit;h=6032d213fa6599678a4c737bc757785a7c35e382
Author: Koen Kooi <koen at dominion.thruhere.net>
Date: Mon Nov 14 19:04:44 2011 +0100
nodejs: add 0.6.1
Signed-off-by: Koen Kooi <koen at dominion.thruhere.net>
---
meta-oe/recipes-devtools/nodejs/nodejs_0.6.1.bb | 53 +++++++++++++++++++++++
1 files changed, 53 insertions(+), 0 deletions(-)
diff --git a/meta-oe/recipes-devtools/nodejs/nodejs_0.6.1.bb b/meta-oe/recipes-devtools/nodejs/nodejs_0.6.1.bb
new file mode 100644
index 0000000..22a215b
--- /dev/null
+++ b/meta-oe/recipes-devtools/nodejs/nodejs_0.6.1.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = "nodeJS Evented I/O for V8 JavaScript"
+HOMEPAGE = "http://nodejs.org"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5c2b22818f53dbcb43dee3cb4daf7845"
+
+DEFAULT_PREFERENCE = "-1"
+
+DEPENDS = "openssl"
+
+SRC_URI = "http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz"
+SRC_URI[md5sum] = "92b8085967110b0125c192634f127a2b"
+SRC_URI[sha256sum] = "b161050ed8cdb2d45f601181d146821e5535a8fcbf5978b2ff064e5476a8e606"
+
+S = "${WORKDIR}/node-v${PV}"
+
+# v8 errors out if you have set CCACHE
+CCACHE = ""
+
+# Node is way too cool to use proper autotools, so we install two wrappers to forcefully inject proper arch cflags to workaround waf+scons
+do_configure () {
+ echo '#!/bin/sh' > ${WORKDIR}/gcc
+ echo '${CC} $@' >> ${WORKDIR}/gcc
+
+ echo '#!/bin/sh' > ${WORKDIR}/g++
+ echo '${CXX} $@'>> ${WORKDIR}/g++
+
+ chmod +x ${WORKDIR}/gcc ${WORKDIR}/g++
+
+ sed -i -e s:\'/usr/lib:\'${STAGING_LIBDIR}:g wscript
+ sed -i -e s:\'/usr/local/lib:\'${STAGING_LIBDIR}:g wscript
+
+ export PATH=${WORKDIR}:${PATH}
+ export CC=gcc
+ export CXX=g++
+
+ ./configure --prefix=${prefix} --without-snapshot
+}
+
+do_compile () {
+ export PATH=${WORKDIR}:${PATH}
+ export CC=gcc
+ export CXX=g++
+ make
+}
+
+do_install () {
+ DESTDIR=${D} oe_runmake install
+}
+
+RDEPENDS_${PN} = "curl python-shell python-datetime python-subprocess python-crypt python-textutils python-netclient "
+
+FILES_${PN} += "${libdir}/node/wafadmin"
+BBCLASSEXTEND = "native"
More information about the Openembedded-commits
mailing list