[oe-commits] Khem Raj : luajit: Add recipes

[git at git.openembedded.org]

Module: meta-openembedded.git
Branch: master
Commit: 9aecf2944ea8646dfce4085622b4cc6427d2140c
URL:    http://git.openembedded.org/?p=meta-openembedded.git&a=commit;h=9aecf2944ea8646dfce4085622b4cc6427d2140c

Author: Khem Raj <raj.khem at gmail.com>
Date:   Sat Jan  5 19:41:10 2013 -0800

luajit: Add recipes

LuaJIT is for JIT'ting LUA code

Signed-off-by: Khem Raj <raj.khem at gmail.com>

---

 .../disable_lj_vm_foldarith_for_spe.patch          |   13 +++++
 meta-oe/recipes-devtools/luajit/luajit_2.0.0.bb    |   53 ++++++++++++++++++++
 2 files changed, 66 insertions(+), 0 deletions(-)

diff --git a/meta-oe/recipes-devtools/luajit/luajit-2.0.0/disable_lj_vm_foldarith_for_spe.patch b/meta-oe/recipes-devtools/luajit/luajit-2.0.0/disable_lj_vm_foldarith_for_spe.patch
new file mode 100644
index 0000000..c96fc77
--- /dev/null
+++ b/meta-oe/recipes-devtools/luajit/luajit-2.0.0/disable_lj_vm_foldarith_for_spe.patch
@@ -0,0 +1,13 @@
+Index: LuaJIT-2.0.0/src/lj_vmmath.c
+===================================================================
+--- LuaJIT-2.0.0.orig/src/lj_vmmath.c	2012-11-08 02:10:00.000000000 -0800
++++ LuaJIT-2.0.0/src/lj_vmmath.c	2012-11-19 22:15:28.613527136 -0800
+@@ -22,7 +22,7 @@
+ LJ_FUNCA double lj_vm_tanh(double x) { return tanh(x); }
+ #endif
+ 
+-#if !LJ_TARGET_X86ORX64
++#if !(LJ_TARGET_X86ORX64 || LJ_TARGET_PPCSPE)
+ double lj_vm_foldarith(double x, double y, int op)
+ {
+   switch (op) {
diff --git a/meta-oe/recipes-devtools/luajit/luajit_2.0.0.bb b/meta-oe/recipes-devtools/luajit/luajit_2.0.0.bb
new file mode 100644
index 0000000..ac769cf
--- /dev/null
+++ b/meta-oe/recipes-devtools/luajit/luajit_2.0.0.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = " a Just-In-Time Compiler for Lua"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=9511885992e4900014e3b13ca6372b7d"
+HOMEPAGE = "http://luajit.org"
+
+DEPENDS += "lua5.1"
+PR = "r0"
+SRC_URI = "http://luajit.org/download/LuaJIT-${PV}.tar.gz \
+           file://disable_lj_vm_foldarith_for_spe.patch \
+          "
+SRC_URI[md5sum] = "97a2b87cc0490784f54b64cfb3b8f5ad"
+SRC_URI[sha256sum] = "deaed645c4a093c5fb250c30c9933c9131ee05c94b13262d58f6e0b60b338c15"
+
+S = "${WORKDIR}/LuaJIT-${PV}"
+
+inherit pkgconfig binconfig
+
+do_configure_prepend() {
+	sed -i -e s:/usr/local:${prefix}:g ${S}/Makefile
+	sed -i -e s:/lib:${base_libdir}:g ${S}/Makefile
+}
+
+EXTRA_OEMAKE = 'CROSS=${HOST_PREFIX}'
+EXTRA_OEMAKE_append_powerpc = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_x86-64 = ' HOST_CC="${BUILD_CC}"'
+EXTRA_OEMAKE_append_i586 = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_powerpc64 = ' HOST_CC="${BUILD_CC}"'
+EXTRA_OEMAKE_append_arm = ' HOST_CC="${BUILD_CC} -m32"'
+EXTRA_OEMAKE_append_mips64 = ' HOST_CC="${BUILD_CC} -m32"'
+
+do_compile () {
+	oe_runmake
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+	rmdir ${D}${datadir}/lua/5.1 \
+	      ${D}${datadir}/lua \
+	      ${D}${libdir}/lua/5.1 \
+	      ${D}${libdir}/lua
+}
+
+PACKAGES += 'luajit-common'
+
+FILES_${PN} += "${libdir}/libluajit-5.1.so.2 \
+		${libdir}/libluajit-5.1.so.2.0.0 \
+	       "
+FILES_${PN}-dev += "${libdir}/libluajit-5.1.a \
+		    ${libdir}/libluajit-5.1.so \
+                    ${libdir}/pkgconfig/luajit.pc \
+                   "
+FILES_luajit-common = "${datadir}/${BPN}-${PV}"
+