[oe-commits] Laurentiu Palcu : add fontcache.bbclass
git at git.openembedded.org
git at git.openembedded.org
Wed Feb 6 09:38:02 UTC 2013
Module: openembedded-core.git
Branch: master
Commit: 0c12f7fb3c2c42e5b633682bb1277b943ac19ea6
URL: http://git.openembedded.org/?p=openembedded-core.git&a=commit;h=0c12f7fb3c2c42e5b633682bb1277b943ac19ea6
Author: Laurentiu Palcu <laurentiu.palcu at intel.com>
Date: Thu Jan 31 09:59:10 2013 +0200
add fontcache.bbclass
All font packages should inherit this class in order to generate the
proper postinst/postrm scriptlets.
The scriptlets will actually create a host intercept hook that will be
executed at the end, at do_rootfs time, after all packages have been
installed. This is good when there are many font packages.
[YOCTO #2923]
Signed-off-by: Laurentiu Palcu <laurentiu.palcu at intel.com>
Signed-off-by: Saul Wold <sgw at linux.intel.com>
---
meta/classes/fontcache.bbclass | 47 ++++++++++++++++++++++++++++++++++++++++
1 files changed, 47 insertions(+), 0 deletions(-)
diff --git a/meta/classes/fontcache.bbclass b/meta/classes/fontcache.bbclass
new file mode 100644
index 0000000..8381735
--- /dev/null
+++ b/meta/classes/fontcache.bbclass
@@ -0,0 +1,47 @@
+#
+# This class will generate the proper postinst/postrm scriptlets for font
+# packages.
+#
+
+DEPENDS += "qemu-native"
+inherit qemu
+
+FONT_PACKAGES ??= "${PN}"
+
+fontcache_common() {
+if [ "x$D" != "x" ] ; then
+ if [ ! -f $INTERCEPT_DIR/update_font_cache ]; then
+ cat << "EOF" > $INTERCEPT_DIR/update_font_cache
+#!/bin/sh
+
+${@qemu_run_binary(d, '$D', '/usr/bin/fc-cache')} --sysroot=$D >/dev/null 2>&1
+
+if [ $? -ne 0 ]; then
+ exit 1
+fi
+
+EOF
+ fi
+ exit 0
+fi
+
+fc-cache
+}
+
+python populate_packages_append() {
+ font_pkgs = d.getVar('FONT_PACKAGES', True).split()
+
+ for pkg in font_pkgs:
+ bb.note("adding fonts postinst and postrm scripts to %s" % pkg)
+ postinst = d.getVar('pkg_postinst_%s' % pkg, True) or d.getVar('pkg_postinst', True)
+ if not postinst:
+ postinst = '#!/bin/sh\n'
+ postinst += d.getVar('fontcache_common', True)
+ d.setVar('pkg_postinst_%s' % pkg, postinst)
+
+ postrm = d.getVar('pkg_postrm_%s' % pkg, True) or d.getVar('pkg_postrm', True)
+ if not postrm:
+ postrm = '#!/bin/sh\n'
+ postrm += d.getVar('fontcache_common', True)
+ d.setVar('pkg_postrm_%s' % pkg, postrm)
+}
More information about the Openembedded-commits
mailing list