[OE-core] [PATCH 1/6] lttng-modules: Add version 2.4.0

Tom Zanussi tom.zanussi at linux.intel.com
Thu Mar 6 17:09:26 UTC 2014


From: Tom Zanussi <tom.zanussi at intel.com>

This updates lttng-modules to 2.4.0, codenamed Époque Opaque, needed
for interoperability with the 3.14 (dev) kernel.

Signed-off-by: Tom Zanussi <tom.zanussi at intel.com>
---
 meta/recipes-kernel/lttng/lttng-modules_2.4.0.bb | 34 ++++++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 meta/recipes-kernel/lttng/lttng-modules_2.4.0.bb

diff --git a/meta/recipes-kernel/lttng/lttng-modules_2.4.0.bb b/meta/recipes-kernel/lttng/lttng-modules_2.4.0.bb
new file mode 100644
index 0000000..0b7d5e8
--- /dev/null
+++ b/meta/recipes-kernel/lttng/lttng-modules_2.4.0.bb
@@ -0,0 +1,34 @@
+SECTION = "devel"
+SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
+DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
+LICENSE = "LGPLv2.1 & GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=1412caf5a1aa90d6a48588a4794c0eac \
+                    file://gpl-2.0.txt;md5=751419260aa954499f7abaabaa882bbe \
+                    file://lgpl-2.1.txt;md5=243b725d71bb5df4a1e5920b344b86ad"
+
+DEPENDS = "virtual/kernel"
+
+inherit module
+
+SRCREV = "fb2c37799306d16fb590aebee6fad8be431264b7"
+PV = "2.4.0"
+
+SRC_URI = "git://git.lttng.org/lttng-modules.git;branch=stable-2.4 \
+           file://lttng-modules-replace-KERNELDIR-with-KERNEL_SRC.patch"
+
+export INSTALL_MOD_DIR="kernel/lttng-modules"
+export KERNEL_SRC="${STAGING_KERNEL_DIR}"
+
+
+S = "${WORKDIR}/git"
+
+do_install_append() {
+	# Delete empty directories to avoid QA failures if no modules were built
+	find ${D}/lib -depth -type d -empty -exec rmdir {} \;
+}
+
+python do_package_prepend() {
+    if not os.path.exists(os.path.join(d.getVar('D', True), 'lib/modules')):
+        bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN', True))
+}
+
-- 
1.8.3.1



More information about the Openembedded-core mailing list