[oe-commits] [meta-openembedded] 07/19: grilo: initial add 0.3.10

git at git.openembedded.org git at git.openembedded.org
Sat Dec 7 23:47:12 UTC 2019


This is an automated email from the git hooks/post-receive script.

khem pushed a commit to branch master-next
in repository meta-openembedded.

commit 0bfd90a4c7b87fcfaaa5947c873c224f93112120
Author: Andreas Müller <schnitzeltony at gmail.com>
AuthorDate: Fri Dec 6 01:09:04 2019 +0100

    grilo: initial add 0.3.10
    
    It is an unconditional dependency for upcoming gnome-control-center
    
    Signed-off-by: Andreas Müller <schnitzeltony at gmail.com>
    Signed-off-by: Khem Raj <raj.khem at gmail.com>
---
 meta-gnome/recipes-gnome/grilo/grilo_0.3.10.bb | 29 ++++++++++++++++++++++++++
 1 file changed, 29 insertions(+)

diff --git a/meta-gnome/recipes-gnome/grilo/grilo_0.3.10.bb b/meta-gnome/recipes-gnome/grilo/grilo_0.3.10.bb
new file mode 100644
index 0000000..e3fd671
--- /dev/null
+++ b/meta-gnome/recipes-gnome/grilo/grilo_0.3.10.bb
@@ -0,0 +1,29 @@
+SUMMARY = "Grilo is a framework forsearching media content from various sources"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
+
+DEPENDS = " \
+    libxml2 \
+    glib-2.0 \
+"
+
+GNOMEBASEBUILDCLASS = "meson"
+
+inherit gnomebase gobject-introspection gtk-doc gettext vala
+
+SRC_URI[archive.md5sum] = "f02bf585d1a48dc65be8b90ae3b08330"
+SRC_URI[archive.sha256sum] = "7e44b2e74c31ed24eb97e43265a9e41effe8660287b02295111805c7bda7f1e8"
+
+GIR_MESON_OPTION = "enable-introspection"
+GTKDOC_MESON_OPTION = "enable-gtk-doc"
+
+# Note: removing 'net' from PACKAGECONFIG causes
+# | bindings/vala/meson.build:15:0: ERROR: Unknown variable "grlnet_gir".
+PACKAGECONFIG ??= "net"
+
+PACKAGECONFIG[net] = "-Denable-grl-net=true, -Denable-grl-net=false, libsoup-2.4"
+PACKAGECONFIG[test-ui] = "-Denable-test-ui=true, -Denable-test-ui=false, gtk+3 liboauth"
+
+# Once we have a recipe for 'totem-plparser' this can turn into a PACKAGECONFIG
+EXTRA_OEMESON = "-Denable-grl-pls=false"
+

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.


More information about the Openembedded-commits mailing list