[oe] [PATCH 07/11] zbar: Add support for Qt widgets and bump to 0.10

[Camille Moncelier]

  * Added support for qt widgets (not only gtk ones)

Signed-off-by: Camille Moncelier <moncelier at devlife.org>
---
 recipes/zbar/zbar_0.10.bb |   31 +++++++++++++++++++++++++++++++
 1 files changed, 31 insertions(+), 0 deletions(-)
 create mode 100644 recipes/zbar/zbar_0.10.bb

diff --git a/recipes/zbar/zbar_0.10.bb b/recipes/zbar/zbar_0.10.bb
new file mode 100644
index 0000000..844764d
--- /dev/null
+++ b/recipes/zbar/zbar_0.10.bb
@@ -0,0 +1,31 @@
+DESCRIPTION = "2D barcode scanner toolkit."
+SECTION = "graphics"
+LICENSE = "GPL"
+DEPENDS = "intltool-native gtk+ qt4-x11-free libpng jpeg"
+PR = "r1"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/${PN}/${P}.tar.bz2"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = " --without-imagemagick --without-python"
+
+do_configure_append() {
+    # This one tries to autodetect MOC and fails, so we have to force it
+    sed -i "s#^MOC =.*#MOC = ${STAGING_BINDIR_NATIVE}/moc4#" Makefile
+}
+
+PACKAGES += "libzbar libzbargtk libzbarqt"
+
+FILES_${PN} = "${bindir}/zbar*"
+FILES_${PN}-doc = "${datadir}/doc ${datadir}/man "
+FILES_${PN}-dbg += " ${bindir}/.debug"
+FILES_libzbar = "${libdir}/libzbar.so.*"
+FILES_libzbar-dev = "${libdir}/libzbar.so ${libdir}/libzbar.*a ${includedir}/zbar* "
+FILES_libzbargtk = "${libdir}/libzbargtk.so.*"
+FILES_libzbargtk-dev = "${libdir}/libzbargtk.so ${libdir}/libzbargtk.*a"
+FILES_libzbarqt = "${libdir}/libzbarqt.so.*"
+FILES_libzbarqt-dev = "${libdir}/libzbarqt.so ${libdir}/libzbarqt.*a"
+
+SRC_URI[md5sum] = "0fd61eb590ac1bab62a77913c8b086a5"
+SRC_URI[sha256sum] = "234efb39dbbe5cef4189cc76f37afbe3cfcfb45ae52493bfe8e191318bdbadc6"
-- 
1.7.3.1