[oe-commits] Bian Naimeng : waf-samba: add new class

[git at git.openembedded.org]

Module: meta-openembedded.git
Branch: master-next
Commit: 2615ad4e3d3dd2643538a990c460e65b3ca21561
URL:    http://git.openembedded.org/?p=meta-openembedded.git&a=commit;h=2615ad4e3d3dd2643538a990c460e65b3ca21561

Author: Bian Naimeng <biannm at cn.fujitsu.com>
Date:   Tue Jun 16 14:18:25 2015 +0900

waf-samba: add new class

waf-samba is a build system used by samba related software

Signed-off-by: Bian Naimeng <biannm at cn.fujitsu.com>

---

 meta-oe/classes/waf-samba.bbclass | 51 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/meta-oe/classes/waf-samba.bbclass b/meta-oe/classes/waf-samba.bbclass
new file mode 100644
index 0000000..23c5556
--- /dev/null
+++ b/meta-oe/classes/waf-samba.bbclass
@@ -0,0 +1,51 @@
+# waf is a build system which is used by samba related project.
+# Obtain details from https://wiki.samba.org/index.php/Waf
+# 
+inherit qemu pythonnative
+
+DEPENDS += "qemu-native libxslt-native docbook-xsl-stylesheets-native python"
+
+CONFIGUREOPTS = " --prefix=${prefix} \
+                  --bindir=${bindir} \
+                  --sbindir=${sbindir} \
+                  --libexecdir=${libexecdir} \
+                  --datadir=${datadir} \
+                  --sysconfdir=${sysconfdir} \
+                  --sharedstatedir=${sharedstatedir} \
+                  --localstatedir=${localstatedir} \
+                  --libdir=${libdir} \
+                  --includedir=${includedir} \
+                  --oldincludedir=${oldincludedir} \
+                  --infodir=${infodir} \
+                  --mandir=${mandir} \
+                "
+
+do_configure() {
+    qemu_binary="${@qemu_target_binary(d)}"
+    if [ ${qemu_binary} == "qemu-allarch" ]; then
+        qemu_binary="qemuwrapper"
+    fi
+
+    libdir_qemu="${STAGING_DIR_HOST}/${libdir}"
+    base_libdir_qemu="${STAGING_DIR_HOST}/${base_libdir}"
+    oldest_kernel_qemu=${OLDEST_KERNEL}
+
+    CROSS_EXEC="${qemu_binary} \
+                -r ${oldest_kernel_qemu} \
+                -L ${STAGING_DIR_HOST} \
+                -E LD_LIBRARY_PATH=${libdir_qemu}:${base_libdir_qemu}"
+
+    export BUILD_SYS=${BUILD_SYS}
+    export HOST_SYS=${HOST_SYS}
+    export BUILD_ARCH=${BUILD_ARCH}
+    export HOST_ARCH=${HOST_ARCH}
+    export STAGING_LIBDIR=${STAGING_LIBDIR}
+    export STAGING_INCDIR=${STAGING_INCDIR}
+    export PYTHONPATH=${STAGING_DIR_HOST}${PYTHON_SITEPACKAGES_DIR}
+
+    ./configure ${CONFIGUREOPTS} ${EXTRA_OECONF} --cross-compile --cross-execute="${CROSS_EXEC}"
+}
+
+do_install() {
+    oe_runmake install DESTDIR=${D}
+}