[oe-commits] [meta-openembedded] 01/35: Introduce recipes for sdbus-c++ library and its tools

[git at git.openembedded.org]

This is an automated email from the git hooks/post-receive script.

khem pushed a commit to branch master-next
in repository meta-openembedded.

commit 61c1539e49fc5def2e2fdfa882be56cd18086016
Author: sangelovic <angelovic.s at gmail.com>
AuthorDate: Wed Jun 12 11:50:07 2019 +0200

    Introduce recipes for sdbus-c++ library and its tools
    
    Signed-off-by: Khem Raj <raj.khem at gmail.com>
---
 .../sdbus-c++/sdbus-c++-0.7.3/run-ptest            | 13 ++++++++
 .../sdbus-c++/sdbus-c++-libsystemd_242.bb          | 39 ++++++++++++++++++++++
 .../sdbus-c++/sdbus-c++-tools-native_0.7.3.bb      | 14 ++++++++
 meta-oe/recipes-core/sdbus-c++/sdbus-c++_0.7.3.bb  | 32 ++++++++++++++++++
 4 files changed, 98 insertions(+)

diff --git a/meta-oe/recipes-core/sdbus-c++/sdbus-c++-0.7.3/run-ptest b/meta-oe/recipes-core/sdbus-c++/sdbus-c++-0.7.3/run-ptest
new file mode 100644
index 0000000..48bbd4e
--- /dev/null
+++ b/meta-oe/recipes-core/sdbus-c++/sdbus-c++-0.7.3/run-ptest
@@ -0,0 +1,13 @@
+#!/bin/sh
+set -e
+set -o pipefail
+
+../tests/sdbus-c++-unit-tests |& \
+sed -r 's/^\[\s+OK\s+\] (.*) \([0-9]+\sms\)$/OK: \1 /' | \
+sed -r 's/^\[\s+FAILED\s+\] (.*) \([0-9]+\sms\)$/FAILED: \1 /' | \
+awk '{if ($1 == "OK:" || $1 == "FAILED:") {print $0}}'
+
+../tests/sdbus-c++-integration-tests |& \
+sed -r 's/^\[\s+OK\s+\] (.*) \([0-9]+\sms\)$/OK: \1 /' | \
+sed -r 's/^\[\s+FAILED\s+\] (.*) \([0-9]+\sms\)$/FAILED: \1 /' | \
+awk '{if ($1 == "OK:" || $1 == "FAILED:") {print $0}}' 
diff --git a/meta-oe/recipes-core/sdbus-c++/sdbus-c++-libsystemd_242.bb b/meta-oe/recipes-core/sdbus-c++/sdbus-c++-libsystemd_242.bb
new file mode 100644
index 0000000..e007a52
--- /dev/null
+++ b/meta-oe/recipes-core/sdbus-c++/sdbus-c++-libsystemd_242.bb
@@ -0,0 +1,39 @@
+SUMMARY = "libsystemd static library"
+DESCRIPTION = "libsystemd static library built specifically as an integral component of sdbus-c++"
+
+SECTION = "libs"
+
+LICENSE = "LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://LICENSE.LGPL2.1;md5=4fbd65380cdd255951079008b364516c"
+
+inherit meson pkgconfig
+
+DEPENDS += "gperf-native gettext-native util-linux libcap"
+
+SRCREV = "1e5d2d656420d0e755dbcf72aeba3c3aba54e956"
+SRC_URI = "git://github.com/systemd/systemd.git;protocol=https;branch=master"
+
+EXTRA_OEMESON += "-Dstatic-libsystemd=pic"
+
+S = "${WORKDIR}/git"
+
+do_patch() {
+    LIBS_TO_APPEND='Libs: -L$''{libdir} -lsystemd'
+    sed -i -e "s/$LIBS_TO_APPEND.*/$LIBS_TO_APPEND -lrt -lmount -lcap/" ${S}/src/libsystemd/libsystemd.pc.in
+}
+
+do_compile() {
+    ninja -v ${PARALLEL_MAKE} version.h
+    ninja -v ${PARALLEL_MAKE} libsystemd.a
+}
+
+do_install () {
+    install -d ${D}${libdir}
+    install ${B}/libsystemd.a ${D}${libdir}
+
+    install -d ${D}${includedir}/systemd
+    install ${S}/src/systemd/*.h ${D}${includedir}/systemd
+
+    install -d ${D}${libdir}/pkgconfig
+    install ${B}/src/libsystemd/libsystemd.pc ${D}${libdir}/pkgconfig
+}
diff --git a/meta-oe/recipes-core/sdbus-c++/sdbus-c++-tools-native_0.7.3.bb b/meta-oe/recipes-core/sdbus-c++/sdbus-c++-tools-native_0.7.3.bb
new file mode 100644
index 0000000..cac6c06
--- /dev/null
+++ b/meta-oe/recipes-core/sdbus-c++/sdbus-c++-tools-native_0.7.3.bb
@@ -0,0 +1,14 @@
+SUMMARY = "sdbus-c++ native tools"
+DESCRIPTION = "Native interface code generator for development with sdbus-c++"
+
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://${S}/COPYING;md5=1803fa9c2c3ce8cb06b4861d75310742"
+
+inherit cmake native
+
+DEPENDS += "expat"
+
+SRCREV = "e7155c550627c265a78f358b9eb08ec509ceb411"
+SRC_URI = "git://github.com/Kistler-Group/sdbus-cpp.git;protocol=https;branch=master;subpath=tools"
+
+S = "${WORKDIR}/tools"
diff --git a/meta-oe/recipes-core/sdbus-c++/sdbus-c++_0.7.3.bb b/meta-oe/recipes-core/sdbus-c++/sdbus-c++_0.7.3.bb
new file mode 100644
index 0000000..d6f504c
--- /dev/null
+++ b/meta-oe/recipes-core/sdbus-c++/sdbus-c++_0.7.3.bb
@@ -0,0 +1,32 @@
+SUMMARY = "sdbus-c++"
+DESCRIPTION = "High-level C++ D-Bus library designed to provide easy-to-use yet powerful API in modern C++"
+
+SECTION = "libs"
+
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=1803fa9c2c3ce8cb06b4861d75310742"
+
+inherit cmake pkgconfig systemd ptest
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'with-external-libsystemd', 'with-builtin-libsystemd', d)} \
+                   ${@bb.utils.contains('PTEST_ENABLED', '1', 'with-tests', '', d)}"
+PACKAGECONFIG[with-builtin-libsystemd] = ",,sdbus-c++-libsystemd,libcap"
+PACKAGECONFIG[with-external-libsystemd] = ",,systemd,libsystemd"
+PACKAGECONFIG[with-tests] = "-DBUILD_TESTS=ON -DTESTS_INSTALL_PATH=${libdir}/${BPN}/tests,-DBUILD_TESTS=OFF"
+
+DEPENDS += "expat"
+
+SRCREV = "e7155c550627c265a78f358b9eb08ec509ceb411"
+SRC_URI = "git://github.com/Kistler-Group/sdbus-cpp.git;protocol=https;branch=master"
+SRC_URI += "file://run-ptest"
+
+EXTRA_OECMAKE = "-DBUILD_CODE_GEN=ON \
+                 -DBUILD_DOC=ON \
+                 -DBUILD_DOXYGEN_DOC=OFF"
+
+S = "${WORKDIR}/git"
+
+FILES_${PN}_remove = "${sysconfdir}"
+FILES_${PN}-ptest += "${sysconfdir}/dbus-1/system.d/"
+FILES_${PN}-ptest += "${libdir}/${BPN}/tests"
+FILES_${PN}-dev += "${bindir}/sdbus-c++-xml2cpp"

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.