[oe-commits] Otavio Salvador : distro_features_check.bbclass: Allow checking of required /conflicting features

[git at git.openembedded.org]

Module: openembedded-core.git
Branch: master-next
Commit: a7519be6a23869ebafbf712370dab86ab92f68a5
URL:    http://git.openembedded.org/?p=openembedded-core.git&a=commit;h=a7519be6a23869ebafbf712370dab86ab92f68a5

Author: Otavio Salvador <otavio at ossystems.com.br>
Date:   Thu Aug  1 19:13:57 2013 -0300

distro_features_check.bbclass: Allow checking of required/conflicting features

This add support to list required/confliting distro features for a
recipe; this avoids user mistake when building recipes/images which
would not work depending on DISTRO_FEATURES option set.

Adding:

,----[ Use example ]
| inherit distro_features_check
|
| REQUIRED_DISTRO_FEATURES = "x11"
| CONFLICT_DISTRO_FEATURES_mx6 = "wayland"
`----

In the image recipe allow us to make clear to user that this image
needs X11 and /cannot/ be build with Wayland support in i.MX6
platforms, for example.

Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
Signed-off-by: Saul Wold <sgw at linux.intel.com>

---

 meta/classes/distro_features_check.bbclass |   28 ++++++++++++++++++++++++++++
 1 files changed, 28 insertions(+), 0 deletions(-)

diff --git a/meta/classes/distro_features_check.bbclass b/meta/classes/distro_features_check.bbclass
new file mode 100644
index 0000000..61b11b7
--- /dev/null
+++ b/meta/classes/distro_features_check.bbclass
@@ -0,0 +1,28 @@
+# Allow checking of required and conflicting DISTRO_FEATURES
+#
+# REQUIRED_DISTRO_FEATURES: ensure every item on this list is included
+#                           in DISTRO_FEATURES.
+# CONFLICT_DISTRO_FEATURES: ensure no item in this list is included in
+#                           DISTRO_FEATURES.
+#
+# Copyright 2013 (C) O.S. Systems Software LTDA.
+
+python () {
+    required_distro_features = d.getVar('REQUIRED_DISTRO_FEATURES', True)
+    if required_distro_features:
+        required_distro_features = required_distro_features.split()
+        distro_features = (d.getVar('DISTRO_FEATURES', True) or "").split()
+        for f in required_distro_features:
+            if f in distro_features:
+                break
+        else:
+            raise bb.parse.SkipPackage("missing required distro feature %s (not in DISTRO_FEATURES)" % required_distro_features)
+
+    conflict_distro_features = d.getVar('CONFLICT_DISTRO_FEATURES', True)
+    if conflict_distro_features:
+        conflict_distro_features = conflict_distro_features.split()
+        distro_features = (d.getVar('DISTRO_FEATURES', True) or "").split()
+        for f in conflict_distro_features:
+            if f in distro_features:
+                raise bb.parse.SkipPackage("conflicting distro feature %s (in DISTRO_FEATURES)" % conflict_distro_features)
+}