[oe-commits] [meta-openembedded] 05/14: metacity: upgrade 3.32.0 -> 3.34.1

git at git.openembedded.org git at git.openembedded.org
Mon Dec 9 07:02:02 UTC 2019


This is an automated email from the git hooks/post-receive script.

khem pushed a commit to branch master-next
in repository meta-openembedded.

commit 0467ec9587dcb8bf119dad3696e48160218b0082
Author: Andreas Müller <schnitzeltony at gmail.com>
AuthorDate: Fri Dec 6 01:09:09 2019 +0100

    metacity: upgrade 3.32.0 -> 3.34.1
    
    This is more or less a recipe-rewrite:
    
    * get sources from GNOME
    * cleanup DEPENDS
    * give up tailored configure
    * make xinerama a PACKAGECONFIG
    
    Signed-off-by: Andreas Müller <schnitzeltony at gmail.com>
    Signed-off-by: Khem Raj <raj.khem at gmail.com>
---
 .../recipes-gnome/metacity/metacity_3.32.0.bb      | 41 ----------------------
 .../recipes-gnome/metacity/metacity_3.34.1.bb      | 38 ++++++++++++++++++++
 2 files changed, 38 insertions(+), 41 deletions(-)

diff --git a/meta-gnome/recipes-gnome/metacity/metacity_3.32.0.bb b/meta-gnome/recipes-gnome/metacity/metacity_3.32.0.bb
deleted file mode 100644
index 8f15c57..0000000
--- a/meta-gnome/recipes-gnome/metacity/metacity_3.32.0.bb
+++ /dev/null
@@ -1,41 +0,0 @@
-SECTION = "x11/wm"
-SUMMARY = "Metacity is the boring window manager for the adult in you"
-LICENSE = "GPLv2+"
-LIC_FILES_CHKSUM = "file://COPYING;md5=b4cce53560b8e619ffa7c830fb8761aa \
-                    file://src/include/main.h;endline=24;md5=72148ede07a6dadd01de6a882d20a9ad"
-
-PE = "1"
-
-DEPENDS = "gsettings-desktop-schemas startup-notification \
-           gnome-doc-utils gdk-pixbuf-native \
-           gtk+3 glib-2.0 libcanberra libgtop intltool-native"
-
-inherit autotools gettext gnomebase features_check
-# depends on startup-notification which depends on virtual/libx11
-REQUIRED_DISTRO_FEATURES = "x11"
-
-SRC_URI = "git://github.com/GNOME/metacity.git;branch=master \
-           file://0001-drop-zenity-detection.patch \
-"
-
-S = "${WORKDIR}/git"
-SRCREV = "bf1bfbadf47eff97703df17e95b15168e2034222"
-
-EXTRA_OECONF += "--disable-xinerama"
-
-PACKAGECONFIG ?= ""
-
-# enable as neccessary until new warnings are dealt with
-PACKAGECONFIG[werror] = "--enable-Werror,--disable-Werror,,"
-
-do_configure_prepend() {
-    cd ${S}
-    aclocal --install || exit 1
-    autoreconf --verbose --force --install -Wno-portability || exit 1
-    cd -
-
-}
-
-FILES_${PN} += "${datadir}/themes ${datadir}/gnome-control-center ${datadir}/gnome"
-RDEPENDS_${PN} += "gsettings-desktop-schemas"
-
diff --git a/meta-gnome/recipes-gnome/metacity/metacity_3.34.1.bb b/meta-gnome/recipes-gnome/metacity/metacity_3.34.1.bb
new file mode 100644
index 0000000..d8c8b53
--- /dev/null
+++ b/meta-gnome/recipes-gnome/metacity/metacity_3.34.1.bb
@@ -0,0 +1,38 @@
+SECTION = "x11/wm"
+SUMMARY = "Metacity is the boring window manager for the adult in you"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b4cce53560b8e619ffa7c830fb8761aa \
+                    file://src/include/main.h;endline=24;md5=72148ede07a6dadd01de6a882d20a9ad"
+
+PE = "1"
+
+DEPENDS = " \
+    gdk-pixbuf-native \
+    gtk+3 \
+    gsettings-desktop-schemas \
+    startup-notification \
+    libcanberra \
+    libgtop \
+"
+
+
+# depends on startup-notification which depends on virtual/libx11
+REQUIRED_DISTRO_FEATURES = "x11"
+
+inherit gnomebase gsettings gettext upstream-version-is-even features_check
+
+SRC_URI[archive.md5sum] = "c0c10204e4d6d024cb413042c1de316b"
+SRC_URI[archive.sha256sum] = "31c7d1045c390afb3bf405735b0b26c459197cbf43af37c469eb8918ce3a453d"
+SRC_URI += "file://0001-drop-zenity-detection.patch"
+
+PACKAGECONFIG[xinerama] = "--enable-xinerama,--disable-xinerama,libxinerama"
+# enable as neccessary until new warnings are dealt with
+PACKAGECONFIG[werror] = "--enable-Werror,--disable-Werror,,"
+
+FILES_${PN} += " \
+    ${datadir}/themes \
+    ${datadir}/gnome-control-center \
+    ${datadir}/gnome\
+"
+
+RDEPENDS_${PN} += "gsettings-desktop-schemas"

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.


More information about the Openembedded-commits mailing list