[oe-commits] [openembedded-core] 13/41: gobject-introspection.bbclass: add a class that enables gobject introspection

[git at git.openembedded.org]

rpurdie pushed a commit to branch master-next
in repository openembedded-core.

commit e151256193e3cc816ae15a0daa0e32d7b770cb88
Author: Alexander Kanavin <alexander.kanavin at linux.intel.com>
AuthorDate: Wed Mar 9 17:01:52 2016 +0200

    gobject-introspection.bbclass: add a class that enables gobject introspection
    
    Signed-off-by: Alexander Kanavin <alexander.kanavin at linux.intel.com>
    Signed-off-by: Richard Purdie <richard.purdie at linuxfoundation.org>
---
 meta/classes/gobject-introspection.bbclass | 39 ++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

diff --git a/meta/classes/gobject-introspection.bbclass b/meta/classes/gobject-introspection.bbclass
new file mode 100644
index 0000000..ef51629
--- /dev/null
+++ b/meta/classes/gobject-introspection.bbclass
@@ -0,0 +1,39 @@
+# Inherit this class in recipes to enable building their introspection files
+
+# This allows disabling introspection support in recipes
+# (and therefore avoiding the use of qemu)
+# if gobject-introspection-data is omitted from DISTRO_FEATURES and MACHINE_FEATURES.
+EXTRA_OECONF_prepend = "${@bb.utils.contains('COMBINED_FEATURES', 'gobject-introspection-data', '--enable-introspection', '--disable-introspection', d)} "
+
+UNKNOWN_CONFIGURE_WHITELIST_append = " --enable-introspection --disable-introspection"
+
+# Generating introspection data depends on a combination of native and target introspection tools,
+# and qemu to run the target tools.
+DEPENDS_append = " gobject-introspection gobject-introspection-native qemu-native"
+
+# This is necessary for python scripts to succeed - distutils
+# failes if these are not set
+export BUILD_SYS
+export HOST_SYS
+export STAGING_LIBDIR
+export STAGING_INCDIR
+
+# This is used by introspection tools to find .gir includes
+export XDG_DATA_DIRS = "${STAGING_DATADIR}"
+
+do_configure_prepend_class-target () {
+    # introspection.m4 pre-packaged with upstream tarballs does not yet
+    # have our fixes
+    mkdir -p ${S}/m4
+    cp ${STAGING_DIR_TARGET}/${datadir}/aclocal/introspection.m4 ${S}/m4
+}
+
+
+# .typelib files are needed at runtime and so they go to the main package
+# (so they'll be together with libraries they support).
+FILES_${PN}_append = " ${libdir}/girepository-*/*.typelib" 
+    
+# .gir files go to dev package, as they're needed for developing (but not for running)
+# things that depends on introspection.
+FILES_${PN}-dev_append = " ${datadir}/gir-*/*.gir"
+

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.