[oe-commits] [openembedded-core] 20/29: classes: add gitupstream class
git at git.openembedded.org
git at git.openembedded.org
Fri Mar 10 10:16:27 UTC 2017
This is an automated email from the git hooks/post-receive script.
rpurdie pushed a commit to branch master-next
in repository openembedded-core.
commit 5a08bea7c9a8579285ca67f470e374039602045b
Author: Ross Burton <ross.burton at intel.com>
AuthorDate: Fri Nov 11 17:51:17 2016 +0000
classes: add gitupstream class
This class lets you use BBCLASSEXTEND to add a variant of the recipe that
fetches from git instead of a tarball.
For example:
BBCLASSEXTEND = "gitupstream:target"
SRC_URI_class-gitupstream = "git://git.example.com/example"
SRCREV_class-gitupstream = "abcd1234"
This variant will have DEFAULT_PREFERENCE set to -1 so it needs to be selected
to be used, and any git-specific tweaks can be done with the class-gitupstream
override, for example:
DEPENDS_append_class-gitupstream = " gperf-native"
do_configure_prepend_class-gitupstream() {
touch ${S}/README
}
It currently only supports creating a git variant of the target recipe, not
native or nativesdk. The BBCLASSEXTEND syntax (gitupstream:target) was chosen
so that support for native and nativesdk can be added at a later date.
[ YOCTO #10215 ]
Signed-off-by: Ross Burton <ross.burton at intel.com>
---
meta/classes/gitupstream.bbclass | 25 +++++++++++++++++++++++++
1 file changed, 25 insertions(+)
diff --git a/meta/classes/gitupstream.bbclass b/meta/classes/gitupstream.bbclass
new file mode 100644
index 0000000..405283d
--- /dev/null
+++ b/meta/classes/gitupstream.bbclass
@@ -0,0 +1,25 @@
+CLASSOVERRIDE = "class-gitupstream"
+
+# TODO doesn't let you gitupstream a native recipe yet
+
+python gitupstream_virtclass_handler () {
+ # Do nothing if this is inherited, as it's for BBCLASSEXTEND
+ if "gitupstream" not in (e.data.getVar('BBCLASSEXTEND', True) or ""):
+ bb.error("Don't inherit gitupstream, use BBCLASSEXTEND")
+ return
+
+ variant = d.getVar("BBEXTENDVARIANT", True)
+ if variant not in ("target"):
+ bb.error("Pass the variant when using gitupstream, for example gitupstream:target")
+
+ d.setVar("DEFAULT_PREFERENCE", "-1")
+ d.setVar("S", "${WORKDIR}/git")
+
+ # Modify the SRCREV, if the recipe hasn't used PV_class-gitupstream to
+ # assign a +gitX PV already.
+ pv = d.getVar("PV", True)
+ if "+git" not in pv:
+ d.setVar("PV", pv + "+git${SRCPV}")
+}
+addhandler gitupstream_virtclass_handler
+gitupstream_virtclass_handler[eventmask] = "bb.event.RecipePreFinalise"
--
To stop receiving notification emails like this one, please contact
the administrator of this repository.
More information about the Openembedded-commits
mailing list