[oe] [PATCH] qwt: Add version 5.2.1

[Thomas Elste]

Add recipe for current version of Qwt. This new version uses qt4-classes
instead of palmtop. Different bb-files for Qt and Qt-Embedded
variant are provided. Qwt examples are also build. They get deployed in
extra packages.

Signed-off-by: Thomas Elste <thomas.elste at imms.de>
---
 recipes/qwt/qwt-e_5.2.1.bb |   10 ++++++++++
 recipes/qwt/qwt.inc        |   35 +++++++++++++++++++++++++++++++++++
 recipes/qwt/qwt_5.2.1.bb   |   10 ++++++++++
 3 files changed, 55 insertions(+), 0 deletions(-)
 create mode 100644 recipes/qwt/qwt-e_5.2.1.bb
 create mode 100644 recipes/qwt/qwt.inc
 create mode 100644 recipes/qwt/qwt_5.2.1.bb

diff --git a/recipes/qwt/qwt-e_5.2.1.bb b/recipes/qwt/qwt-e_5.2.1.bb
new file mode 100644
index 0000000..95bb31f
--- /dev/null
+++ b/recipes/qwt/qwt-e_5.2.1.bb
@@ -0,0 +1,10 @@
+QWT_VARIANT = "E"
+inherit qt4e
+require qwt.inc
+RDEPENDS_${PN}-examples += "qt4-embedded-fonts"
+
+PR = "${INC_PR}.1"
+
+SRC_URI[md5sum] = "4a595b8db0ec3856b117836c1d60cb27"
+SRC_URI[sha256sum] = "e2b8bb755404cb3dc99e61f3e2d7262152193488f5fbe88524eb698e11ac569f"
+
diff --git a/recipes/qwt/qwt.inc b/recipes/qwt/qwt.inc
new file mode 100644
index 0000000..09ceb56
--- /dev/null
+++ b/recipes/qwt/qwt.inc
@@ -0,0 +1,35 @@
+DESCRIPTION = "Qt Widget Extension for Technical Applications"
+HOMEPAGE = "http://qwt.sourceforge.net/"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "GPL"
+INC_PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/qwt/qwt-${PV}.tar.bz2"
+
+S = "${WORKDIR}/qwt-${PV}"
+
+EXTRA_OEMAKE = "${PARALLEL_MAKE}"
+
+do_configure_prepend() {
+        # set install and doc path, set lib suffix, enable examples
+        sed -i \
+                -e 's/\(INSTALLBASE *= \)\/usr.*/\1\/usr/' \
+                -e 's/\(doc.path.*\/\).*/\1share\/doc\/qwt-${PV}/' \
+                -e 's/\(RELEASE_SUFFIX *=\).*/\1 ${QWT_VARIANT}/' \
+                -e 's/#CONFIG     += QwtExamples/CONFIG += QwtExamples/' \
+                qwtconfig.pri
+}
+
+do_install() {
+        oe_runmake install INSTALL_ROOT=${D}
+        rm ${D}${libdir}/libqwt${QWT_VARIANT}.so
+        install -d ${D}${bindir}/qwt${QWT_VARIANT}-examples
+        install examples/bin${QWT_VARIANT}/* ${D}${bindir}/qwt${QWT_VARIANT}-examples
+}
+
+PACKAGES =+ "${PN}-examples ${PN}-examples-dbg"
+FILES_${PN} = "${libdir}/*"
+FILES_${PN}-examples = "${bindir}/qwt${QWT_VARIANT}-examples/*"
+FILES_${PN}-examples-dbg = "${bindir}/qwt${QWT_VARIANT}-examples"
+
diff --git a/recipes/qwt/qwt_5.2.1.bb b/recipes/qwt/qwt_5.2.1.bb
new file mode 100644
index 0000000..4f59d16
--- /dev/null
+++ b/recipes/qwt/qwt_5.2.1.bb
@@ -0,0 +1,10 @@
+QWT_VARIANT = 
+inherit qt4x11
+require qwt.inc
+RDEPENDS_${PN}-examples += "qt4-fonts"
+
+PR = "${INC_PR}.1"
+
+SRC_URI[md5sum] = "4a595b8db0ec3856b117836c1d60cb27"
+SRC_URI[sha256sum] = "e2b8bb755404cb3dc99e61f3e2d7262152193488f5fbe88524eb698e11ac569f"
+
-- 
1.7.1