[OE-core] [PATCH] libdrm: remove git recipe, merge inc

[Khem Raj]

> On Jul 3, 2015, at 3:21 AM, Ross Burton <ross.burton at intel.com> wrote:
> 
> The git recipe hasn't been touched since 2012 and is out of date, so simplify
> the recipe by removing the git form and merging the remaining bb and inc file.

There might be recipes in other layers which might be using .inc file, drm is sometimes
specific to some SOCs. layer index shows that atleast meta-ti assumes .inc to be available
and there might be more unlisted or closed layers which do so.


> 
> Signed-off-by: Ross Burton <ross.burton at intel.com>
> ---
> meta/recipes-graphics/drm/libdrm.inc       | 41 ------------------------------
> meta/recipes-graphics/drm/libdrm_2.4.59.bb | 41 +++++++++++++++++++++++++++---
> meta/recipes-graphics/drm/libdrm_git.bb    | 12 ---------
> 3 files changed, 38 insertions(+), 56 deletions(-)
> delete mode 100644 meta/recipes-graphics/drm/libdrm.inc
> delete mode 100644 meta/recipes-graphics/drm/libdrm_git.bb
> 
> diff --git a/meta/recipes-graphics/drm/libdrm.inc b/meta/recipes-graphics/drm/libdrm.inc
> deleted file mode 100644
> index d3e1e92..0000000
> --- a/meta/recipes-graphics/drm/libdrm.inc
> +++ /dev/null
> @@ -1,41 +0,0 @@
> -SUMMARY = "Userspace interface to the kernel DRM services"
> -DESCRIPTION = "The runtime library for accessing the kernel DRM services.  DRM \
> -stands for \"Direct Rendering Manager\", which is the kernel portion of the \
> -\"Direct Rendering Infrastructure\" (DRI).  DRI is required for many hardware \
> -accelerated OpenGL drivers."
> -HOMEPAGE = "http://dri.freedesktop.org"
> -SECTION = "x11/base"
> -LICENSE = "MIT"
> -LIC_FILES_CHKSUM = "file://xf86drm.c;beginline=9;endline=32;md5=c8a3b961af7667c530816761e949dc71"
> -SRC_URI = "http://dri.freedesktop.org/libdrm/libdrm-${PV}.tar.bz2"
> -PROVIDES = "drm"
> -DEPENDS = "libpthread-stubs udev"
> -
> -# be aware that libdrm_2.4.44.bb ignores this
> -INC_PR = "r4"
> -
> -#libpciaccess is required starting from libdrm 2.4.26
> -DEPENDS += " libpciaccess"
> -
> -inherit autotools pkgconfig
> -
> -EXTRA_OECONF += "--disable-cairo-tests \
> -                 --enable-omap-experimental-api \
> -                 --enable-install-test-programs \
> -                 --disable-manpages \
> -                "
> -ALLOW_EMPTY_${PN}-drivers = "1"
> -PACKAGES =+ "${PN}-tests ${PN}-drivers ${PN}-radeon ${PN}-nouveau ${PN}-omap \
> -             ${PN}-intel ${PN}-exynos ${PN}-kms ${PN}-freedreno"
> -
> -RRECOMMENDS_${PN}-drivers = "${PN}-radeon ${PN}-nouveau ${PN}-omap ${PN}-intel \
> -                             ${PN}-exynos ${PN}-freedreno"
> -
> -FILES_${PN}-tests = "${bindir}/dr* ${bindir}/mode* ${bindir}/*test"
> -FILES_${PN}-radeon = "${libdir}/libdrm_radeon.so.*"
> -FILES_${PN}-nouveau = "${libdir}/libdrm_nouveau.so.*"
> -FILES_${PN}-omap = "${libdir}/libdrm_omap.so.*"
> -FILES_${PN}-intel = "${libdir}/libdrm_intel.so.*"
> -FILES_${PN}-exynos = "${libdir}/libdrm_exynos.so.*"
> -FILES_${PN}-kms = "${libdir}/libkms*.so.*"
> -FILES_${PN}-freedreno = "${libdir}/libdrm_freedreno.so.*"
> diff --git a/meta/recipes-graphics/drm/libdrm_2.4.59.bb b/meta/recipes-graphics/drm/libdrm_2.4.59.bb
> index 14bf44a..97f75ff 100644
> --- a/meta/recipes-graphics/drm/libdrm_2.4.59.bb
> +++ b/meta/recipes-graphics/drm/libdrm_2.4.59.bb
> @@ -1,6 +1,41 @@
> -require libdrm.inc
> -
> -SRC_URI += "file://installtests.patch "
> +SUMMARY = "Userspace interface to the kernel DRM services"
> +DESCRIPTION = "The runtime library for accessing the kernel DRM services.  DRM \
> +stands for \"Direct Rendering Manager\", which is the kernel portion of the \
> +\"Direct Rendering Infrastructure\" (DRI).  DRI is required for many hardware \
> +accelerated OpenGL drivers."
> +HOMEPAGE = "http://dri.freedesktop.org"
> +SECTION = "x11/base"
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://xf86drm.c;beginline=9;endline=32;md5=c8a3b961af7667c530816761e949dc71"
> +PROVIDES = "drm"
> +DEPENDS = "libpthread-stubs udev libpciaccess"
> 
> +SRC_URI = "http://dri.freedesktop.org/libdrm/${BP}.tar.bz2 \
> +           file://installtests.patch "
> SRC_URI[md5sum] = "d32a1d37c2546ee11fc5924abeedb23e"
> SRC_URI[sha256sum] = "68d26e1fd85582f4243d66864f9b43ca4ee93662825de32b5506fc8e181ea41b"
> +
> +inherit autotools pkgconfig
> +
> +EXTRA_OECONF += "--disable-cairo-tests \
> +                 --enable-omap-experimental-api \
> +                 --enable-install-test-programs \
> +                 --disable-manpages \
> +                "
> +
> +ALLOW_EMPTY_${PN}-drivers = "1"
> +PACKAGES =+ "${PN}-tests ${PN}-drivers ${PN}-radeon ${PN}-nouveau ${PN}-omap \
> +             ${PN}-intel ${PN}-exynos ${PN}-kms ${PN}-freedreno"
> +
> +RRECOMMENDS_${PN}-drivers = "${PN}-radeon ${PN}-nouveau ${PN}-omap ${PN}-intel \
> +                             ${PN}-exynos ${PN}-freedreno"
> +
> +FILES_${PN}-tests = "${bindir}/dr* ${bindir}/mode* ${bindir}/*test"
> +FILES_${PN}-radeon = "${libdir}/libdrm_radeon.so.*"
> +FILES_${PN}-nouveau = "${libdir}/libdrm_nouveau.so.*"
> +FILES_${PN}-omap = "${libdir}/libdrm_omap.so.*"
> +FILES_${PN}-intel = "${libdir}/libdrm_intel.so.*"
> +FILES_${PN}-exynos = "${libdir}/libdrm_exynos.so.*"
> +FILES_${PN}-kms = "${libdir}/libkms*.so.*"
> +FILES_${PN}-freedreno = "${libdir}/libdrm_freedreno.so.*"
> +
> diff --git a/meta/recipes-graphics/drm/libdrm_git.bb b/meta/recipes-graphics/drm/libdrm_git.bb
> deleted file mode 100644
> index d7245ee..0000000
> --- a/meta/recipes-graphics/drm/libdrm_git.bb
> +++ /dev/null
> @@ -1,12 +0,0 @@
> -require libdrm.inc
> -
> -SRC_URI = "git://anongit.freedesktop.org/git/mesa/drm"
> -
> -S = "${WORKDIR}/git"
> -
> -DEFAULT_PREFERENCE = "-1"
> -
> -SRCREV = "e01d68f9f3acfc35fe164283904b5d058c2ab378"
> -PV = "2.4.40+git${SRCPV}"
> -PR = "${INC_PR}.0"
> -
> --
> 2.1.4
> 
> --
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core

-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 204 bytes
Desc: Message signed with OpenPGP using GPGMail
URL: <http://lists.openembedded.org/pipermail/openembedded-core/attachments/20150707/7abfa78a/attachment-0002.sig>