[oe-commits] Hongxu Jia : netcf: fix offline rebuilding failed

[git at git.openembedded.org]

Module: meta-openembedded.git
Branch: master-next
Commit: 60c49640554b62afc8c9e5ce54db93b76b03f6c3
URL:    http://git.openembedded.org/?p=meta-openembedded.git&a=commit;h=60c49640554b62afc8c9e5ce54db93b76b03f6c3

Author: Hongxu Jia <hongxu.jia at windriver.com>
Date:   Fri Mar 14 16:36:47 2014 +0800

netcf: fix offline rebuilding failed

The netcf downloaded gnulib source to ${S} at the configure time,
while the network disconnected, if sstate cache was cleaned, the
netcf rebuilding failed.

Added a new recipe named 'gnulib' to download gnulib source to
${GITDIR} and populate it to the staging data dir.

So netcf could specify this local directory where gnulib sources
reside to save the bandwidth downloading.

Signed-off-by: Hongxu Jia <hongxu.jia at windriver.com>
Signed-off-by: Joe MacDonald <joe at deserted.net>

---

 .../recipes-support/netcf/gnulib_git.bb            | 35 ++++++++++++++++++++++
 meta-networking/recipes-support/netcf/netcf_git.bb |  5 ++--
 2 files changed, 38 insertions(+), 2 deletions(-)

diff --git a/meta-networking/recipes-support/netcf/gnulib_git.bb b/meta-networking/recipes-support/netcf/gnulib_git.bb
new file mode 100644
index 0000000..730f5cd
--- /dev/null
+++ b/meta-networking/recipes-support/netcf/gnulib_git.bb
@@ -0,0 +1,35 @@
+SUMMARY = "The GNU portability library"
+DESCRIPTION = "A collection of software subroutines which are designed to \
+be usable on many operating systems. The goal of the project \
+is to make it easy for free software authors to make their \
+software run on many operating systems. Since source is designed \
+to be copied from gnulib, it is not a library per-se, as much \
+as a collection of portable idioms to be used in other projects."
+
+HOMEPAGE = "http://www.gnu.org/software/gnulib/"
+SECTION = "libs"
+LICENSE = "LGPLv2+"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4cf3810f33a067ea7ccd2cd889fed21"
+SRCREV = "24379a9217fa4bd62685795aaaa010fd90ced9e3"
+SRC_URI = "git://git.sv.gnu.org/gnulib;protocol=git \
+"
+S = "${WORKDIR}/git"
+
+# Git clone a copy of gnulib source to the staging data dir
+sysroot_stage_all () {
+    [ -d ${STAGING_DATADIR}/gnulib/ ] && rm -rf ${STAGING_DATADIR}/gnulib/
+    cd ${S}
+    git checkout master
+    git clone ${S} ${STAGING_DATADIR}/gnulib
+}
+
+do_patch[noexec] = "1"
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+do_install[noexec] = "1"
+do_package[noexec] = "1"
+do_packagedata[noexec] = "1"
+do_package_write_ipk[noexec] = "1"
+do_package_write_deb[noexec] = "1"
+do_package_write_rpm[noexec] = "1"
diff --git a/meta-networking/recipes-support/netcf/netcf_git.bb b/meta-networking/recipes-support/netcf/netcf_git.bb
index 93f8c70..6c36ce8 100644
--- a/meta-networking/recipes-support/netcf/netcf_git.bb
+++ b/meta-networking/recipes-support/netcf/netcf_git.bb
@@ -12,7 +12,7 @@ PV = "0.2.3+git${SRCPV}"
 SRC_URI = "git://git.fedorahosted.org/netcf.git;protocol=git \
 "
 
-DEPENDS += "augeas libnl libxslt libxml2"
+DEPENDS += "augeas libnl libxslt libxml2 gnulib"
 
 S = "${WORKDIR}/git"
 
@@ -21,6 +21,7 @@ inherit gettext autotools
 EXTRA_OECONF_append_class-target = " --with-driver=redhat"
 do_configure_prepend() {
 	cd ${S}
-	./bootstrap
+	rm -f .gitmodules
+	./bootstrap --gnulib-srcdir=${STAGING_DATADIR}/gnulib
 }