[OE-core] [PATCH meta-oe 3/9] libmad: Imported from OE-classic

[Koen Kooi]

Op 26 aug. 2011, om 02:28 heeft Joel A Fernandes het volgende geschreven:
> 
> diff --git a/meta-oe/recipes-multimedia/libmad/libmad_0.15.1b.bb b/meta-oe/recipes-multimedia/libmad/libmad_0.15.1b.bb
> new file mode 100644
> index 0000000..537d685
> --- /dev/null
> +++ b/meta-oe/recipes-multimedia/libmad/libmad_0.15.1b.bb
> @@ -0,0 +1,34 @@
> +DESCRIPTION = "MPEG Audio Decoder Library"
> +SECTION = "libs"
> +PRIORITY = "optional"

That field isn't used anymore

> +DEPENDS = "libid3tag"
> +LICENSE = "GPL"

Which version?

> +PR = "r5"

reset that

> +
> +LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/mad/libmad-${PV}.tar.gz \
> +           file://add-pkgconfig.patch \
> +	   file://mad.diff \
> +	   file://mad-mips-h-constraint.patch"
> +
> +S = "${WORKDIR}/libmad-${PV}"
> +
> +SRC_URI_append_avr32 = " file://libmad-0.15.1b-avr32-optimization.patch"
> +
> +inherit autotools pkgconfig
> +
> +EXTRA_OECONF = "-enable-speed --enable-shared"
> +# The ASO's don't take any account of thumb...
> +EXTRA_OECONF_append_thumb = " --disable-aso --enable-fpm=default"
> +EXTRA_OECONF_append_arm = " --enable-fpm=arm"
> +
> +do_configure_prepend () {
> +#	damn picky automake...
> +	touch NEWS AUTHORS ChangeLog
> +}
> +
> +ARM_INSTRUCTION_SET = "arm"
> +
> +SRC_URI[md5sum] = "1be543bc30c56fb6bea1d7bf6a64e66c"
> +SRC_URI[sha256sum] = "bbfac3ed6bfbc2823d3775ebb931087371e142bb0e9bb1bee51a76a6e0078690"
> -- 
> 1.7.0.4
> 
> 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core at lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core