[OE-core] [PATCH] u-boot-fw-utils: Fix the cross build

[Denys Dmytriyenko]

On Thu, Jan 22, 2015 at 11:18:27PM -0200, Otavio Salvador wrote:
> This merges the u-boot-fw-utils-cross into the main u-boot-fw-utils
> recipe and fixes the build failure seen since 2014.07 update.

So, the actual fix is to drop unnecessary EXTRA_OEMAKE that you had there from 
the beginning of time... Combining it with target recipe is icing on the cake.


> The cross package now is handled using an extended class instead of a
> duplicated recipe.
> 
> Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
> ---
>  .../u-boot/u-boot-fw-utils-cross_2014.07.bb        | 38 ----------------------
>  meta/recipes-bsp/u-boot/u-boot-fw-utils_2014.07.bb | 12 +++++++
>  2 files changed, 12 insertions(+), 38 deletions(-)
>  delete mode 100644 meta/recipes-bsp/u-boot/u-boot-fw-utils-cross_2014.07.bb
> 
> diff --git a/meta/recipes-bsp/u-boot/u-boot-fw-utils-cross_2014.07.bb b/meta/recipes-bsp/u-boot/u-boot-fw-utils-cross_2014.07.bb
> deleted file mode 100644
> index d1f1f9a..0000000
> --- a/meta/recipes-bsp/u-boot/u-boot-fw-utils-cross_2014.07.bb
> +++ /dev/null
> @@ -1,38 +0,0 @@
> -SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
> -LICENSE = "GPLv2+"
> -LIC_FILES_CHKSUM = "file://Licenses/README;md5=025bf9f768cbcb1a165dbe1a110babfb"
> -SECTION = "bootloader"
> -DEPENDS = "mtd-utils"
> -
> -# This revision corresponds to the tag "v2014.07"
> -# We use the revision in order to avoid having to fetch it from the
> -# repo during parse
> -SRCREV = "524123a70761110c5cf3ccc5f52f6d4da071b959"
> -
> -PV = "v2014.07+git${SRCPV}"
> -
> -SRC_URI = "git://git.denx.de/u-boot.git;branch=master;protocol=git"
> -
> -S = "${WORKDIR}/git"
> -
> -inherit uboot-config cross
> -
> -EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TARGET_CC_ARCH} ${TOOLCHAIN_OPTIONS}"'
> -
> -do_compile () {
> -	oe_runmake ${UBOOT_MACHINE}
> -	oe_runmake env
> -}
> -
> -do_install () {
> -	install -d ${D}${bindir_cross}
> -	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
> -	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
> -}
> -
> -SYSROOT_PREPROCESS_FUNCS = "uboot_fw_utils_cross"
> -uboot_fw_utils_cross() {
> -	sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
> -}
> -
> -PACKAGE_ARCH = "${MACHINE_ARCH}"
> diff --git a/meta/recipes-bsp/u-boot/u-boot-fw-utils_2014.07.bb b/meta/recipes-bsp/u-boot/u-boot-fw-utils_2014.07.bb
> index a626c95..9a304c8 100644
> --- a/meta/recipes-bsp/u-boot/u-boot-fw-utils_2014.07.bb
> +++ b/meta/recipes-bsp/u-boot/u-boot-fw-utils_2014.07.bb
> @@ -32,4 +32,16 @@ do_install () {
>  	install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
>  }
>  
> +do_install_class-cross () {
> +    install -d ${D}${bindir_cross}
> +    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
> +    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
> +}
> +
> +SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
> +uboot_fw_utils_cross() {
> +    sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
> +}
> +
>  PACKAGE_ARCH = "${MACHINE_ARCH}"
> +BBCLASSEXTEND = "cross"
> -- 
> 2.1.4
>