[oe] [PATCH] Added ImageMagick 6.7.2-3

[Paul Menzel]

Dear Gavin,


thank you for your patch.

Am Donnerstag, den 06.10.2011, 16:01 -0700 schrieb gavinswanson at gmail.com:
> From: Gavin Swanson <gavinswanson at gmail.com>

Please refer to our commit policy [1] and style guide [2].
(Unfortunately the Wiki is down at the moment.)

Change the commit summary to

	imagemagick: Add version 6.7.2-3

and add some more information to the commit message. What distribution
and machine did you use for testing? Have you run tested the new
version.

You seem to have used an existing recipe as a template. Please note that
too.

At last please add you Signed-off-by line.

> ---
>  recipes/imagemagick/imagemagick_6.7.2-3.bb |   36 ++++++++++++++++++++++++++++
>  1 files changed, 36 insertions(+), 0 deletions(-)
>  create mode 100644 recipes/imagemagick/imagemagick_6.7.2-3.bb
> 
> diff --git a/recipes/imagemagick/imagemagick_6.7.2-3.bb b/recipes/imagemagick/imagemagick_6.7.2-3.bb
> new file mode 100644
> index 0000000..14746c9
> --- /dev/null
> +++ b/recipes/imagemagick/imagemagick_6.7.2-3.bb
> @@ -0,0 +1,36 @@
> +DESCRIPTION = "ImageMagick is an image convertion tools"
> +SECTION = "console/utils"
> +LICENSE = "GPL"

I updated those meta fields in the repository. Please update the above
too.

> +# FIXME: There is much more checked libraries. All should be added or explicitly disabled to get consistent results.
> +DEPENDS = "lcms bzip2 jpeg libpng librsvg tiff zlib"
> +
> +PR = "r1"

Please start with `r0`.

> +
> +SRC_URI = "ftp://ftp.nluug.nl/pub/ImageMagick/ImageMagick-${PV}.tar.bz2 \
> +#           file://PerlMagic_MakePatch;apply=yes \

Why is this patch not needed anymore? You can just delete the line then.

> +          "
> +
> +IMVER = "6.7.2-3"

I think the old recipes strip the `-3` to get the correct directory
names. This way `IMVER` is equal to `PN`.

> +
> +S = "${WORKDIR}/ImageMagick-${IMVER}"

It looks like you can delete this line for this version, since in your
version the archive seems to have a “correctly” named folder included.

$ ls minimal-dev/work/armv7a-oe-linux-gnueabi/imagemagick-6.4.4-1-r7/
ImageMagick-6.4.4  temp

$ ls minimal-dev/work/armv7a-oe-linux-gnueabi/imagemagick-6.7.2-3-r1/
ImageMagick-6.7.2-3  temp

> +
> +inherit autotools binconfig pkgconfig
> +
> +EXTRA_OECONF = "--program-prefix= --without-x --without-freetype --without-perl --disable-openmp"
> +
> +FILES_${PN} += "${libdir}/ImageMagick-${IMVER}/modules-Q16/*/*.so \
> +                ${libdir}/ImageMagick-${IMVER}/modules-Q16/*/*.la \
> +                ${libdir}/ImageMagick-${IMVER}/config/ \
> +                ${datadir}/ImageMagick-${IMVER}"

Could you please look into the following warnings.

        NOTE: package imagemagick-6.7.2-3-r1: task do_qa_staging: Succeeded
        WARNING: the following files were installed but not shipped in any package:
        WARNING:   /usr/share/ImageMagick-6.7.2/francais.xml
        WARNING:   /usr/share/ImageMagick-6.7.2/locale.xml
        WARNING:   /usr/share/ImageMagick-6.7.2/english.xml
        WARNING:   /usr/share/ImageMagick-6.7.2/configure.xml

Here you can also see that the directory name seems to only include
6.7.2 instead of 6.7.2-3. So you should check where `IMVER` should be
used and where `PV`, which is 6.7.2-3.

> +
> +FILES_${PN}-dev += "${libdir}/ImageMagick-${IMVER}/modules-Q16/*/*.a"
> +
> +FILES_${PN}-dbg += "${libdir}/ImageMagick-${IMVER}/modules-Q16/*/.debug/*"
> +
> +BBCLASSEXTEND = "native"
> +
> +LEAD_SONAME = "libMagickCore.so.*"
> +
> +
> +SRC_URI[md5sum] = "62e12090d2d385f4800c06f58f477bea"
> +SRC_URI[sha256sum] = "50fe6e1af9e900e5d4bef45879a3a7e15512bb9ab3dbbafb521825359cb6d2c7"


Thanks,

Paul


[1] http://www.openembedded.org/wiki/Commit_Policy
[2] http://www.openembedded.org/index.php?title=Styleguide
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 198 bytes
Desc: This is a digitally signed message part
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20111007/bc69dc71/attachment-0002.sig>