[oe-commits] [meta-openembedded] 44/52: ne10: add recipe

[git at git.openembedded.org]

martin_jansa pushed a commit to branch master-next
in repository meta-openembedded.

commit 472ba3392da36a0259e0d5f53c2049bac85709d1
Author: Carlos Rafael Giani <dv at pseudoterminal.org>
AuthorDate: Wed Feb 3 18:15:25 2016 +0100

    ne10: add recipe
    
    Add recipe for the Ne10 library ( http://projectne10.github.io/Ne10/ ).
    This library provides heavily ARM NEON optimized versions of functions
    that are commonly used.
    
    Signed-off-by: Carlos Rafael Giani <dv at pseudoterminal.org>
    Signed-off-by: Martin Jansa <Martin.Jansa at gmail.com>
---
 meta-oe/recipes-support/ne10/ne10_1.2.1.bb | 38 ++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/meta-oe/recipes-support/ne10/ne10_1.2.1.bb b/meta-oe/recipes-support/ne10/ne10_1.2.1.bb
new file mode 100644
index 0000000..5da3137
--- /dev/null
+++ b/meta-oe/recipes-support/ne10/ne10_1.2.1.bb
@@ -0,0 +1,38 @@
+DESCRIPTION = "Library containing NEON-optimized implementations for a common set of functions"
+HOMEPAGE = "http://projectne10.github.io/Ne10/"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=463ac0a7d64edc2b787c4206635ca2b1"
+SECTION = "libs"
+
+SRC_URI = "git://github.com/projectNe10/Ne10.git"
+SRCREV = "a08b29d88e3c94d32b5b8f827e7fcf0bc2b34ac2"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+NE10_TARGET_ARCH = ""
+EXTRA_OECMAKE = '-DGNULINUX_PLATFORM=ON -DNE10_BUILD_SHARED=ON -DNE10_LINUX_TARGET_ARCH="${NE10_TARGET_ARCH}"'
+
+COMPATIBLE_MACHINE_aarch64 = "(.*)"
+COMPATIBLE_MACHINE_armv7a = "(.*)"
+
+python () {
+    if any(t.startswith('armv7') for t in d.getVar('TUNE_FEATURES', True).split()):
+        d.setVar('NE10_TARGET_ARCH', 'armv7')
+        bb.note('Building Ne10 for armv7')
+    elif any(t.startswith('aarch64') for t in d.getVar('TUNE_FEATURES', True).split()):
+        d.setVar('NE10_TARGET_ARCH', 'aarch64')
+        bb.note('Building Ne10 for aarch64')
+    else:
+        raise bb.parse.SkipPackage("Incompatible with archs other than armv7 and aarch64")
+}
+
+do_install() {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    install -m 0644 ${S}/inc/NE10*.h ${D}${includedir}/
+    install -m 0644 ${B}/modules/libNE10.a ${D}${libdir}/
+    install -m 0755 ${B}/modules/libNE10.so.* ${D}${libdir}/
+    cp -a ${B}/modules/libNE10.so ${D}${libdir}/
+}

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.