[oe] [meta-oe][PATCH] ltp-ddt: import initial version 0.0.4 plus fixes
Denys Dmytriyenko
denis at denix.org
Thu Oct 13 19:55:32 UTC 2011
From: Denys Dmytriyenko <denys at ti.com>
Imported from Arago, adapted for meta-openembedded
Signed-off-by: Denys Dmytriyenko <denys at ti.com>
---
meta-oe/recipes-devtools/ltp-ddt/ltp-ddt_0.0.4.bb | 63 +++++++++++++++++++++
1 files changed, 63 insertions(+), 0 deletions(-)
create mode 100644 meta-oe/recipes-devtools/ltp-ddt/ltp-ddt_0.0.4.bb
diff --git a/meta-oe/recipes-devtools/ltp-ddt/ltp-ddt_0.0.4.bb b/meta-oe/recipes-devtools/ltp-ddt/ltp-ddt_0.0.4.bb
new file mode 100644
index 0000000..4b8ff98
--- /dev/null
+++ b/meta-oe/recipes-devtools/ltp-ddt/ltp-ddt_0.0.4.bb
@@ -0,0 +1,63 @@
+DESCRIPTION = "Embedded Linux Device Driver Tests based on Linux Test Project"
+HOMEPAGE = "http://arago-project.org/git/projects/test-automation/ltp-ddt.git"
+SECTION = "console/utils"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3"
+PR = "r1"
+
+PROVIDES += "ltp"
+DEPENDS += "zip-native virtual/kernel alsa-lib"
+
+inherit autotools
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+SRCREV = "5fba3d42f126ce13333fb7d0412d729b753ee5a4"
+BRANCH ?= "master"
+
+SRC_URI = "git://arago-project.org/git/projects/test-automation/ltp-ddt.git;protocol=git;branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+LTPROOT = "/opt/ltp"
+
+EXTRA_OEMAKE_append = " \
+ prefix=${LTPROOT} \
+ CROSS_COMPILE=${HOST_PREFIX} \
+ SKIP_IDCHECK=1 \
+ KERNEL_INC=${STAGING_KERNEL_DIR}/include \
+ KERNEL_USR_INC=${STAGING_INCDIR} \
+ ALSA_INCPATH=${STAGING_INCDIR} \
+ ALSA_LIBPATH=${STAGING_LIBDIR} \
+ PLATFORM=${MACHINE} \
+"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+FILES_${PN}-dbg += " \
+ ${LTPROOT}/.debug \
+ ${LTPROOT}/bin/.debug \
+ ${LTPROOT}/runtest/.debug \
+ ${LTPROOT}/testcases/bin/.debug \
+ ${LTPROOT}/testcases/bin/*/bin/.debug \
+ ${LTPROOT}/testcases/bin/*/test/.debug \
+ ${LTPROOT}/testcases/bin/ddt/.debug \
+ ${LTPROOT}/testcases/bin/ddt/*/bin/.debug \
+ ${LTPROOT}/testcases/bin/ddt/*/test/.debug \
+"
+
+FILES_${PN} += "${LTPROOT}/*"
+
+do_configure() {
+ cp ${S}/include/config.h.default ${S}/include/config.h
+ cp ${S}/include/mk/config.mk.default ${S}/include/mk/config.mk
+ cp ${S}/include/mk/features.mk.default ${S}/include/mk/features.mk
+ echo "${TAG}" > ${S}/ChangeLog
+}
+
+do_install() {
+ oe_runmake DESTDIR=${D} install
+ install -d ${D}${datadir}
+ cp -a ${D}${LTPROOT}/share/* ${D}${datadir}
+ rm -rf ${D}${LTPROOT}/share/
+}
--
1.7.0.4
More information about the Openembedded-devel
mailing list