[oe] [meta-oe][V2 2/4] libnl: add 3.23

[Andreas Müller]

* fixes networkmanager default route issue
* to make wpa-supplicant build, links to include files and shared libs were
  added since wpa-supplicant expects old libnl-2 locations. Should libnl-3
  move to oe-core, this woraround should be fixed at wpa-supplicant.
* the command line interface (cli) applications were added at libnl-cli packet.
  This seems correct because EXTRA_OECONF += "--disable-cli" creates empty
  package libnl-cli without affecting other packages.
* build tested from scratch & run tested on overo with iw 3.2 /
  wpa-supplicant 0.7.3 / networkmanager 0.9.2.

Signed-off-by: Andreas Müller <schnitzeltony at gmx.de>
---
 meta-oe/recipes-support/libnl/libnl_3.2.3.bb |   46 ++++++++++++++++++++++++++
 1 files changed, 46 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-support/libnl/libnl_3.2.3.bb

diff --git a/meta-oe/recipes-support/libnl/libnl_3.2.3.bb b/meta-oe/recipes-support/libnl/libnl_3.2.3.bb
new file mode 100644
index 0000000..190ea4c
--- /dev/null
+++ b/meta-oe/recipes-support/libnl/libnl_3.2.3.bb
@@ -0,0 +1,46 @@
+DESCRIPTION = "libnl is a library for applications dealing with netlink sockets."
+HOMEPAGE = "http://www.infradead.org/~tgr/libnl/"
+SECTION = "libs/network"
+
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=2b41e13261a330ee784153ecbb6a82bc"
+
+DEPENDS = "flex-native bison-native"
+
+SRC_URI = "http://www.infradead.org/~tgr/${BPN}/files/${BP}.tar.gz"
+
+SRC_URI[md5sum] = "dbbb44801e833cf9ca4fdc943f2a58ee"
+SRC_URI[sha256sum] = "69f4a360350ea61f2c988f947c251995c04093c74743eae9eeffba85846ef007"
+
+inherit autotools pkgconfig
+
+do_install_append() {
+    # make wpa-supplicant happy
+    # TODO: when moving to oe-core fix at wpa-supplicant
+    # (e.g src/drivers/drivers.mak)
+    cd ${D}${includedir}
+    ln -sf libnl3/netlink netlink
+    cd ${D}${libdir}
+    ln -sf libnl-3.so.200 libnl.so
+    ln -sf libnl-3.so.200 libnl.so.3
+    ln -sf libnl-genl-3.so.200 libnl-genl.so
+    ln -sf libnl-genl-3.so.200 libnl-genl.so.3
+}
+
+FILES_${PN} = "${libdir}/libnl-3.so.* \
+               ${libdir}/libnl.so.* \
+               ${sysconfdir}"
+FILES_${PN}-dbg += "${libdir}/libnl/cli/*/.debug"
+FILES_${PN}-dev += "${libdir}/libnl/cli/*/*.so \
+                    ${libdir}/libnl/cli/*/*.la"
+FILES_${PN}-staticdev += "${libdir}/libnl/cli/*/*.a"
+
+PACKAGES += "${PN}-cli ${PN}-route ${PN}-nf ${PN}-genl"
+FILES_${PN}-cli   = "${libdir}/libnl-cli-3.so.* \
+                     ${libdir}/libnl/cli/*/*.so.* \
+                     ${sbindir}/nl-*"
+FILES_${PN}-route = "${libdir}/libnl-route-3.so.*"
+FILES_${PN}-nf    = "${libdir}/libnl-nf-3.so.*"
+FILES_${PN}-genl  = "${libdir}/libnl-genl-3.so.* \
+                     ${libdir}/libnl-genl.so.*"
+
-- 
1.7.4.4