[oe-commits] [openembedded-core] 03/03: distrooverrides.bbclass: DISTRO_FEATURES as overrides

[git at git.openembedded.org]

This is an automated email from the git hooks/post-receive script.

rpurdie pushed a commit to branch master-next
in repository openembedded-core.

commit 25c2503251dcf6a47aa7d76dc748d6e3a7ec751b
Author: Patrick Ohly <patrick.ohly at intel.com>
AuthorDate: Wed Jun 14 12:33:50 2017 +0200

    distrooverrides.bbclass: DISTRO_FEATURES as overrides
    
    This achieves the same goal as the same change to bitbake.conf itself,
    but because the class gets added later as part expanding INHERIT, this
    new approach is less likely to run into problems when DISTRO_FEATURES
    contains complex code.
    
    Another difference is that the class currently does not get inherited
    by default and thus is completely absent from a build unless some
    layer or include file adds it to INHERIT.
    
    Compared to the earlier code in bitbake.conf and a similar class in
    intel-iot-refkit, additional overrides now get sorted. This makes the
    final OVERRIDES more deterministic.
    
    The lessons learned about unintentionally depending on OVERRIDES are
    documented in the class because such problems are more likely to show
    up as unexpected signature differences when using this class.
    
    Signed-off-by: Patrick Ohly <patrick.ohly at intel.com>
    Signed-off-by: Richard Purdie <richard.purdie at linuxfoundation.org>
---
 meta/classes/distrooverrides.bbclass | 32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)

diff --git a/meta/classes/distrooverrides.bbclass b/meta/classes/distrooverrides.bbclass
new file mode 100644
index 0000000..9a42712
--- /dev/null
+++ b/meta/classes/distrooverrides.bbclass
@@ -0,0 +1,32 @@
+# Turns certain DISTRO_FEATURES into overrides with the same
+# name plus a df- prefix. Ensures that these special
+# distro features remain set also for native and nativesdk
+# recipes, so that these overrides can also be used there.
+#
+# This makes it simpler to write .bbappends that only change the
+# task signatures of the recipe if the change is really enabled,
+# for example with:
+#   do_install_append_df-my-feature () { ... }
+# where "my-feature" is a DISTRO_FEATURE.
+#
+# The class is meant to be used in a layer.conf or distro
+# .inc file with:
+# INHERIT += "distrooverrides"
+# DISTRO_FEATURES_OVERRIDES += "my-feature"
+#
+# Beware that this part of OVERRIDES changes during parsing, so usage
+# of these overrides should be limited to .bb and .bbappend files,
+# because then DISTRO_FEATURES is final.
+
+DISTRO_FEATURE_OVERRIDES ?= ""
+DISTRO_FEATURE_OVERRIDES[doc] = "A space-separated list of <feature> entries. \
+Each entry is added to OVERRIDES as df-<feature> if <feature> is in DISTRO_FEATURES."
+
+DISTRO_FEATURES_FILTER_NATIVE_append = " ${DISTRO_FEATURES_OVERRIDES}"
+DISTRO_FEATURES_FILTER_NATIVESDK_append = " ${DISTRO_FEATURES_OVERRIDES}"
+
+# If DISTRO_FEATURES_OVERRIDES or DISTRO_FEATURES show up in a task
+# signature because of this line, then the task dependency on
+# OVERRIDES itself should be fixed. Excluding these two variables
+# with DISTROOVERRIDES[vardepsexclude] would just work around the problem.
+DISTROOVERRIDES .= "${@ ''.join([':df-' + x for x in sorted(set(d.getVar('DISTRO_FEATURES_OVERRIDES').split()) & set((d.getVar('DISTRO_FEATURES') or '').split()))]) }"

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.