[OE-core] [PATCH v3 01/14] pypi.bbclass: bring in from meta-python

[Tim Orling]

Moments after hitting send, I realized this was missing the documentation strings
from v1. I have added that change in the contrib git repo, but will not bother resending
the patch via email. This series must be applied from git regardless, due to the long
lines in the old manifest files which break git send-email.

> On Dec 11, 2017, at 9:04 PM, Tim Orling <timothy.t.orling at linux.intel.com> wrote:
> 
> The pypi.bbclass has usefullness in many meta layers, not
> just meta-python. Add it to oe-core for the benefit of
> everyone.
> 
> Signed-off-by: Tim Orling <timothy.t.orling at linux.intel.com>
> ---
> meta/classes/pypi.bbclass | 26 ++++++++++++++++++++++++++
> 1 file changed, 26 insertions(+)
> create mode 100644 meta/classes/pypi.bbclass
> 
> diff --git a/meta/classes/pypi.bbclass b/meta/classes/pypi.bbclass
> new file mode 100644
> index 0000000000..e5d7ab3ce1
> --- /dev/null
> +++ b/meta/classes/pypi.bbclass
> @@ -0,0 +1,26 @@
> +def pypi_package(d):
> +    bpn = d.getVar('BPN')
> +    if bpn.startswith('python-'):
> +        return bpn[7:]
> +    elif bpn.startswith('python3-'):
> +        return bpn[8:]
> +    return bpn
> +
> +PYPI_PACKAGE ?= "${@pypi_package(d)}"
> +PYPI_PACKAGE_EXT ?= "tar.gz"
> +
> +def pypi_src_uri(d):
> +    package = d.getVar('PYPI_PACKAGE')
> +    package_ext = d.getVar('PYPI_PACKAGE_EXT')
> +    pv = d.getVar('PV')
> +    return 'https://files.pythonhosted.org/packages/source/%s/%s/%s-%s.%s' % (package[0], package, package, pv, package_ext)
> +
> +PYPI_SRC_URI ?= "${@pypi_src_uri(d)}"
> +
> +HOMEPAGE ?= "https://pypi.python.org/pypi/${PYPI_PACKAGE}/"
> +SECTION = "devel/python"
> +SRC_URI += "${PYPI_SRC_URI}"
> +S = "${WORKDIR}/${PYPI_PACKAGE}-${PV}"
> +
> +UPSTREAM_CHECK_URI ?= "https://pypi.python.org/pypi/${PYPI_PACKAGE}/"
> +UPSTREAM_CHECK_REGEX ?= "/${PYPI_PACKAGE}/(?P<pver>(\d+[\.\-_]*)+)"
> -- 
> 2.14.3
> 
> -- 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core