[oe] [PATCH] barebox: Add recipe for this new bootloader

[Eric Benard]

* barebox is "a bootloader that inherits the best of U-Boot and the Linux kernel"
* add recipe for v2009.12.0 (last stable)
* add recipe for git repository

Signed-off-by: Eric Benard <eric at eukrea.com>
---
 recipes/barebox/barebox.inc        |   49 ++++++++++++++++++++++++++++++++++++
 recipes/barebox/barebox_2009.12.bb |   15 +++++++++++
 recipes/barebox/barebox_git.bb     |   10 +++++++
 3 files changed, 74 insertions(+), 0 deletions(-)
 create mode 100644 recipes/barebox/barebox.inc
 create mode 100644 recipes/barebox/barebox_2009.12.bb
 create mode 100644 recipes/barebox/barebox_git.bb

diff --git a/recipes/barebox/barebox.inc b/recipes/barebox/barebox.inc
new file mode 100644
index 0000000..b3def2a
--- /dev/null
+++ b/recipes/barebox/barebox.inc
@@ -0,0 +1,49 @@
+DESCRIPTION = "Barebox - a bootloader that inherits the best of U-Boot and the Linux kernel"
+HOMEPAGE = "http://www.barebox.org/"
+SECTION = "bootloaders"
+PRIORITY = "optional"
+LICENSE = "GPL"
+PROVIDES = "virtual/bootloader"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit kernel-arch
+
+EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX}"
+
+BAREBOX_MACHINE ?= "${MACHINE}_defconfig"
+BAREBOX_BINARY ?= "barebox.bin"
+BAREBOX_IMAGE ?= "barebox-${MACHINE}-${PV}-${PR}.bin"
+BAREBOX_SYMLINK ?= "barebox-${MACHINE}.bin"
+
+INSANE_SKIP_${PN} = True
+
+do_configure_prepend() {
+	   cp ${WORKDIR}/defconfig ${S}/.config
+	   oe_runmake oldconfig
+}
+
+do_compile () {
+	   unset LDFLAGS
+	   unset CFLAGS
+	   unset CPPFLAGS
+	   oe_runmake all
+}
+
+do_deploy () {
+	  install -d ${DEPLOY_DIR_IMAGE}
+	  install ${S}/${BAREBOX_BINARY} ${DEPLOY_DIR_IMAGE}/${BAREBOX_IMAGE}
+	  package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${BAREBOX_IMAGE}
+
+	  cd ${DEPLOY_DIR_IMAGE}
+	  rm -f ${BAREBOX_SYMLINK}
+	  ln -sf ${BAREBOX_IMAGE} ${BAREBOX_SYMLINK}
+	  package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${BAREBOX_SYMLINK}
+}
+do_deploy[dirs] = "${S}"
+addtask deploy before do_build after do_compile
+
+do_stage() {
+	   install -d ${STAGING_BINDIR_NATIVE}
+	   install -m 755 scripts/mkimage ${STAGING_BINDIR_NATIVE}/
+}
diff --git a/recipes/barebox/barebox_2009.12.bb b/recipes/barebox/barebox_2009.12.bb
new file mode 100644
index 0000000..2977429
--- /dev/null
+++ b/recipes/barebox/barebox_2009.12.bb
@@ -0,0 +1,15 @@
+require barebox.inc
+
+PR = "r0"
+
+DEFAULT_PREFERENCE = "-1"
+
+BAREBOX_REVISION ?= "0"
+
+S = "${WORKDIR}/barebox-${PV}.${BAREBOX_REVISION}"
+
+SRC_URI = "http://barebox.org/download/barebox-${PV}.${BAREBOX_REVISION}.tar.bz2;name=barebox-${PV}.${BAREBOX_REVISION} \
+	   file://defconfig"
+
+SRC_URI[barebox-2009.12.0.md5sum] = "d1aefe17cfd72affec766617b42dfb78"
+SRC_URI[barebox-2009.12.0.sha256sum] = "0ccd59898289652f4bebd8282737a771729d84886195221c781df08f81a837ef"
diff --git a/recipes/barebox/barebox_git.bb b/recipes/barebox/barebox_git.bb
new file mode 100644
index 0000000..8f9e322
--- /dev/null
+++ b/recipes/barebox/barebox_git.bb
@@ -0,0 +1,10 @@
+require barebox.inc
+
+PR = "r0"
+
+FILESPATHPKG =. "barebox-git:"
+
+SRC_URI = "git://git.pengutronix.de/git/barebox.git;protocol=git \
+	   file://defconfig"
+
+S = "${WORKDIR}/git"
-- 
1.6.0.4