[OE-core] [PATCH 1/2] linaro-pm-qa-utils: Add power management test utils

[Koen Kooi]

Op 18 mrt. 2014, om 12:56 heeft Chase Maupin <Chase.Maupin at ti.com> het volgende geschreven:

> * The power management test utilities from Linaro can be used
>  to test multiple PM features such as cpufreq, cpuidle, thermal
>  control and suspend operations.
> * These utilities are not platform specific and can be used by
>  a broader base of users.

PN should me 'pm-qa' or 'pm-qa-utils'. And it would fit better in meta-oe since it's not 'core' enough for oe-core.

> 
> Signed-off-by: Chase Maupin <Chase.Maupin at ti.com>
> ---
> .../linaro-pm-qa/linaro-pm-qa-utils_git.bb         |   63 ++++++++++++++++++++
> 1 file changed, 63 insertions(+)
> create mode 100644 meta/recipes-devtools/linaro-pm-qa/linaro-pm-qa-utils_git.bb
> 
> diff --git a/meta/recipes-devtools/linaro-pm-qa/linaro-pm-qa-utils_git.bb b/meta/recipes-devtools/linaro-pm-qa/linaro-pm-qa-utils_git.bb
> new file mode 100644
> index 0000000..610f3a7
> --- /dev/null
> +++ b/meta/recipes-devtools/linaro-pm-qa/linaro-pm-qa-utils_git.bb
> @@ -0,0 +1,63 @@
> +DESCRIPTION = "Utilities from Linaro for testing Power Management"
> +HOMEPAGE = "https://wiki.linaro.org/WorkingGroups/PowerManagement/Resources/TestSuite/PmQa"
> +
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
> +
> +PV = "0.4.4"
> +
> +BRANCH ?= "master"
> +SRCREV = "fbc2762359b863dfbf4fd0bab1e8abd2a6125ed4"
> +
> +SRC_URI = "git://git.linaro.org/tools/pm-qa.git;protocol=git;branch=${BRANCH}"
> +
> +S = "${WORKDIR}/git"
> +
> +CFLAGS += "-pthread"
> +
> +do_compile () {
> +    # Find all the .c files in this project and build them.
> +    for x in `find . -name "*.c"`
> +    do
> +        util=`echo ${x} | sed s/.c$//`
> +        oe_runmake ${util}
> +    done
> +}
> +
> +do_install () {
> +    install -d ${D}${bindir}
> +    install -d ${D}${bindir}/linaro-pm-qa-include
> +
> +    # Install the compiled binaries the were built in the previous step
> +    for x in `find . -name "*.c"`
> +    do
> +        util=`echo ${x} | sed s/.c$//`
> +        util_basename=`basename ${util}`
> +        install -m 0755 ${util} ${D}${bindir}/${util_basename}
> +    done
> +
> +    # Install the helper scripts in the include directory
> +    for script in `find . -name "*.sh" | grep include`
> +    do
> +        # Remove hardcoded relative paths
> +        sed -i -e 's#..\/utils\/##' ${script}
> +
> +        script_basename=`basename ${script}`
> +        install -m 0755 $script ${D}${bindir}/linaro-pm-qa-include/${script_basename}
> +    done
> +
> +    # Install the shell scripts NOT in the include directory since those
> +    # will be installed elsewhere
> +    for script in `find . -name "*.sh" | grep -v include`
> +    do
> +        # if the script includes any helper scripts from the include
> +        # directory then change the include path to the absolute path
> +        # to reflect the install location of the helper scripts.
> +        sed -i -e "s#source ../include#source ${bindir}/linaro-pm-qa-include#g" ${script}
> +        # Remove hardcoded relative paths
> +        sed -i -e 's#..\/utils\/##' ${script}
> +
> +        script_basename=`basename ${script}`
> +        install -m 0755 $script ${D}${bindir}/${script_basename}
> +    done
> +}
> -- 
> 1.7.9.5
> 
> -- 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core
>