[OE-core] [PATCH 2/2] strace: update to 4.8

[Richard Purdie]

On Wed, 2013-06-19 at 13:34 +0800, Kai Kang wrote:
> Update strace to 4.8.
> 
> * Update License file.
> * Remove the backport patches which are already in version 4.8.
> * Add file git-version-gen from git repo. Without this file configure
>   fails.
> * Add libaio and acl to PACKAGECONFIG for target package. Make libaio as a
>   dependency by default which could be covered easily.
> 
> Signed-off-by: Kai Kang <kai.kang at windriver.com>

[...]

> diff --git a/meta/recipes-devtools/strace/strace_4.8.bb b/meta/recipes-devtools/strace/strace_4.8.bb
> new file mode 100644
> index 0000000..eb9f660
> --- /dev/null
> +++ b/meta/recipes-devtools/strace/strace_4.8.bb
> @@ -0,0 +1,32 @@
> +DESCRIPTION = "strace is a system call tracing tool."
> +HOMEPAGE = "http://strace.sourceforge.net"
> +SECTION = "console/utils"
> +LICENSE = "BSD"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=124500c21e856f0912df29295ba104c7"
> +PR = "r0"
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.xz \
> +           file://git-version-gen"
> +
> +SRC_URI[md5sum] = "c575ef43829586801f514fd91bfe7575"
> +SRC_URI[sha256sum] = "f492291f07a7c805c07a8395cce1ea054a6401ad414f4cc12185672215e1d7f8"
> +inherit autotools
> +
> +PACKAGECONFIG_class-target ?= "libaio"
> +PACKAGECONFIG_class-target += "${@base_contains('DISTRO_FEATURES', 'acl', 'acl', '', d)}"
> +
> +PACKAGECONFIG[libaio] = ",,libaio,"
> +PACKAGECONFIG[acl] = ",,acl,"

Are there not --enable/--disable type options we can pass into configure
here to ensure build are deterministic?

Please also send this with move detection enabled in git so we get a
diff rather than a file removal/addition correctly shown (-M option to
git format-patch for example).

Cheers,

Richard

> +
> +export INCLUDES = "-I. -I./linux"
> +
> +do_configure_prepend() {
> +	cp ${WORKDIR}/git-version-gen ${S}
> +}
> +
> +do_install_append() {
> +	# We don't ship strace-graph here because it needs perl
> +	rm ${D}${bindir}/strace-graph
> +}
> +
> +BBCLASSEXTEND = "native"