[oe-commits] [meta-openembedded] 17/17: cups-filters: add recipe

[git at git.openembedded.org]

This is an automated email from the git hooks/post-receive script.

khem pushed a commit to branch master-next
in repository meta-openembedded.

commit 8c4c97fc5893aef2bbf18af57d3c16e281232db9
Author: Diego Rondini <diego.rondini at kynetics.com>
AuthorDate: Fri Jan 3 14:45:43 2020 +0000

    cups-filters: add recipe
    
    Add cups-filters recipe to provide backends and filters required for
    real world printing with CUPS. The recipe has been imported from
    meta-printing and updated.
    
    Signed-off-by: Diego Rondini <diego.rondini at kynetics.com>
    Signed-off-by: Khem Raj <raj.khem at gmail.com>
---
 meta-oe/recipes-printing/cups/cups-filters.inc     | 95 ++++++++++++++++++++++
 .../recipes-printing/cups/cups-filters_1.26.0.bb   |  4 +
 2 files changed, 99 insertions(+)

diff --git a/meta-oe/recipes-printing/cups/cups-filters.inc b/meta-oe/recipes-printing/cups/cups-filters.inc
new file mode 100644
index 0000000..45bdab3
--- /dev/null
+++ b/meta-oe/recipes-printing/cups/cups-filters.inc
@@ -0,0 +1,95 @@
+DESCRIPTION = "CUPS backends, filters, and other software"
+HOMEPAGE = "http://www.linuxfoundation.org/collaborate/workgroups/openprinting/cups-filters"
+
+LICENSE = "GPLv2 & LGPLv2 & MIT & GPLv2+ & GPLv3"
+LIC_FILES_CHKSUM = "file://COPYING;md5=516215fd57564996d70327db19b368ff"
+
+SECTION = "console/utils"
+
+DEPENDS = "cups glib-2.0 glib-2.0-native dbus dbus-glib lcms ghostscript poppler qpdf libpng"
+DEPENDS_class-native = "poppler-native glib-2.0-native dbus-native pkgconfig-native gettext-native libpng-native"
+
+SRC_URI = "http://openprinting.org/download/cups-filters/cups-filters-${PV}.tar.gz"
+
+inherit autotools-brokensep gettext pkgconfig
+
+EXTRA_OECONF += " --enable-ghostscript --disable-ldap \
+                       --with-pdftops=hybrid --enable-imagefilters \
+                       --enable-ghostscript --with-gs-path=${bindir}/gs \
+                       --with-pdftops-path=${bindir}/gs \
+                       --with-fontdir=${datadir}/fonts --with-rcdir=no \
+                       --with-cups-rundir=${localstatedir}/run/cups \
+                       --localstatedir=${localstatedir}/var \
+                       --with-rcdir=no \
+                       --without-php"
+
+EXTRA_OECONF_class-native += " --with-pdftops=pdftops \
+                                    --disable-avahi --disable-ghostscript \
+                                    --disable-ldap \
+                                    --with-png --without-jpeg --without-tiff"
+
+BBCLASSEXTEND = "native"
+
+PACKAGECONFIG[jpeg] = "--with-jpeg,--without-jpeg,jpeg"
+PACKAGECONFIG[png] = "--with-png,--without-png,libpng"
+PACKAGECONFIG[tiff] = "--with-tiff,--without-tiff,tiff"
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'zeroconf', 'avahi', '', d)}"
+
+PACKAGECONFIG[avahi] = "--enable-avahi,--disable-avahi,avahi"
+PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus"
+
+DIRFILES = "1"
+
+PACKAGES =+ "\
+	${PN}-gst \
+        ${PN}-data \
+        "
+
+FILES_${PN}-gst = "\
+	${libdir}/cups/filter/gstopxl \
+	${libdir}/cups/filter/gstoraster \
+	"
+
+FILES_${PN}-data = "\
+	${datadir}/cups/data \
+	"
+
+FILES_${PN}-dbg += "\
+	${libdir}/cups/filter/.debug \
+	${libdir}/cups/backend/.debug \
+	"
+
+FILES_${PN} += "\
+        ${libdir}/cups/filter \
+        ${libdir}/cups/backend \
+        ${libdir}/cups/driver \
+        ${datadir}/cups/charsets \
+        ${datadir}/cups/drv \
+        ${datadir}/cups/mime \
+        ${datadir}/cups/ppdc \
+        ${datadir}/ppd/cupsfilters \
+        ${datadir}/cups/braille \
+        ${datadir}/cups/banners \
+        ${datadir}/cups/braille/index.sh \
+        ${datadir}/cups/braille/cups-braille.sh \
+        ${datadir}/cups/braille/indexv3.sh \
+        ${datadir}/cups/braille/indexv4.sh \
+        ${datadir}/cups/banners/topsecret \
+        ${datadir}/cups/banners/secret \
+        ${datadir}/cups/banners/confidential \
+        ${datadir}/cups/banners/unclassified \
+        ${datadir}/cups/banners/form \
+        ${datadir}/cups/banners/classified \
+        ${datadir}/cups/banners/standard \
+"
+
+do_install_append() {
+	# remove banners, braille dirs
+	rm -rf ${D}${datadir}/cups/{banners,braille}
+
+	# remove sysroot path contamination from pkgconfig file
+	sed -i -e 's:${STAGING_DIR_TARGET}::' ${D}/${libdir}/pkgconfig/libcupsfilters.pc
+}
+
+RDEPENDS_${PN} += "bash"
diff --git a/meta-oe/recipes-printing/cups/cups-filters_1.26.0.bb b/meta-oe/recipes-printing/cups/cups-filters_1.26.0.bb
new file mode 100644
index 0000000..619602a
--- /dev/null
+++ b/meta-oe/recipes-printing/cups/cups-filters_1.26.0.bb
@@ -0,0 +1,4 @@
+include cups-filters.inc
+
+SRC_URI[md5sum] = "afb278c77bb195c2a32fc64e5c8378fb"
+SRC_URI[sha256sum] = "ff8679fcd0c31c25d229262c7ad100ba161ef6b2aa455a2df673dd74ef93f488"

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.