[oe] [meta-oe][PATCH] qextserialport: Added 1.2rc recipe
Martin Jansa
martin.jansa at gmail.com
Tue Feb 26 23:36:33 UTC 2013
On Wed, Feb 20, 2013 at 11:40:01AM -0800, eu at felipetonello.com wrote:
> From: "Felipe F. Tonello" <ftonello at cercacor.com>
>
> QExtSerialPort is a serial port library for Qt4/5.
1.2rc as version will sort lower then 1.2 when it's released, use something like:
REAL_PV="1.2rc"
PV = "1.1+${REAL_PV}"
to provide upgrade path when 1.2 is released and recipe is updated to use it.
It also has a lot of QA warnings, it's better to use += for FILES_, so that
default values are preserved where possible.
qextserialport-1.2rc: qextserialport: Files/directories were installed but not shipped
/usr/src
/usr/src/debug
/usr/src/debug/qextserialport
/usr/src/debug/qextserialport/1.2rc-r0
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/moc_qextserialport.cpp
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/moc_qextserialenumerator.cpp
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialport_unix.cpp
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialport_p.h
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialport.h
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialport.cpp
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialenumerator_p.h
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialenumerator_linux.cpp
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialenumerator.h
/usr/src/debug/qextserialport/1.2rc-r0/qextserialport-1.2rc/src/qextserialenumerator.cpp
>
> Signed-off-by: Felipe F. Tonello <ftonello at cercacor.com>
> ---
> .../qextserialport/qextserialport_1.2rc.bb | 53 ++++++++++++++++++++
> 1 file changed, 53 insertions(+)
> create mode 100644 meta-oe/recipes-qt/qextserialport/qextserialport_1.2rc.bb
>
> diff --git a/meta-oe/recipes-qt/qextserialport/qextserialport_1.2rc.bb b/meta-oe/recipes-qt/qextserialport/qextserialport_1.2rc.bb
> new file mode 100644
> index 0000000..da83404
> --- /dev/null
> +++ b/meta-oe/recipes-qt/qextserialport/qextserialport_1.2rc.bb
> @@ -0,0 +1,53 @@
> +DESCRIPTION = "Qt Ext Serial Port Library"
> +HOMEPAGE = "http://http://code.google.com/p/qextserialport/"
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=b866a28cda707ec714878bd933f46251"
> +SECTION = "qt/libs"
> +
> +PR = "r0"
> +
> +inherit qt4x11 pkgconfig
> +
> +DEPENDS = "udev"
> +
> +SRC_URI = " \
> + http://qextserialport.googlecode.com/files/qextserialport-${PV}.zip \
> +"
> +
> +SRC_URI[md5sum] = "ffa061edb9f64666468d18402eee6108"
> +SRC_URI[sha256sum] = "9cbee267aac9830f9944bb1d13872e51fba400aa9afe158e64f0fe265a0176bc"
> +
> +
> +S = "${WORKDIR}/qextserialport-${PV}"
> +
> +FILES_${PN} = "${libdir}/libqextserialport${SOLIBS}"
> +
> +FILES_${PN}-dev = " \
> + ${libdir}/libqextserialport${SOLIBSDEV} \
> + ${libdir}/libqextserialport.prl \
> + ${includedir}/QtExtSerialPort/*.h \
> + ${datadir}/qt4/mkspecs/features/extserialport.prf \
> +"
> +
> +FILES_${PN}-dbg = " \
> + ${libdir}/.debug/libqextserialport.so* \
> + /usr/src/debug/qextserialport-${PV}-${PR}/qextserialport-${PV}/* \
> +"
> +
> +do_configure_prepend() {
> + # based on the documentation, this line make sure we use udev in linux
> + cd ${S} && echo "linux*:CONFIG += qesp_linux_udev" > .qmake.cache
> +
> + # Hacking hardcoded qmake variables
> + find *.pro -exec sed -i -e 's,$$\[QT_INSTALL_HEADERS\],${includedir},g' '{}' ';'
> + find *.pro -exec sed -i -e 's,$$\[QT_INSTALL_LIBS\],${libdir},g' '{}' ';'
> + find *.pro -exec sed -i -e 's,$$\[QMAKE_MKSPECS\],${datadir}/qt4/mkspecs/,g' '{}' ';'
> +}
> +
> +do_install() {
> + export INSTALL_ROOT=${D}
> + oe_runmake install
> +
> + # This is necessary to make it work with the qt based SDK
> + cd ${D}/${datadir}/qt4/mkspecs/features && sed -i -e "s|${STAGING_INCDIR_NATIVE}/qt4|\$(OE_QMAKE_INCDIR_QT)/..|" ./extserialport.prf
> +}
> --
> 1.7.9.5
>
>
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel
--
Martin 'JaMa' Jansa jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 198 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20130227/83051f3c/attachment-0002.sig>
More information about the Openembedded-devel
mailing list