[oe] [meta-oe][PATCH] goffice: update to version 0.10.1

[Mario Domenech Goulart]

That's a version requirement for Gnumeric.

Note that goffice 0.10.1 requires gtk3.

Signed-off-by: Mario Domenech Goulart <mario at ossystems.com.br>
---
 .../recipes-support/goffice/goffice_0.10.1.bb      |   47 ++++++++++++++++++++
 .../recipes-support/goffice/goffice_0.8.17.bb      |   46 -------------------
 2 files changed, 47 insertions(+), 46 deletions(-)
 create mode 100644 meta-gnome/recipes-support/goffice/goffice_0.10.1.bb
 delete mode 100644 meta-gnome/recipes-support/goffice/goffice_0.8.17.bb

diff --git a/meta-gnome/recipes-support/goffice/goffice_0.10.1.bb b/meta-gnome/recipes-support/goffice/goffice_0.10.1.bb
new file mode 100644
index 0000000..e567b1f
--- /dev/null
+++ b/meta-gnome/recipes-support/goffice/goffice_0.10.1.bb
@@ -0,0 +1,47 @@
+DESCRIPTION="Gnome Office Library"
+
+LICENSE="GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6dc33ff21e1ba1ac1a2a1069d361e29e"
+
+DEPENDS = "libxml-parser-perl-native glib-2.0 gtk+3 pango cairo libgsf libpcre libxml2 libart-lgpl"
+
+inherit gnome pkgconfig perlnative
+
+GNOME_COMPRESS_TYPE = "xz"
+
+SRC_URI[archive.md5sum] = "90fd17c6fe205b779571e00d9b0b4727"
+SRC_URI[archive.sha256sum] = "5c38f4e81e874cc8e89481b080f77c47c72bfd6fe2526f4fc2ef87c17f96cad0"
+
+FILES_${PN}-dbg += "${libdir}/goffice/${PV}/plugins/*/.debug"
+
+RRECOMMENDS_${PN} = " \
+  goffice-plugin-plot-barcol \
+  goffice-plugin-plot-distrib \
+  goffice-plugin-plot-pie \
+  goffice-plugin-plot-radar \
+  goffice-plugin-plot-surface \
+  goffice-plugin-plot-xy \
+  goffice-plugin-reg-linear \
+  goffice-plugin-reg-logfit \
+  goffice-plugin-smoothing \
+"
+
+FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
+            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
+            ${base_bindir}/* ${base_sbindir}/* \
+            ${base_libdir}/*${SOLIBS} \
+            ${datadir}/${PN} \
+            ${datadir}/pixmaps ${datadir}/applications \
+            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
+            ${libdir}/bonobo/servers"
+
+FILES_${PN}-locale = "${libdir}/locale"
+
+PACKAGES_DYNAMIC += "^goffice-plugin-.*"
+
+python populate_packages_prepend () {
+    goffice_libdir = d.expand('${libdir}/goffice/${PV}/plugins/')
+
+    do_split_packages(d, goffice_libdir, '(.*)', 'goffice-plugin-%s', 'Goffice plugin for %s', allow_dirs=True)
+}
+
diff --git a/meta-gnome/recipes-support/goffice/goffice_0.8.17.bb b/meta-gnome/recipes-support/goffice/goffice_0.8.17.bb
deleted file mode 100644
index c5d54ab..0000000
--- a/meta-gnome/recipes-support/goffice/goffice_0.8.17.bb
+++ /dev/null
@@ -1,46 +0,0 @@
-DESCRIPTION="Gnome Office Library"
-
-LICENSE="GPLv2"
-LIC_FILES_CHKSUM = "file://COPYING;md5=fa1348b178f4a7322170203c6c36f4c3"
-
-DEPENDS = "libxml-parser-perl-native glib-2.0 gtk+ pango cairo libgsf libpcre libxml2 libart-lgpl"
-
-inherit gnome pkgconfig perlnative
-
-SRC_URI += " file://c99math.patch \
-             file://nodolt.patch "
-
-SRC_URI[archive.md5sum] = "b4c924457163e02daf8a8d2428f51d10"
-SRC_URI[archive.sha256sum] = "dd8caef5fefffbc53938fa619de9f58e7c4dc71a1803de134065d42138a68c06"
-
-FILES_${PN}-dbg += "${libdir}/goffice/${PV}/plugins/*/.debug"
-
-RRECOMMENDS_${PN} = " \
-  goffice-plugin-plot-barcol \
-  goffice-plugin-plot-distrib \
-  goffice-plugin-plot-pie \
-  goffice-plugin-plot-radar \
-  goffice-plugin-plot-surface \
-  goffice-plugin-plot-xy \
-  goffice-plugin-reg-linear \
-  goffice-plugin-reg-logfit \
-  goffice-plugin-smoothing \
-"
-
-FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
-            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
-            ${base_bindir}/* ${base_sbindir}/* \
-            ${base_libdir}/*${SOLIBS} \
-            ${datadir}/${PN} \
-            ${datadir}/pixmaps ${datadir}/applications \
-            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
-            ${libdir}/bonobo/servers"
-
-PACKAGES_DYNAMIC += "^goffice-plugin-.*"
-
-python populate_packages_prepend () {
-    goffice_libdir = d.expand('${libdir}/goffice/${PV}/plugins/')
-
-    do_split_packages(d, goffice_libdir, '(.*)', 'goffice-plugin-%s', 'Goffice plugin for %s', allow_dirs=True)
-}
-
-- 
1.7.2.5