[oe] [PATCH 5/6] sun-jre6: add 1.6.0.10

[Otavio Salvador]

Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
---
 packages/sun-jre/sun-jre6_1.6.0.10.bb |   89 +++++++++++++++++++++++++++++++++
 1 files changed, 89 insertions(+), 0 deletions(-)
 create mode 100644 packages/sun-jre/sun-jre6_1.6.0.10.bb

diff --git a/packages/sun-jre/sun-jre6_1.6.0.10.bb b/packages/sun-jre/sun-jre6_1.6.0.10.bb
new file mode 100644
index 0000000..d72cfa0
--- /dev/null
+++ b/packages/sun-jre/sun-jre6_1.6.0.10.bb
@@ -0,0 +1,89 @@
+
+DESCRIPTION = "Sun J2SE Runtime Environment"
+
+PR="r0"
+
+LICENSE = "Sun Binary Code License Agreement"
+
+SP = "jdk-6u10-dlj-linux-i586.bin"
+SD = "jdk1.6.0_10"
+S = ${WORKDIR}
+
+SRC_URI = "http://download.java.net/dlj/binaries/jdk-6u10-dlj-linux-i586.bin"
+
+PRIVATE_LIBS = "${@base_read_file('${WORKDIR}/${SD}.shlibs')}"
+
+do_install() {
+	export MORE=10000
+	sh ${WORKDIR}/${SP} --accept-license >/dev/null
+	chmod -R go=u-w ${SD}
+	chmod -R u+w ${SD}
+
+	mkdir -p ${D}${libdir}/sun-java6-${PV}
+	mv ${S}/${SD}/jre/* ${D}${libdir}/sun-java6-${PV}
+
+	mkdir -p ${D}${libdir}/mozilla/plugins
+	cd ${D}${libdir}/mozilla/plugins
+	ln -s ${libdir}/sun-java6-${PV}/plugin/i386/ns7/libjavaplugin_oji.so .
+
+	cd ${D}${libdir}/sun-java6-${PV}
+
+	for p in `find . -name '*.pack'`; do
+		./bin/unpack200 $p $(echo $p | sed 's,.pack$,.jar,g') || exit 1
+		rm $p
+	done
+
+	for i in	bin/ControlPanel	\
+			bin/javaws	\
+			bin/jcontrol	\
+			bin/keytool	\
+			bin/orbd	\
+			bin/pack200	\
+			bin/policytool	\
+			bin/rmid	\
+			bin/rmiregistry	\
+			bin/servertool	\
+			bin/tnameserv	\
+			bin/unpack200
+	do
+		rm $i
+	done
+
+	rm -rf javaws lib/javaws*
+
+	rm -rf plugin/desktop plugin/i386/ns7-gcc29
+
+	rm -f lib/fontconfig.*.bfc lib/fontconfig.*.properties.src
+
+	rm -f lib/javaws.jar lib/ext/ldapsec.jar lib/cmm/PYCC.pf \
+		lib/audio/soundbank.gm
+
+	rm -rf lib/i386/server lib/i386/motif21 lib/i386/client/classes.jsa \
+		lib/i386/libjavaplugin_nscp_gcc29.so \
+		lib/i386/headless
+
+	rm -rf fonts oblique-fonts man
+
+	rm -rf lib/locale lib/zi lib/management
+	rm -rf lib/desktop LICENSE README COPYRIGHT THIRDPARTYLICENSEREADME.txt \
+	    Welcome.html
+
+	# Find out what shared libs we contain and spit it out to a file
+	find . -name "*.so" -exec basename {} \; | sort | uniq \
+						> ${WORKDIR}/${SD}.shlibs
+}
+
+PACKAGES =+ "${PN}-plugin"
+
+FILES_${PN} = "/usr/"
+FILES_${PN}-dbg += "/usr/*/.debug /usr/*/*/.debug /usr/*/*/*/.debug /usr/*/*/*/*/.debug /usr/*/*/*/*/*/.debug"
+FILES_${PN}-plugin = "${libdir}/firefox-3.0.1/plugins/* ${libdir}/sun-java6-${PV}/plugin/i386/ns7/libjavaplugin_oji.so"
+
+RDEPENDS_${PN} += "libx11-locale"
+RDEPENDS_${PN}-plugin += "${PN}"
+
+pkg_postinst_${PN} () {
+	grep -v JAVA_HOME /etc/environment > /etc/environment.new
+	mv /etc/environment.new /etc/environment
+	echo "JAVA_HOME=\"${libdir}/sun-java6-${PV}\"" >> /etc/environment
+}
-- 
1.6.2.rc0