[OE-core] [PATCH v3] libsolv: add new recipe

[Andre McCurdy]

On Thu, Dec 10, 2015 at 1:22 PM, Alejandro del Castillo
<alejandro.delcastillo at ni.com> wrote:
> Required by the optional opkg 0.3.1 libsolv backend.
>
> Signed-off-by: Alejandro del Castillo <alejandro.delcastillo at ni.com>
> ---
>  meta/recipes-extended/libsolv/libsolv_0.6.14.bb | 28 +++++++++++++++++++++++++
>  1 file changed, 28 insertions(+)
>  create mode 100644 meta/recipes-extended/libsolv/libsolv_0.6.14.bb
>
> diff --git a/meta/recipes-extended/libsolv/libsolv_0.6.14.bb b/meta/recipes-extended/libsolv/libsolv_0.6.14.bb
> new file mode 100644
> index 0000000..fba6b2d
> --- /dev/null
> +++ b/meta/recipes-extended/libsolv/libsolv_0.6.14.bb
> @@ -0,0 +1,28 @@
> +SUMMARY = "Library for solving packages and reading repositories"
> +HOMEPAGE = "https://github.com/openSUSE/libsolv"
> +BUGTRACKER = "https://github.com/openSUSE/libsolv/issues"
> +SECTION = "devel"
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://LICENSE.BSD;md5=62272bd11c97396d4aaf1c41bc11f7d8"
> +
> +SRC_URI = "https://github.com/openSUSE/libsolv/archive/${PV}.zip"

GitHub tar file archives sometimes get regenerated and the hashes
change. I'm not sure if the same can happen for zip files, but it's
probably safer to checkout a git release tag rather than trust the zip
file.

> +SRC_URI[md5sum] = "171da68f08f672cacd1930643f8d1b4d"
> +SRC_URI[sha256sum] = "0263b11372012be9c83f1c01f7d55ea9464dde58c109f5ae4de1e52870034a45"
> +
> +S = "${WORKDIR}/libsolv-${PV}"

This is effectively the default value, so this line can be removed (if
you switch to a git checkout then S does need to be specified though).

> +inherit cmake
> +
> +EXTRA_OECMAKE = "-DLIB=${baselib}"
> +
> +DEPENDS = "expat zlib"

DEPENDS should be above SRC_URI. See the OE style guide:

  http://www.openembedded.org/wiki/Styleguide

> +PACKAGES =+ "${PN}-tools ${PN}ext ${PN}ext-dbg"
> +
> +FILES_${PN}-dev += "${datadir}/cmake/Modules/FindLibSolv.cmake"
> +FILES_${PN}-tools = "${bindir}/*"
> +FILES_${PN}ext = "${libdir}/${PN}ext.so.*"
> +FILES_${PN}ext-dbg = "${libdir}/.debug/${PN}ext.so.*"
> +
> +BBCLASSEXTEND =+ "native nativesdk"
> --
> 1.9.1
>
> --
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core