[oe] [PATCH] qwt: Add version 5.2.1

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 22-06-10 12:59, Thomas Elste wrote:
> Add recipe for current version of Qwt. This new version uses qt4-classes
> instead of palmtop. Different bb-files for Qt and Qt-Embedded
> variant are provided. Qwt examples are also build. They get deployed in
> extra packages.

Could you make the -e and regular variants parallel installable? The
demos could be put in ${D}${bindir}/qwt-examples${QWT_VARIANT} for example.

regards,

Koen


> 
> Signed-off-by: Thomas Elste <thomas.elste at imms.de>
> ---
>  recipes/qwt/qwt-e_5.2.1.bb |    8 ++++++++
>  recipes/qwt/qwt.inc        |   33 +++++++++++++++++++++++++++++++++
>  recipes/qwt/qwt_5.2.1.bb   |    8 ++++++++
>  3 files changed, 49 insertions(+), 0 deletions(-)
>  create mode 100644 recipes/qwt/qwt-e_5.2.1.bb
>  create mode 100644 recipes/qwt/qwt.inc
>  create mode 100644 recipes/qwt/qwt_5.2.1.bb
> 
> diff --git a/recipes/qwt/qwt-e_5.2.1.bb b/recipes/qwt/qwt-e_5.2.1.bb
> new file mode 100644
> index 0000000..09b31ed
> --- /dev/null
> +++ b/recipes/qwt/qwt-e_5.2.1.bb
> @@ -0,0 +1,8 @@
> +QWT_VARIANT = "e"
> +require qwt.inc
> +
> +PR = "${INC_PR}.1"
> +
> +SRC_URI[md5sum] = "4a595b8db0ec3856b117836c1d60cb27"
> +SRC_URI[sha256sum] = "e2b8bb755404cb3dc99e61f3e2d7262152193488f5fbe88524eb698e11ac569f"
> +
> diff --git a/recipes/qwt/qwt.inc b/recipes/qwt/qwt.inc
> new file mode 100644
> index 0000000..6a9f9e0
> --- /dev/null
> +++ b/recipes/qwt/qwt.inc
> @@ -0,0 +1,33 @@
> +DESCRIPTION = "Qt Widget Extension for Technical Applications"
> +HOMEPAGE = "http://qwt.sourceforge.net/"
> +SECTION = "libs"
> +PRIORITY = "optional"
> +LICENSE = "GPL"
> +INC_PR = "r0"
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/qwt/qwt-${PV}.tar.bz2"
> +
> +inherit qt4${QWT_VARIANT}
> +
> +EXTRA_OEMAKE = "${PARALLEL_MAKE}"
> +
> +do_configure_prepend() {
> +        # set install path and doc path, enable examples
> +        sed -i \
> +                -e 's/\(INSTALLBASE *= \)\/usr.*/\1\/usr/' \
> +                -e 's/\(doc.path.*\/\).*/\1share\/doc\/qwt-${PV}/' \
> +                -e 's/#CONFIG     += QwtExamples/CONFIG += QwtExamples/' \
> +                qwtconfig.pri
> +}
> +
> +do_install() {
> +        oe_runmake install INSTALL_ROOT=${D}
> +        install -d ${D}${bindir}/qwt-examples
> +        install examples/bin/* ${D}${bindir}/qwt-examples
> +}
> +
> +PACKAGES =+ "${PN}-examples ${PN}-examples-dbg"
> +FILES_${PN} = "${libdir}/*"
> +FILES_${PN}-examples = "${bindir}/qwt-examples/*"
> +FILES_${PN}-examples-dbg = "${bindir}/qwt-examples"
> +
> diff --git a/recipes/qwt/qwt_5.2.1.bb b/recipes/qwt/qwt_5.2.1.bb
> new file mode 100644
> index 0000000..a1142f0
> --- /dev/null
> +++ b/recipes/qwt/qwt_5.2.1.bb
> @@ -0,0 +1,8 @@
> +QWT_VARIANT = "x11"
> +require qwt.inc
> +
> +PR = "${INC_PR}.1"
> +
> +SRC_URI[md5sum] = "4a595b8db0ec3856b117836c1d60cb27"
> +SRC_URI[sha256sum] = "e2b8bb755404cb3dc99e61f3e2d7262152193488f5fbe88524eb698e11ac569f"
> +

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)

iD8DBQFMIMhrMkyGM64RGpERAmX+AJ9xH0uFz2QAA4afR1pTrfcJCVC1CACfQLYm
PFUyc+Uul7EcHZ8sS99hj6E=
=SRqv
-----END PGP SIGNATURE-----