[oe-commits] chase maupin : pm-qa: Add power management test utils
git at git.openembedded.org
git at git.openembedded.org
Wed Mar 26 20:50:11 UTC 2014
Module: meta-openembedded.git
Branch: master
Commit: c99803b0e50ebc7ac5dfec9efc92e493bb37d5c2
URL: http://git.openembedded.org/?p=meta-openembedded.git&a=commit;h=c99803b0e50ebc7ac5dfec9efc92e493bb37d5c2
Author: chase maupin <chase.maupin at ti.com>
Date: Fri Mar 21 09:06:53 2014 -0500
pm-qa: Add power management test utils
* The power management test utilities from Linaro can be used
to test multiple PM features such as cpufreq, cpuidle, thermal
control and suspend operations.
* These utilities are not platform specific and can be used by
a broader base of users.
Signed-off-by: Chase Maupin <Chase.Maupin at ti.com>
Signed-off-by: Martin Jansa <Martin.Jansa at gmail.com>
---
meta-oe/recipes-devtools/pm-qa/pm-qa_git.bb | 65 +++++++++++++++++++++++++++++
1 file changed, 65 insertions(+)
diff --git a/meta-oe/recipes-devtools/pm-qa/pm-qa_git.bb b/meta-oe/recipes-devtools/pm-qa/pm-qa_git.bb
new file mode 100644
index 0000000..4d33975
--- /dev/null
+++ b/meta-oe/recipes-devtools/pm-qa/pm-qa_git.bb
@@ -0,0 +1,65 @@
+DESCRIPTION = "Utilities for testing Power Management"
+HOMEPAGE = "https://wiki.linaro.org/WorkingGroups/PowerManagement/Resources/TestSuite/PmQa"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+PV = "0.4.8"
+
+BRANCH ?= "master"
+
+# Corresponds to tag pm-qa-v0.4.8
+SRCREV = "6a8c2ae8a6035b15a7fbe61b6ca56841e056fa37"
+
+SRC_URI = "git://git.linaro.org/tools/pm-qa.git;protocol=git;branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+CFLAGS += "-pthread"
+
+do_compile () {
+ # Find all the .c files in this project and build them.
+ for x in `find . -name "*.c"`
+ do
+ util=`echo ${x} | sed s/.c$//`
+ oe_runmake ${util}
+ done
+}
+
+do_install () {
+ install -d ${D}${bindir}
+ install -d ${D}${libdir}/${PN}
+
+ # Install the compiled binaries that were built in the previous step
+ for x in `find . -name "*.c"`
+ do
+ util=`echo ${x} | sed s/.c$//`
+ util_basename=`basename ${util}`
+ install -m 0755 ${util} ${D}${bindir}/${util_basename}
+ done
+
+ # Install the helper scripts in a subdirectory of $libdir
+ for script in `find . -name "*.sh" | grep include`
+ do
+ # Remove hardcoded relative paths
+ sed -i -e 's#..\/utils\/##' ${script}
+
+ script_basename=`basename ${script}`
+ install -m 0755 $script ${D}${libdir}/${PN}/${script_basename}
+ done
+
+ # Install the shell scripts NOT in the $libdir directory since those
+ # will be installed elsewhere
+ for script in `find . -name "*.sh" | grep -v include`
+ do
+ # if the script includes any helper scripts from the $libdir
+ # directory then change the source path to the absolute path
+ # to reflect the install location of the helper scripts.
+ sed -i -e "s#source ../include#source ${libdir}/${PN}#g" ${script}
+ # Remove hardcoded relative paths
+ sed -i -e 's#..\/utils\/##' ${script}
+
+ script_basename=`basename ${script}`
+ install -m 0755 $script ${D}${bindir}/${script_basename}
+ done
+}
More information about the Openembedded-commits
mailing list